for to next

[Necromorph]

i don't really understand how to use this yet, im trying to figure it out. i want to read every 6th line of a text doc till i reach the end, which could be any given length. how do i do this

$log = @ScriptDir & "\test.txt"

For $x = 1 to $log[0] Step 6

FileReadLine($log, $x)

Next

i just don't get it, im sure this is way off. thanks for the help.

[AdmiralAlkex]

Oh come on now, @ScriptDir & "\test.txt" is not a number

Edit: Nor an array, what are you thinking with?

Edited April 9, 2010 by AdmiralAlkex

[BugFix]

You must check Ubound:

Use _FileCountLines.

For $x = 1 to $log[0] Step 6
    FileReadLine($log, $x)
    If $x + 6 > $log[0] Then ExitLoop
Next

Edited April 9, 2010 by BugFix

[Melba23]

redLabel,

I would do it this way:

$hFile = FileOpen(@ScriptDir & "\Test.txt")

$iCount = 1

While 1

    $sText = FileReadLine($hFile)
    If @error Then ExitLoop

    If Mod($iCount, 6) = 0 Then ConsoleWrite($sText & @CRLF)

    $iCount += 1

WEnd

FileClose($hFile)

Why? Because if you give a line number to FileReadLine, it reads through the whole file each time to get up to that line. Can you imagine how long that would take if the file is a biggie?

Much better to let AutoIt read through the file a line at a time - which it does automatically - and then just extract every 6th line like the code above!

I hope the explanation is clear - ask again if not.

M23

[Necromorph]

@melba23

thank you very much for your help, works perfect!!

[Necromorph]

actually i have a little more to this i need help on. here is a n example text file i am reading from

<Start>

totaltime: 0.5 hours date: 2010/04/05

starttime: 04:00 PM endtime: 04:30 PM

company:

user:

tasks completed: Quickbooks file locked for editing issue

totaltime: 1 hours date: 2010/04/05

starttime: 04:30 PM endtime: 05:00 PM

company:

user: none

tasks completed: Work on server rack drawing.

totaltime: 1.5 hours date: 2010/04/05

starttime: 05:00 PM endtime: 06:00 PM

company:

user: none

tasks completed: Work on server2, RAID crashed.

<End>

here is my script (thanks again)

$hFile = FileOpen(@ScriptDir & "\Testlog.txt")

$iCount = 5

While 1

    $xLeft = StringTrimLeft(FileReadLine($hFile), 11)
    $xRight = StringTrimRight($xLeft, 18)
    $xHours = Number($xLeft)

    If Mod($iCount, 6) = 0 Then MsgBox(0, "", $xHours & @CRLF)

    $iCount += 1

WEnd

FileClose($hFile)

basiacally i want to add all the "total hours" up. can i list it to an array and do it? thanks again!!

Edited April 9, 2010 by redLabel

[Melba23]

redLabel,

I should start charging.......

Try this:

#Include <String.au3>

$hFile = FileOpen(@ScriptDir & "\Test.txt")

$iCount = 1
$nHours = 0

While 1

    $sText = FileReadLine($hFile)
    If @error Then ExitLoop

    If Mod($iCount, 6) = 1 Then ; Adjust this value to match the 1-based line of the first "totaltime" line
        $aHours = _StringBetween($sText, "totaltime: ", "hours")
        $nHours += Number($aHours[0])
    EndIf

    $iCount += 1

WEnd

FileClose($hFile)

MsgBox(0, "Total", $nHours, 1)

You will need to adjust the figure in the Mod line as explained.

M23

[Necromorph]

thanks again, but i get an error in regaurds to the $nHours += Number($aHours[0])

it says that 'Subscript used with non-array Variable;==>

not sure what that means exactly. thanks again.

[Melba23]

redLabel,

I did tell you that you might need to adjust the Mod check value:

#Include <String.au3>

$hFile = FileOpen(@ScriptDir & "\Test.txt")

$iCount = 1
$nHours = 0

While 1

    $sText = FileReadLine($hFile)
    If @error Then ExitLoop

    If Mod($iCount, 6) = 1 Then
        ; Adjust the "1" in the line above until you get the "totaltime" lines appearing in the SciTE console
        ; Then remove this ConsoleWrite line
        ConsoleWrite($sText & @CRLF)
        ; And uncomment these 2 lines
        ;$aHours = _StringBetween($sText, "totaltime: ", "hours")
        ;$nHours += Number($aHours[0])
    EndIf

    $iCount += 1

WEnd

FileClose($hFile)

MsgBox(0, "Total", $nHours, 1)

You have to do some work yourself, you know!

M23

[Necromorph]

sorry, about all this, i just didn't understand how your script was working, and i also didn't know that you can output with the "consolewrite" function like that, but now i understand what is happening. thank you again.

[Melba23]

redLable,

i just didn't understand how your script was working

Then do please ask for an explanation.

Just plugging a chunk of code into your script without understanding what is going on can only lead to trouble in the long-term.

M23