Start and Stop(exit) script with GUI, problem.

[duzers]

Hello,

I want to Start script and Exit script with GUI, but when I click Start, button Exit (X) not work.

how can I stop the running script?

I used OnEventmode.

It is sample code:

#include <GUIConstantsEx.au3>
Sleep(1000)

Opt("GUIOnEventMode", 1)

GUICreate("OnEvent test", 230, 120)
GUISetOnEvent($GUI_EVENT_CLOSE, "ExitProgram")
$button = GUICtrlCreateButton("Start", 10, 40, 100)
GUICtrlSetOnEvent($button , "button")
GUISetState(@SW_SHOW)


While 1
sleep(40)
WEnd

Func button()
    sleep(20000)
    ;work...
    ;work...
    ;work firefox with FF, autologins, writes, sets other things...
endfunc

Func Exitprogram()
  MsgBox(0, "exit", "exit")
  Exit
EndFunc

thx

Edited May 17, 2010 by duzers

[Realm]

duzers, I'm not sure what your attempting, and I'm no pro, but I think this is what your looking for. Try this

#include <GUIConstantsEx.au3>
Sleep(1000)

Opt("GUIOnEventMode", 1)

GUICreate("OnEvent test", 230, 120)
GUISetOnEvent($GUI_EVENT_CLOSE, "ExitProgram")
$button = GUICtrlCreateButton("Start", 10, 40, 100)
GUICtrlSetOnEvent($button , "button")
GUISetState(@SW_SHOW)


While 1
$nMsg = GUIGetMsg()
Switch $nMsg
    Case $GUI_EVENT_CLOSE
        Exit
    Case $button
        button()
EndSwitch
WEnd

Func button()
    sleep(20000)
    ;work...
    ;work...
    ;work firefox with FF, autologins, writes, sets other things...
endfunc

Edited May 17, 2010 by Realm

[duzers]

No, It's not this. I want exit even if sleep(20000) work.

[Realm]

Sorry, I forgot to take out the on event code stuff, this will work now:

#include <GUIConstantsEx.au3>
Sleep(1000)

GUICreate("OnEvent test", 230, 120)
$button = GUICtrlCreateButton("Start", 10, 40, 100)
GUISetState()


While 1
 $msg = GUIGetMsg()

 Select
    Case $msg = $button
    button()

    Case $msg = $GUI_EVENT_CLOSE
    Exit
 EndSelect
WEnd

Func button()
    sleep(20000)
    ;work...
    ;work...
    ;work firefox with FF, autologins, writes, sets other things...
endfunc

Edited May 17, 2010 by Realm

[Jos]

Example that should work:

#include <GUIConstantsEx.au3>

Global $StartPressed = 0
Opt("GUIOnEventMode", 1)

GUICreate("OnEvent test", 230, 120)
GUISetOnEvent($GUI_EVENT_CLOSE, "ExitProgram")
$button = GUICtrlCreateButton("Start", 10, 40, 100)
GUICtrlSetOnEvent($button, "ButtonPressed")
GUISetState(@SW_SHOW)
;
While 1
    If $StartPressed Then
        $StartPressed = 0
        Button()
    EndIf
    Sleep(10)
WEnd
;
Func ButtonPressed()
    $StartPressed = 1
EndFunc   ;==>ButtonPressed
;
Func button()
    Sleep(20000)
    ;work...
    ;work...
    ;work firefox with FF, autologins, writes, sets other things...
EndFunc   ;==>button

Func ExitProgram()
    Exit
EndFunc   ;==>ExitProgram

Edited May 17, 2010 by Jos

[duzers]

This is it!. Many thanks.

This should be a standard feature in AutoIt.

[GEOSoft]

This is it!. Many thanks.

This should be a standard feature in AutoIt.

It is, you just have to learn how to use it.

[duzers]

Is there a sample way with this example to Pause/Go script with etc. button2 ?

[Jos]

Is there a sample way with this example to Pause/Go script with etc. button2 ?

Everything is possible when you set your mind to it.

Just think about how to get this done ... The hotkeys could be an option but also a button as long as you ensure you read the GUI messages.

Jos

Edited May 18, 2010 by Jos