Icon to a MenuItem

[Sbarabau]

Hi,

my English isn't perfect so I'm not sure to speak correctly. Forgive me if I'm wrong ^^

So, my current problem is to assign an icon to a MenuItem, icon that is exported correctly from a dll through a function (which I created, tested and classified as working xD)

As long as I draw an icon and I apply for a button or pull it out through the function GUICtrlCreateIcon ok, the problem comes when I assign an icon to a MenuItem through the function _GUICtrlMenu_SetItemBmp

In fact, the icon in question does not appear in the MenuItem.

The help of AutoIt gives the following example:

expandcollapse popup

#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>

Opt('MustDeclareVars', 1)

Global $iMemo

_Main()

Func _Main()
   Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
   Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

   ; Create GUI
   $hGUI = GUICreate("Menu", 400, 300)

   ; Create File menu
   $hFile = _GUICtrlMenu_CreateMenu ()
   _GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
   _GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
   _GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
   _GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
   _GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)

   ; Create Edit menu
   $hEdit = _GUICtrlMenu_CreateMenu ()
   _GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
   _GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
   _GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)

   ; Create Help menu
   $hHelp = _GUICtrlMenu_CreateMenu ()
   _GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)

   ; Create Main menu
   $hMain = _GUICtrlMenu_CreateMenu ()
   _GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
   _GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
   _GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, $hHelp)

   ; Set window menu
   _GUICtrlMenu_SetMenu ($hGUI, $hMain)

   ; Create memo control
   $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
   GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
   GUISetState()

   ; Set New menu item to have a bitmap
   _GUICtrlMenu_SetItemBmp ($hFile, 0, _WinAPI_CreateSolidBitmap ($hGUI, 0xFF0000, 11, 11))
   MemoWrite("Item bitmap handle: 0x" & Hex(_GUICtrlMenu_GetItemBmp ($hFile, 0)))

   ; Loop until user exits
   Do
   Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Write message to memo
Func MemoWrite($sMessage)
   GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

Here appears a solid next to the text of the MenuItem, solid created by the function _WinAPI_CreateSolidBitmap

This is the function that I created for extract the icon to read from a dll (it is the classic function _WinAPI_LoadShell32Icon slightly modified), but, as I wrote, the icon doesn't appear.

Func Leggi_Dll ($Dll, $iIconID)
       Local $tIcons = DllStructCreate("ptr Data")
       Local $pIcons = DllStructGetPtr($tIcons)
       Local $iIcons = _WinAPI_ExtractIconEx($Dll, Number ($iIconID) - 1, 0, $pIcons, 1)
       Return DllStructGetData($tIcons, "Data")
EndFunc

Can you help me?

[kaotkbliss]

I could be wrong, but I'm sure I remember reading you can't set an icon (.ico) as a bitmap (.bmp) you must use correct functions with correct file types.

[GEOSoft]

You may also want to take a look at the Menu Icon UDF by Holger.

[Sbarabau]

I could be wrong, but I'm sure I remember reading you can't set an icon (.ico) as a bitmap (.bmp) you must use correct functions with correct file types.

There is no way to use files. ico as an icon for the MenuItem?

You may also want to take a look at the Menu Icon UDF by Holger.

Thanks but I've already seen that UDF

I'd like to add only the icon, and not the colors and styles other than the default

Edited June 9, 2010 by Sbarabau

[UEZ]

Have a look here: http://www.autoitscript.com/forum/index.php?showtopic=115491&view=findpost&p=806834

It might help you!

BR,

UEZ

[Sbarabau]

Have a look here: #806834

It might help you!

BR,

UEZ

Thank you very much!

It works perfectly!

[Sbarabau]

I have a small problem: I load the icon from a dll file using the function that I wrote before.

The icon isn't displayed properly, and instead appears the icon of an unknown file.

How can I resolve this problem?

[UEZ]

Maybe the icon id is wrong!

I modified my code a little bit:

expandcollapse popup

#include <GDIPlus.au3>
#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <WinAPIEx.au3>
#include <WindowsConstants.au3>
#Include <Constants.au3>
Global $iMemo


$file = FileOpenDialog("Select file", @ScriptDir, ("Icons from (*.ico; *.dll; *.exe)"))

If @error Then Exit
$iIndex = 0
$Ret = DllCall("shell32", "long", "ExtractAssociatedIcon", "int", 0, "str", $file, "int*", $iIndex)
$hIcon = $Ret[0]

_GDIPlus_Startup()
$hImage = DllCall($ghGDIPDll,"int", "GdipCreateBitmapFromHICON", "ptr", $hIcon, "int*", 0)
$hImage = $hImage[2]
_WinAPI_DestroyIcon($hIcon)

$iWidth = 16
$iHeight = 16
$hBitmap = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
$hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsDrawImageRect($hContext, $hImage, 0, 0, $iWidth, $iHeight)
$hIcon = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)

_Main()

_GDIPlus_GraphicsDispose($hContext)
_WinAPI_DeleteObject($hIcon)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_Shutdown()

Exit


Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; Create GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Create File menu
    $hFile = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
    _GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
    _GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
    _GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)

    ; Create Edit menu
    $hEdit = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)

    ; Create Help menu
    $hHelp = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)

    ; Create Main menu
    $hMain = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, $hHelp)

    ; Set window menu
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)

    ; Create memo control
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Set New menu item to have a bitmap
    _GUICtrlMenu_SetItemBmp ($hFile, 0, $hIcon)
    MemoWrite("Item bitmap handle: 0x" & Hex(_GUICtrlMenu_GetItemBmp ($hFile, 0)))

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main

; Write message to memo
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite

Func _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight, $iStride = 0, $iPixelFormat = 0x0026200A, $pScan0 = 0)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iWidth, "int", $iHeight, "int", $iStride, "int", $iPixelFormat, "ptr", $pScan0, "int*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    $GDIP_STATUS = $aResult[0]
    Return $aResult[6]
EndFunc ;==>_GDIPlus_BitmapCreateFromScan0

Change $iIndex to get the desired icon displayed!

BR,

UEZ

Edited June 9, 2010 by UEZ

[Sbarabau]

Maybe the icon id is wrong!

I modified my code a little bit:

expandcollapse popup

#include <GDIPlus.au3>
#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <WinAPIEx.au3>
#include <WindowsConstants.au3>
#Include <Constants.au3>
Global $iMemo


$file = FileOpenDialog("Select file", @ScriptDir, ("Icons from (*.ico; *.dll; *.exe)"))

If @error Then Exit
$iIndex = 0
$Ret = DllCall("shell32", "long", "ExtractAssociatedIcon", "int", 0, "str", $file, "int*", $iIndex)
$hIcon = $Ret[0]

_GDIPlus_Startup()
$hImage = DllCall($ghGDIPDll,"int", "GdipCreateBitmapFromHICON", "ptr", $hIcon, "int*", 0)
$hImage = $hImage[2]
_WinAPI_DestroyIcon($hIcon)

$iWidth = 16
$iHeight = 16
$hBitmap = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
$hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsDrawImageRect($hContext, $hImage, 0, 0, $iWidth, $iHeight)
$hIcon = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)

_Main()

_GDIPlus_GraphicsDispose($hContext)
_WinAPI_DeleteObject($hIcon)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_Shutdown()

Exit


Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; Create GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Create File menu
    $hFile = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
    _GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
    _GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
    _GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)

    ; Create Edit menu
    $hEdit = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)

    ; Create Help menu
    $hHelp = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)

    ; Create Main menu
    $hMain = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, $hHelp)

    ; Set window menu
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)

    ; Create memo control
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Set New menu item to have a bitmap
    _GUICtrlMenu_SetItemBmp ($hFile, 0, $hIcon)
    MemoWrite("Item bitmap handle: 0x" & Hex(_GUICtrlMenu_GetItemBmp ($hFile, 0)))

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main

; Write message to memo
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite

Func _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight, $iStride = 0, $iPixelFormat = 0x0026200A, $pScan0 = 0)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iWidth, "int", $iHeight, "int", $iStride, "int", $iPixelFormat, "ptr", $pScan0, "int*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    $GDIP_STATUS = $aResult[0]
    Return $aResult[6]
EndFunc ;==>_GDIPlus_BitmapCreateFromScan0

Change $iIndex to get the desired icon displayed!

BR,

UEZ

This code works perfectly and i haven't any kind of problem.

Thank you! ^^