[SOLVED] _GUICtrlListView_Create() and Highlight Indivdual Items

[guinness]

OK, I have a couple of questions with Searching and ListViews, I have tried to search the forum and found a UDF titled FormatSubItemLV, but I received an error when I ran it.

So, my question(s) is when an item is found in the ListView, is it possible to highlight the found item with a normal blue highlight rather than the grey highlight currently shown. Found this, but is there anything less complicated?

2. Change the text colour of the highlighted item found.

3. Show the found item at the top of the ListView Windows (not move the item, but highlight to the top, at present you can see items above and below the found text.)

I very much appreciate anyones help.

expandcollapse popup

#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <GuiListView.au3>
$iI = 0

$hGUI = GUICreate("Test", 400, 200, -1, -1, -1, $WS_EX_ACCEPTFILES)
$hLV = _GUICtrlListView_Create($hGUI, "", 5, 5, 390, 150, BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($hLV, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_BORDERSELECT))
_GUICtrlListView_InsertColumn($hLV, 0, "Column 1", 120)
$hFind = GUICtrlCreateInput("", 5, 160, 90, 20)
$hFind_Button = GUICtrlCreateButton("", 100, 160, 20, 20)
GUISetState(@SW_SHOW)

For $i = 1 To 50
    _GUICtrlListView_AddItem($hLV, "Line Number " & $i)
Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hFind_Button
            _GetFocus()
            $iI = _GUICtrlListView_FindInText($hLV, GUICtrlRead($hFind), $iI, True, False)
            If $iI <> -1 Then
                _GUICtrlListView_SetItemState($hLV, $iI, $LVIS_SELECTED, $LVIS_SELECTED)
                _GUICtrlListView_EnsureVisible($hLV, $iI, True)
                Sleep(75)
            Else
                MsgBox(0, "Finished", "Completed Search.")
            EndIf
    EndSwitch
WEnd

Func _GetFocus() ; This clears any selected items on the ListView.
    $A = _GUICtrlListView_GetSelectedIndices($hLV, True)
    For $B = 1 To $A[0]
        _GUICtrlListView_SetItemState($hLV, $A[$B], 0, $LVIS_SELECTED)
    Next
EndFunc   ;==>_GetFocus

Edited April 29, 2010 by guinness

[Melba23]

guinness,

A bit "kludgy", but it seems to work:

expandcollapse popup

#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <GuiListView.au3>
$iI = 0

$hGUI = GUICreate("Test", 400, 200, -1, -1, -1, $WS_EX_ACCEPTFILES)
$hLV = _GUICtrlListView_Create($hGUI, "", 5, 5, 390, 150, BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($hLV, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_BORDERSELECT))
_GUICtrlListView_InsertColumn($hLV, 0, "Column 1", 120)
$hFind = GUICtrlCreateInput("", 5, 160, 90, 20)
$hFind_Button = GUICtrlCreateButton("", 100, 160, 20, 20)
GUISetState(@SW_SHOW)

For $i = 1 To 50
    _GUICtrlListView_AddItem($hLV, "Line Number " & $i)
Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hFind_Button
            $iI = _GUICtrlListView_FindInText($hLV, GUICtrlRead($hFind), $iI, True, False)
            If $iI <> -1 Then
                _GUICtrlListView_EnsureVisible($hLV, $iI, True)
                $aPos = WinGetPos($hGUI)
                $tRect = _GUICtrlListView_GetItemRectEx($hLV, $iI)
                $iX = DllStructGetData($tRect, "Left")
                $iY = DllStructGetData($tRect, "Top")
                $aMousePos = MouseGetPos()
                MouseClick("left", $iX + $aPos[0] + 15, $iY + $aPos[1] + 30, 1, 0)
                MouseMove($aMousePos[0], $aMousePos[1], 0)
                $iTop = _GUICtrlListView_GetTopIndex($hLV)
                While $iTop <> $iI
                    _GUICtrlListView_Scroll($hLV, 0, 10)
                    $iTop = _GUICtrlListView_GetTopIndex($hLV)
                WEnd
            Else
                MsgBox(0, "Finished", "Completed Search.")
            EndIf
    EndSwitch
WEnd

I hope that helps a bit.

M23

[guinness]

A bit "kludgy", but it seems to work:

That's prefect, works really well. It's a little insight into how you sometimes have to think outside the box. Your help was much appreciated. Also I got the inspiration from one of your posts many months ago.