Creating a console in the interface

[3ggerhappy]

Hi Guys

I need some ideas how to create my own console in my gui. where in i can print messages like a visual log. Im thinking of using a list view for the logging but i dont know how to append messages in itso that it reatins prevoiusly written message. hope you got what i mean thanks

[taietel]

3ggerhappy, take this as a start:

expandcollapse popup

#include <GuiEdit.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinApi.au3>
Global $hGUI = GUICreate("GUI Log", 320, 320)
WinSetTrans($hGUI,"",200)
Global $Edit = GUICtrlCreateEdit("", 10, 10, 300, 300, BitOR($ES_AUTOVSCROLL,$ES_WANTRETURN,$WS_VSCROLL), 0)
;set the initial data
GUICtrlSetData(-1, "########################################" & @CRLF & _
                   "#" & @TAB & @TAB & "    Operation so far:" & @TAB & @TAB & "           #" & _
                   @CRLF & "########################################" & @CRLF)
GUICtrlSetColor(-1, 0x00FF00)
GUICtrlSetBkColor(-1, 0x000000)
GUISetState(@SW_SHOW)

;put your variable (optional) e.g. _Logging($var)
For $i = 1 To 30
    _Logging(@TAB & "#> " & "This is line no." & $i)
Next
;set the finish message (optional)
_Logging( @CRLF & @CRLF & "########################################" & @CRLF & _
                   "#" & @TAB & @TAB & "    No errors found!" & @TAB & @TAB & "           #" & _
                   @CRLF & "########################################" & @CRLF)
_Logging("Bye!")
Sleep(3000)
Exit

While 1
    Sleep(10)
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _Logging($text)
    _GUICtrlEdit_AppendText($Edit,$text & @CRLF)
    Sleep(150)
EndFunc

Edited July 17, 2010 by taietel

[3ggerhappy]

Wow thank you very for this i tried the code in my script and it wotked. ill just need a little tweaking thanks much taitel

[taietel]

You're welcome! 

[3ggerhappy]

Hi Im getting an error in the _Logging Function

_GUICtrlEdit_AppendText($Edit,$text & @CRLF) undefined function

[GEOSoft]

Did you remember to #include<GuiEdit.au3> at the top of the script?

[3ggerhappy]

uh forgot about that.

thanks taitel and geosoft