StringSize

[trancexx]

Subtitle doesn't make sense, don't try to find one.

Seems everyone has a version of this function.

Here's another one. This one is trick free and it's mine, mine, mine...

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

#include <WinAPI.au3>

; Make GUI
GUICreate("StringSize", 600, 400)
GUISetBkColor(0) ; black magic GUI

; First example:
Global $sLabelText = "Pa Da Pam Pam..."
Global $aLabelTextSize = _StringSize($sLabelText, 14)
GUICtrlCreateLabel($sLabelText, 10, 20, $aLabelTextSize[0], $aLabelTextSize[1]) ; create label in calculated size
GUICtrlSetFont(-1, 14) ; set wanted font
GUICtrlSetBkColor(-1, 0xFFFFFF) ; make the background white

; Print size
ConsoleWrite($aLabelTextSize[0] & " x " & $aLabelTextSize[1] & @CRLF)

; Secand example:
$sLabelText = "abcdehmma"
$aLabelTextSize = _StringSize($sLabelText, 60, 800)
GUICtrlCreateLabel($sLabelText, 10, 80, $aLabelTextSize[0], $aLabelTextSize[1]) ; create label in calculated size
GUICtrlSetFont(-1, 60, 800) ; set wanted font
GUICtrlSetBkColor(-1, 0xFFFFFF) ; make the background white

; Print size
ConsoleWrite($aLabelTextSize[0] & " x " & $aLabelTextSize[1] & @CRLF)

; Third example:
$sLabelText = "First line of the text" & @LF & "Second line of the text" & @CRLF & "Third line of the text" & @CRLF & "Fourth line of the text. See ya!"
$aLabelTextSize = _StringSize($sLabelText, 17, 700, 2, "Tahoma", 4)
GUICtrlCreateLabel($sLabelText, 10, 220, $aLabelTextSize[0], $aLabelTextSize[1]) ; create label in calculated size
GUICtrlSetFont(-1, 17, 700, 2, "Tahoma", 4) ; set wanted font
GUICtrlSetBkColor(-1, 0xFFFFFF) ; make the background white

; Print size
ConsoleWrite($aLabelTextSize[0] & " x " & $aLabelTextSize[1] & @CRLF)

; Show GUI
GUISetState()
; Wait for the exit
While GUIGetMsg() <> -3
WEnd


; FUNCTION
Func _StringSize($sText, $iSize = 8.5, $iWeight = 400, $iAttrib = 0, $sName = "", $iQuality = 2)
    Local Const $LOGPIXELSY = 90
    Local $fItalic = BitAND($iAttrib, 2)
    Local $hDC = _WinAPI_GetDC(0)
    Local $hFont = _WinAPI_CreateFont(-_WinAPI_GetDeviceCaps($hDC, $LOGPIXELSY) * $iSize / 72, 0, 0, 0, $iWeight, $fItalic, BitAND($iAttrib, 4), BitAND($iAttrib, 8), 0, 0, 0, $iQuality, 0, $sName)
    Local $hOldFont = _WinAPI_SelectObject($hDC, $hFont)
    Local $tSIZE
    Local $iWidth = 0, $iHeight = 0
    Local $aArrayOfStrings = StringSplit(StringStripCR($sText), @LF, 2)
    For $sString In $aArrayOfStrings
        If $fItalic Then $sString &= " "
        $tSIZE = _WinAPI_GetTextExtentPoint32($hDC, $sString)
        If DllStructGetData($tSIZE, "X") > $iWidth Then $iWidth = DllStructGetData($tSIZE, "X")
        $iHeight += DllStructGetData($tSIZE, "Y")
    Next
    _WinAPI_SelectObject($hDC, $hOldFont)
    _WinAPI_DeleteObject($hFont)
    _WinAPI_ReleaseDC(0, $hDC)
    Local $aOut[2] = [$iWidth, $iHeight]
    Return $aOut
EndFunc   ;==>_StringSize

You calculate the size of the string considering the font and make the label in that size. That's it.

edit: edit

Edited May 6, 2010 by trancexx

[lsakizada]

Works perfect! great work.

Very usefull not only for labels.

[Yashied]

2nd example

[trancexx]

When you manage to find the cause of that don't forget to post the solution.

I'm clueless.

[KaFu]

Just from the looks it seems like the font on the screenshot is painted with quality = 5, a little blurry... Yashied, maybe adjust the quality setting in _StringSize() and retry. trancexx, maybe this is a system specific setting? Saw a function floating around to aquire the system's font default setting, should this be taken into account?

Edit:

I would recommand following steps to make it OS/Font independant:

- Create Control

- Set Font

- Set Control Size with _StringSize(), where _StringSize() should read the actual font settings used by the control.

Edited May 6, 2010 by KaFu

[trancexx]

Just from the looks it seems like the font on the screenshot is painted with quality = 5, a little blurry... Yashied, maybe adjust the quality setting in _StringSize() and retry. trancexx, maybe this is a system specific setting? Saw a function floating around to aquire the system's font default setting, should this be taken into account?

Edit:

I would recommand following steps to make it OS/Font independant:

- Create Control

- Set Font

- Set Control Size with _StringSize(), where _StringSize() should read the actual font settings used by the control.

Yes, but that's defeating the main purpose of why I posted this.

Anyway, _WinAPI_CreateFont() function seems to be the cause of problems. It has $szFace = 'Arial' as the last parameter. AutoIt on the other hand is using empty string as default.

Edited May 6, 2010 by trancexx

[Yashied]

AutoIt on the other hand is using empty string as default.

It seems "MS Shell Dlg" or font that is defined by theme. Edited May 6, 2010 by Yashied

[slayerz]

Great example...thanks trancexx

[Mat]

If Melba is reading this, this is exactly what I was hinting at. No GUI's, just api.

Well done

[Melba23]

Of course Melba23 is reading this!

This shows the gulf between a hobbyist coder like me and a real programmer - vast!

Nice example trancexx.

M23

Edit: There is one difference though, my version will wrap the text for you to fit an designated width - you do not have to preformat with @CRLFs, the UDF does it for you.

Edited May 6, 2010 by Melba23

[Mat]

Of course Melba23 is reading this!

This shows the gulf between a hobbyist coder like me and a real programmer - vast!

Nice example trancexx.

M23

Edit: There is one difference though, my version will wrap the text for you to fit an designated width - you do not have to preformat with @CRLFs, the UDF does it for you.

I'm fairly sure that with a little editing trancexx will be able to figure it out

There is one more difference though... I can understand what goes on in your code

[Melba23]

Mat,

There is one more difference though... I can understand what goes on in your code

Too true!

M23

[trancexx]

I'm not a real programmer Melba23.

@Yashied, could you try replacing _WinAPI_GetDC(0) with

_WinAPI_GetDC(_WinAPI_GetDesktopWindow())

And if that doesn't work then with the gui handle.

Edited May 6, 2010 by trancexx

[Melba23]

trancexx,

I'm not a real programmer Melba23

You could have fooled me!

Would you accept "very talented coder"?

M23

[Mat]

You could have fooled me!

Would you accept "very talented coder"?

'REAL' programmers are something different... http://www.pbm.com/~lindahl/real.programmers.html etc.

[trancexx]

trancexx,

You could have fooled me!

Would you accept "very talented coder"?

M23

I would.

You have to see my other talents...

Sometimes I replace barcode stamps on the fruits in the grocery, steal a snickers even. I can say I'm very talented in different areas.

Tell no one about that. It's kinda of a secret.

[Melba23]

trancexx,

Sometimes I replace barcode stamps on the fruits in the grocery

You devil, you!

M23

[trancexx]

Have you ever done that?

[TheSaint]

@trancexx - If you are not indulging in a bit of leg pull, then you are obviously a gal after my own heart. However, I would suggest you give up the habit, and indulge in other things that are still exciting ... but only embarrassing when you eventually get caught or found out. Take it from one that was lucky enough to learn in time!