[ Solved ] What to do to not have the GUICreate not visible in systray

[Borje]

Hi

Is there anybody can tell me what I must to use for command in GUICreate to not be visible in the systray when i open it?

Edited July 21, 2010 by Borje

[Melba23]

Borje,

I imagine #NoTrayIcon is what you are looking for.

M23

[Borje]

No I mean not No trayicon what i want is if a create a Window and when I open that window it will be

displayed in the systray field example if I call the window test and when I open it up it displayed minimize

in systray what to do to not have that displayed in the systray?

[rvn]

if u minimize the current form, the form's trayicon disappear... right?

then u need "TraySetState (2)" in form's minimize function.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 633, 447, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "Form1Minimize")
GUISetOnEvent($GUI_EVENT_MAXIMIZE, "Form1Maximize")
GUISetOnEvent($GUI_EVENT_RESTORE, "Form1Restore")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
$settingsitem   = TrayCreateMenu("Settings")
$displayitem    = TrayCreateItem("Display", $settingsitem)
$printeritem    = TrayCreateItem("Printer", $settingsitem)
TrayCreateItem("")
$aboutitem      = TrayCreateItem("About")
TrayCreateItem("")
$exititem       = TrayCreateItem("Exit")

TraySetState()
While 1
    Sleep(100)
WEnd

Func Form1Close()
Exit
EndFunc
Func Form1Maximize()

EndFunc
Func Form1Minimize()
TraySetState (2)
EndFunc
Func Form1Restore()

EndFunc

Edited July 21, 2010 by rvn

[Melba23]

Borje,

Ah now I understand. The icons sit in the systray - what you want is to prevent a button appearing in the taskbar.

You can do this by specifying a parent window when you create the GUI. If you do not have a parent GUI, you can use the ever-present, but hidden, AutoIt window. Thsi shows you how:

#include <GUIConstantsEx.au3>

; Create parent
$hGUI = GUICreate("Parent", 500, 500, Default, Default, Default, Default)
GUISetState()

; Use parent handle when creating child
$hGUI_No_TaskBar_1 = GUICreate("Child", 200, 200, 100, 100, Default, Default, $hGUI)
GUISetState()

; Or use the Autoit window
$hGUI_No_TaskBar_2 = GUICreate("AutoIt Child", 200, 200, 200, 200, Default, Default, WinGetHandle(AutoItWinGetTitle()))
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

All clear?

M23

[Borje]

Thank You very very much Melba23

$hGUI_No_TaskBar_2 = GUICreate("AutoIt Child", 200, 200, 200, 200, Default, Default, WinGetHandle(AutoItWinGetTitle()))

GUISetState()

This is want i want and it works that i want.