Function as a parametr

[mLipok]

How to run function in another function by use the function name as a parameter

example:

function _loop have a parametr - another function not result but pointer/handle to function _first

_loop(_first())
Func _loop($Function)
    For $i = 1 To 10
        "START FUNCTION $Function"
        ;
    Next
EndFunc   ;==>_loop

Func _first()
    ;........
EndFunc   ;==>_first

[enaiman]

You can't pass functions as parameters - why do you over-complicate the things?

Just pass a common parameter and if the value of that one is equal to something, run the function:

_loop(1)
Func _loop($which)
    For $i = 1 To 10
        Switch $which
            Case 1
                _first()
            Case 2
                ;other
                
        EndSwitch
        ;
    Next
EndFunc   ;==>_loop

Func _first()
    ;........
EndFunc   ;==>_first

[PsaltyDS]

You can't pass functions as parameters - why do you over-complicate the things?

Who told you that? Nested function calls are basic to AutoIt's syntax. Don't be absurd:

$sOut = _One(_Two(StringLower(InputBox("Test", "Input String:"))))
ConsoleWrite("$sOut = " & $sOut & @LF)

Func _One($sInput)
    Return "-" & StringUpper($sInput) & "-"
EndFunc

Func _Two($sString)
    Return StringLeft($sString, 2) & StringRight($sString, 2)
EndFunc

[enaiman]

My bad

That "basic" part eluded me so far.

[Ascend4nt]

PsaltyDS, you are passing function returns, not actual functions. I think what mlipok is looking for is passing functions that can be called.

mlipok, just pass the function name inside quotes (without the parentheses) to a function, and then use 'Call', as in:

Call("function")

[omikron48]

Down side to using function names as parameters is that you can't use functions, that need parameters, for that purpose.

[Ascend4nt]

Not sure I follow you, omikron48. Call() supports parameters too.

[omikron48]

Whoops. Goes to show, it's not wise to mouth off on stuff you seldom use. Must have confused it with HotKeySet.

[PsaltyDS]

My bad

That "basic" part eluded me so far.

Nope, on closer examination of the OP based on what Ascend4nt said, you weren't that far off. I think the OP may have really meant to pass the function name as a string, and should then be using Call($function [, <parameters>]):

_loop("_first")

Func _loop($Function)
    For $i = 1 To 10
        Call($Function, $i)
    Next
EndFunc   ;==>_loop

Func _first($iInput)
    ConsoleWrite($iInput & " cubed = " & $iInput ^ 3 & @LF)
EndFunc   ;==>_first

Just a small example of me being sparse in my correctness...

Edited June 25, 2010 by PsaltyDS

[mLipok]

Thanks PsaltyDS

it's works fine