Using AutoIT on Windows 7

[soporific]

Hi there,

I have searched for a while to see if there is anything on why i am missing the compile option from the right-click menu on my Win7 Pro system. I couldn't find anything

I have used AutoIT on Windows XP for years now and have got very used to compiling without opening the file in the editor. It is only one extra action to open the file and choose compile from the tools menu, but curiosity is getting the better of me and so i am asking the question here. Why is 'compile' missing from my right-click menu?

Any thoughts appreciated.

Sop.

[GEOSoft]

First guess would be that the AutoIt installer doesn't have the permissions required to write that key. I ran into the same thing adding an entry for .chm files.

[Skruge]

It works fine for me, both on 32-bit and 64-bit Win7 Pro.

Have you tried reinstalling SciTE4AutoIt? Try forcing setup to run elevated.

[soporific]

Thanks for the quick replies.

I have 32-bit Win7 and i have tried reinstalling SciTE4AutoIt running the setup as administrator with no luck. I am using an admin profile anyway but i thought i'd try.

The only other thing i can add is that when i initially couldn't open an au3 script in the editor by default, i choose to open with notepad. Then i fixed the association to get them to open with the editor. But uninstalling and re-installing doesn't change anything with regard to the compile option.

This is only a small thing but it would be good to fix. Thanks again!

EDIT: if someone wants to work out what a quick REG file solution would be to add the compile option to my menu, i would be forever grateful

Edited June 24, 2010 by soporific

[jiglei]

I'm using win7 ultimate and works pretty fine, though i don't even use that option, since when i want to compile the script, they are already in the scite editor lol.

[GEOSoft]

Here is my registry entries. You will have to adjust the paths as necessisary for your system.

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\AutoIt3Script]

@="AutoIt v3 Script"

[HKEY_CLASSES_ROOT\AutoIt3Script\DefaultIcon]

@="C:\\Program Files\\AutoIt3\\Icons\\au3script_v10.ico"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell]

@="Edit"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Compile]

@="Compile Script"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Compile\Command]

@="\"C:\\Program Files\\AutoIt3\\Aut2Exe\\Aut2Exe.exe\" /in \"%l\""

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Compile with Options]

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Compile with Options\Command]

@="\"C:\\Program Files\\AutoIt3\\SciTE\\AutoIt3Wrapper\\AutoIt3Wrapper.exe\" /ShowGui /in \"%l\""

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Edit]

@="Edit Script"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Edit\Command]

@="\"C:\\Program Files\\AutoIt3\\SciTE\\SciTE.exe\" \"%1\""

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Open]

@="Open"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Open\Command]

@="\"C:\\Program Files\\AutoIt3\\SciTE\\SciTE.exe\" \"%1\""

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Run]

@="Run Script"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Run\Command]

@="\"C:\\Program Files\\AutoIt3\\AutoIt3.exe\" \"%1\" %*"

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Tidy]

[HKEY_CLASSES_ROOT\AutoIt3Script\Shell\Tidy\Command]

@="\"C:\\Program Files\\AutoIt3\\SciTE\\Tidy\\Tidy.exe\" \"%1\""

[soporific]

Thanks for that REG file fix, it didn't work but it gives me something to go on with, i have set context menu entries myself in the past and im sure i can get it. Thanks again

[PC2012]

Hi there,

I have searched for a while to see if there is anything on why i am missing the compile option from the right-click menu on my Win7 Pro system. I couldn't find anything

I have used AutoIT on Windows XP for years now and have got very used to compiling without opening the file in the editor. It is only one extra action to open the file and choose compile from the tools menu, but curiosity is getting the better of me and so i am asking the question here. Why is 'compile' missing from my right-click menu?

Any thoughts appreciated.

Sop.

Win7 AutoIt Compiler Context Menu Addon Post By PC2012 http://pc2012.deviantart.com/#/d3dhyz3

[Jos]

try this script to fix any overrides made in on associates for the au3 file extension:

Save this script in a fix.au3 file located in the AutoIt3 directory and run it..

expandcollapse popup

; Scriptname: Fix_Help_Ext.au3
; Script to fix Registry setting for SciTE/AutoIt3/Helpfile Open Button
;
If Not FileExists(@ScriptDir & '\Autoit3.exe') then
    MsgBox(16,"Autoit3.exe error",'File Autoit3.exe not found. Place this script in the AutoIt3 program directory and run it again.')
    Exit
EndIf
If Not FileExists(@ScriptDir & '\SciTE\SciTE.exe') then
    MsgBox(16,"SciTE.exe error",'File ..\SciTE\SciTE.exe not found. Something is not installer the standard way. Exiting.')
    Exit
EndIf
$Open_SciTe = '"' & @ScriptDir & '\SciTE\SciTE.exe" "%1"'
$Edit_SciTe = '"' & @ScriptDir & '\SciTE\SciTE.exe" "%1"'
if @OSArch = "X64" then
    $Run_SciTe = '"' & @ScriptDir & '\AutoIt3_x64.exe" "%1" %*'
Else
    $Run_SciTe = '"' & @ScriptDir & '\AutoIt3.exe" "%1" %*'
EndIf
$Open = RegRead("HKCR\AutoIt3Script\Shell\Open\Command", "")
$Edit = RegRead("HKCR\AutoIt3Script\Shell\Edit\Command", "")
$Run = RegRead("HKCR\AutoIt3Script\Shell\Run\Command", "")
$Default = RegRead("HKCR\AutoIt3Script\Shell", "")
$FixedOpen = RegRead("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.au3", "Application")
ConsoleWrite("+****************************************************************************************" &@CRLF)
ConsoleWrite("+* Current setting: " &@CRLF)
ConsoleWrite("+*        Default action:" & $Default & @CRLF)
ConsoleWrite("+*                   Run:" & $Run & @CRLF)
ConsoleWrite("+*                  Open:" & $Open & @CRLF)
ConsoleWrite("+*                  Edit:" & $Edit & @CRLF)
ConsoleWrite("+*      Always open with:" & $FixedOpen & @CRLF)
ConsoleWrite("+****************************************************************************************" &@CRLF)
; Check for "Always open with settings
If $FixedOpen <> "" Then
    If MsgBox(4, "Override setting for Open on .AU3", 'You have specified to "Always Open" with:' & @CRLF & $FixedOpen & _
            @CRLF & " But this should be removed and the standard setting should be used!" & _
            @CRLF & @CRLF & "Click Yes to Remove this Keys") = 6 Then
        $rc = RegDelete("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.au3", "Application")
        ConsoleWrite('-RegDelete ("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.au3", "Application") $rc = ' & $rc & "  @Error=" & @error & @CRLF)
    Else
        ConsoleWrite('! Override setting for Open on .AU3 not removed' & @CRLF)
    EndIf
Else
    ConsoleWrite('+No Open override on .au3.' & @CRLF)
EndIf
; Check Edit Settings
If $Edit <> $Edit_SciTe Then
    If MsgBox(4, "Edit Settings for AU3", 'Your "Edit" settings are currently:' & @CRLF & $Edit & @CRLF & " But should be:" & @CRLF & $Edit_SciTe & @CRLF & @CRLF & " Update?") = 6 Then
        $rc = RegWrite("HKCR\AutoIt3Script\Shell\Edit\Command", "", "REG_SZ", $Edit_SciTe)
        ConsoleWrite('-RegWrite Edit $rc = ' & $rc & "  @Error=" & @error & @CRLF)
    EndIf
Else
    ConsoleWrite('+Edit already set to default = ' & $Edit & @CRLF)
EndIf
; Check Open Settings
If $Open <> $Open_SciTe Then
    If MsgBox(4, "Open Settings for AU3", 'Your "Open" settings are currently:' & @CRLF & $Open & @CRLF & " But should be:" & @CRLF & $Open_SciTe & @CRLF & @CRLF & " Update?") = 6 Then
        RegWrite("HKCR\AutoIt3Script\Shell\Open\Command", "", "REG_SZ", $Open_SciTe)
        ConsoleWrite('-RegWrite Open $rc = ' & $rc & "  @Error=" & @error & @CRLF)
    EndIf
Else
    ConsoleWrite('+Open already set to default = ' & $Open & @CRLF)
EndIf
; Check Run Settings
If $Run <> $Run_SciTe Then
    If MsgBox(4, "Run Setting for AU3", 'Your "Run" settings are currently:' & @CRLF & $Run & @CRLF & " But should be:" & @CRLF & $Run_SciTe & @CRLF & @CRLF & " Update?") = 6 Then
        RegWrite("HKCR\AutoIt3Script\Shell\Run\Command", "", "REG_SZ", $Run_SciTe)
        ConsoleWrite('-RegWrite Run $rc = ' & $rc & "  @Error=" & @error & @CRLF)
    EndIf
Else
    ConsoleWrite('+Run already set to default = ' & $Run & @CRLF)
EndIf
;Fix default action if needed.
If MsgBox(4, "Default action for AU3", 'Your current "Default" action for au3 is:' & '"' & $Default & '"' &  @CRLF &  @CRLF & "Do you want to change that? ") = 6 Then
    If MsgBox(4, "Default action for AU3", 'Click Yes for "Edit" ' & @CRLF & '    or No for "Run"') = 6 Then
        RegWrite("HKCR\AutoIt3Script\Shell", "", "REG_SZ", "Edit")
        ConsoleWrite('+Changed Default action to "Edit" ' & @CRLF)
    Else
        RegWrite("HKCR\AutoIt3Script\Shell", "", "REG_SZ", "Run")
        ConsoleWrite('+Changed Default action to "Run" ' & @CRLF)
    EndIf
EndIf
;
;Ensure hhctrl is properly registered
$rc = RunWait(@ComSpec & " /c /s regsvr32 hhctrl.ocx", "", @SW_HIDE)
ConsoleWrite('+regsvr32 hhctrl.ocx $rc = ' & $rc & @CRLF)

Edited April 8, 2011 by Jos