Get position of control to the screen?

[Bot]

Hello,

I know that the function ControlGetPos can retrieve the position of the control relative to it's window but are there any way to get this to the screen? Thanks.

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 623, 449, -1, -1)
$Input1 = GUICtrlCreateInput("Input1", 8, 8, 609, 21)
GUISetState(@SW_SHOW)

$pos = ControlGetPos("Form1", "", "[CLASS:Edit; INSTANCE:1]")
MsgBox(0, "Window Stats:", "POS: " & $pos[0] & "," & $pos[1] & " SIZE: " & $pos[2] & "," & $pos[3] )

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[Yoriz]

Hows this ?

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 623, 449, -1, -1)
$Input1 = GUICtrlCreateInput("Input1", 8, 8, 609, 21)
GUISetState(@SW_SHOW)

$pos = ControlGetPos("Form1", "", "[CLASS:Edit; INSTANCE:1]")
MsgBox(0, "Window Pos Stats:", "POS: " & $pos[0] & "," & $pos[1] & " SIZE: " & $pos[2] & "," & $pos[3])
$iWinPos = WinGetPos("Form1")
$iClientSize = WinGetClientSize("Form1")
Global $aScreenPos[2] = [$iWinPos[0] + $pos[0] + ($iWinPos[2] - $iClientSize[0]), $iWinPos[1] + $pos[1] + ($iWinPos[3] - $iClientSize[1])]

MsgBox(0, "Screen Pos Stats:", "POS: " & $aScreenPos[0] & "," & $aScreenPos[1] & " SIZE: " & $pos[2] & "," & $pos[3])
MouseClickDrag("Left", $aScreenPos[0], $aScreenPos[1] + $pos[3] / 2, $aScreenPos[0] + 5, $aScreenPos[1] + $pos[3] / 2)
Send("{RIGHT} side of the in")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[Melba23]

Bot,

Or this:

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

$hLabel = GUICtrlCreateLabel("Here", 10, 10, 80, 30)
GUICtrlSetBkColor(-1, 0xFFCCCC)

$hButton = GUICtrlCreateButton("Coords", 10, 50, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            $aPos = ControlGetPos($hGUI, "", $hLabel)
            MsgBox(0, "Position", "Relative to GUI:" & @CRLF & $aPos[0] & " - " & $aPos[1])
            $tPoint = DllStructCreate("int X;int Y")
            DllStructSetData($tpoint, "X", $aPos[0])
            DllStructSetData($tpoint, "Y", $aPos[1])
            _WinAPI_ClientToScreen($hGUI, $tPoint)
            MsgBox(0, "Position", "Relative to Screen:" & @CRLF & DllStructGetData($tpoint, "X") & " - " & DllStructGetData($tpoint, "Y"))
    EndSwitch

WEnd

Move the GUI around and see how the results change!

M23

[Bot]

I have tried and both are working flawlessly. Thank you so much for your help The example of Yoriz is so funny too Edited June 10, 2010 by Bot

[AdmiralAlkex]

You all forgot WinGetPos

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 320, 160)

$hLabel = GUICtrlCreateLabel("Here", 10, 10, 80, 30)
GUICtrlSetBkColor(-1, 0xFFCCCC)
$hLabelh = GUICtrlGetHandle($hLabel)

$hButton = GUICtrlCreateButton("Coords", 10, 50, 80, 30)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            $aPos = ControlGetPos($hGUI, "", $hLabel)
            MsgBox(0, "Position", "Relative to GUI:" & @CRLF & $aPos[0] & " - " & $aPos[1])
            $aPos = WinGetPos($hLabelh)
            MsgBox(0, "Position", "Relative to Screen:" & @CRLF & $aPos[0] & " - " & $aPos[1])
    EndSwitch
WEnd

[Melba23]

AdmiralAlkex,

How did we miss that?

Thanks!

M23