How to limit possible input?

[KoZuEst]

I'm trying to use an input box to let the user type in two numbers. Is there a way to let the user type in ONLY numbers and ONLY two of them? Or is there a sure way of making sure that the typed symbols are numbers? Using Number() returns 0 in case of letters but can I distinguish this from a typed zero? Help appreciated.

Edited May 6, 2010 by KoZuEst

[Fire]

Hi KoZuEst.

Glad to see you

$hInput = GUICtrlCreateInput("", 128, 88, 361, 21, BitOR($ES_AUTOHSCROLL,$ES_NUMBER))
GUICtrlSetLimit(-1,2)

[KoZuEst]

Perfect! Thank you

[Catavitch]

Is there anyway to limit the input to alpha characters only.

Like ES_text or something like that?

[Melba23]

Catavitch,

Like ES_text or something like that?

Alas, not that easy!

But not that difficult either. Here are 2 ways to do it - firstly by polling in the While...WEnd loop:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hInput = GUICtrlCreateInput ("", 10, 10, 300, 20)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If _GUICtrlEdit_GetModify($hInput_Handle) Then GUICtrlSetData($hInput, StringRegExpReplace(GUICtrlRead($hInput), "(?i)[^a-z]", ""))

WEnd

And now using GUIRegisterMessage:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hInput = GUICtrlCreateInput ("", 10, 10, 300, 20)

GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    If BitAND($wParam, 0xFFFF) = $hInput And BitShift($wParam, 16) = $EN_CHANGE Then GUICtrlSetData($hInput, StringRegExpReplace(GUICtrlRead($hInput), "(?i)[^a-z]", ""))

EndFunc;==>_WM_COMMAND

Happy?

M23

[GEOSoft]

Another SRE that will do it

"[^[:alpha:]]"

Using the loop method posted by Big M

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If StringRegExp(GUICtrlRead($hInput), "[^[:alpha:]]") Then GUICtrlSetData($hInput, StringRegExpReplace(GUICtrlRead($hInput), "[^[:alpha:]]", ""))

WEnd

Edited December 9, 2010 by GEOSoft