How to count Substrings in String

[ThomasQ]

Hi All!

With the function stringinstr you can find a given substring in a string. You can also set wich occurence of that substring you want found, for instance the 2nd or 3d, etc.. How do I count these substrings in a string, e.q. How do I return the total number of occurences of a substring in a string?

Thanks in advance!

Thomas

[jchd]

Local $string = 'avdn123ojvdno 123 vnob123n klbgn123klbcnipg,kl123mbfs'
Local $substring = '123'
Local $nbOccurences

; method 1
StringReplace($string, $substring, $substring)
$nbOccurences = @extended
ConsoleWrite($nbOccurences & @LF)

; method 2
Local $res = StringRegExp($string, $substring, 3)
If @error Then
    $nbOccurences = 0
Else
    $nbOccurences = UBound($res)
Endif
$res = 0        ; you probably don't need that array anymore
ConsoleWrite($nbOccurences & @LF)

[GEOSoft]

$sStr = "This is a string" & @CRLF
$sStr &= "This is another part of the string" & @CRLF
$sStr &= "and one more part with another 'this is' in the string."

StringReplace($sStr, "This is", "")
MsgBox(0, "Result", @Extended & " occurences")

Edit: The same method works using StringRegExpReplace() except that it also allows you to check for substringsstrings starting with one character (or word) and ending in another.

StringRegExpReplace($sStr, "(?i)this.*?string", "")
MsgBox(0, "Result", @Extended & " occurences")

Edited March 31, 2010 by GEOSoft

[jchd]

Isn't that a counterfeit copy of method 1 exposed earlier as prior work?

I hope you layer is a friend of yours

[GEOSoft]

Isn't that a counterfeit copy of method 1 exposed earlier as prior work?

I hope you layer is a friend of yours

And the edit is a counterfeit copy of method #2.

Just chalk it up to great minds and all that.

And I certainly won't be claiming my versions as intelectual property. That alone would suggest some intelect.

Edited March 31, 2010 by GEOSoft

[jchd]

You're right Georges. My intent in supplying both ways was in the hope the OP would ask about which method to use. It depends of the context: short strings will be certainly faster with straight StringReplace, but that advantage will shrink as the target string gets bigger and, above all, how many replaces are going to occur.

The regexp will keep on looking in the original copy while StringReplace will have to remove $SubString at every match, then start over where it left.

Some weeks ago, I wanted to check how many items were listed on some webpage. Looking at the source, I easily found an html pattern introducing each item. I cranked up a regexp and it gave 393781 occurences. Doing the same with StringReplace would have taken ages.

Also I choose to propose a "do nothing" replace to gain advantage in the (unlikely) case that the developper anticipated the "count substrings" use and placed code to avoid duplication in case of "nop" replace.

Finally, as your edit shows, the regexp can implement possibly complex conditions for matching that StringReplace is obviously unable to check.