how to prevent overwriting identical strings in ListBox

[jakkus]

Hello there,

I'm trying to write some strings to a ListBox and every time I use a ListBox I'm surprised by the weird defaults for this funcrion.

Often you don't want sorting, but I know how to turn this off.

But I have not figured out how to prevent identical strings from being written only once to a ListBox (or written to the same position).

Just non identical strings are shown.

Can't find any options in the Gui Control Styles.

Somebody out there who can help me?

Thanks

Jakkus

[Melba23]

jakkus,

Welcome to the AutoIt forum.

Sorting is a default style for a list box, so you have to declare the styles you require to overwrite the default. This is true for all controls - if you specify a style, you overwrite the exisitng setting.

To get multiple entries in a List, you have to set the whole list of required elements all at once.

Take a look at this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hList = GUICtrlCreateList("",10, 10, 400, 450, BitOr($WS_BORDER, $WS_VSCROLL)) ; Overwrite the default style of $LBS_SORT, $WS_BORDER, $WS_VSCROLL

$sData = ""
For $i = 1 To 20
    $sData &= Chr(Random(65, 67, 1)) & "|" ; Do not forget to add the delimiter!
Next

GUICtrlSetData($hList, $sData) ; Set the elements all at once

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

All clear?

M23

[jakkus]

Yep, I see it works ok this way.

Still funny there's no default setting for just writing strings the way you would write it to the console.

Thanks, appreceate your help.

Jakkus

[Melba23]

jakkus,

As you do not want sorting, have you thought of using an Edit control rather than a List?

M23