Cannot set colour in group control item.

[iorih0406]

Hi,

I wonder that why I cannot control group's colour.

Please see my code as below,

$Progress       = GUICtrlCreateGroup("Progress", 40, 130, 470, 50)
GUICtrlSetColor(-1, 0xFFFFFF)

After I read AutoIT help document, It describes "GUICtrlSetColor" supported group of control item.

Somehow I don't let the colour becomes white.

Thanks in advance.

[bogQ]

GUICtrlSetColor ( controlID, textcolor)

Do you try to tell that it do not set "Progress" text in to white color?

Checkbox, Radio, Group or Progress controls cannot be painted if the "Windows XP/Vista style" is used.

[VAN0]

GUICtrlSetColor ( controlID, textcolor)

Do you try to tell that it do not set "Progress" text in to white color?

I can confirm, the text color not being changed. In fact the only style I could manage to change is the font size, font/background colors stay default no matter what...

[Melba23]

VAN0,

You need to remove the Theme from the control if you want to change the text colour - but then you might not like the visual style of teh control:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)
GUISetBkColor(0xC4FFC4, $hGUI)

$hGroup_1 = GUICtrlCreateGroup("Group 1", 10, 10, 480, 200)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0xFF0000)

$hGroup_2 = GUICtrlCreateGroup("Group 2", 10, 210, 480, 200)
; Remove Style from control
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($hGroup_2), "wstr", 0, "wstr", 0)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0xFF0000)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Your choice!

M23

[VAN0]

@Melba23: is there anything you don't know? Your are amazing

The style doesn't look that much different, just border is darker...is there a way make text style the same as border style, aka "disabled" with white outline, so it look like it's "pressed in" into gui?

P.S.

I guess information about removing theme is missing from the help file?

[Melba23]

VAN0,

is there anything you don't know?

I am just a hobbyist - you should see what the real coders around here can do!

is there a way make text style the same as border style, aka "disabled"

Did you think of disabling it?

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)
GUISetBkColor(0xC4FFC4, $hGUI)

$hGroup_1 = GUICtrlCreateGroup("Group 1", 10, 10, 480, 200)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0xFF0000)

$hGroup_2 = GUICtrlCreateGroup("Group 2", 10, 210, 480, 200)
; Remove Style from control
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($hGroup_2), "wstr", 0, "wstr", 0)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0xFF0000)
GUICtrlSetState(-1, $GUI_DISABLE) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

guess information about removing theme is missing from the help file?

Note that it took a DLLCall, not a built-in Autoit command, to remove the style - you cannot expect the Help file to hold info on every DLL call!

M23

[lhw]

so sweet! hope i can write something like this someday