[ Solved] How to have flashing text in GUI

[Borje]

Hello everybody

Is it possible to have flashing text in a GUI window?

I can not find any information of this.

Edited July 23, 2010 by Borje

[Melba23]

Borje,

Two possible ways to get your text to flash:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hLabel_Loop = GUICtrlCreateLabel("Flasher!", 10, 10, 480, 50, $SS_CENTER)
GUICtrlSetFont(-1, 24)
$fShow_Loop = True
$hLabel_Adlib = GUICtrlCreateLabel("", 10, 100, 480, 50, $SS_CENTER)
GUICtrlSetFont(-1, 24)
$fShow_Adlib = False

GUISetState()

AdlibRegister("_Flasher", 250)

$iBegin = TimerInit()


While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If TimerDiff($iBegin) > 250 Then
        $fShow_Loop = Not $fShow_Loop
        Switch $fShow_Loop
            Case True
                GUICtrlSetData($hLabel_Loop, "Flasher!")
            Case False
                GUICtrlSetData($hLabel_Loop, "")
        EndSwitch
        $iBegin = TimerInit()
    EndIf

WEnd

Func _Flasher()

    $fShow_Adlib = Not $fShow_Adlib
        Switch $fShow_Adlib
            Case True
                GUICtrlSetData($hLabel_Adlib, "Flasher!")
            Case False
                GUICtrlSetData($hLabel_Adlib, "")
        EndSwitch

EndFunc

M23

[Borje]

Thank you Melba23

I have test and I have problem with AdlibRegister("_Flasher", 250)

Error msg : ==> Unknown function name.: AdlibRegister("_Flasher", 250)

Why this happen?

Is this the possible 2 ways to have the text flashing?

[Melba23]

Borje,

Error msg : ==> Unknown function name.: AdlibRegister

Either upgrade to the newest version of AutoIt or change AdlibRegister to AdlibEnable.

Is this the possible 2 ways to have the text flashing?

As far as I know there is no Windows style which sets the text to "flash", so you have to do it this way.

M23

[Borje]

Thanks for your help now thats working I change to AdlibEnable

I can not find any information about Windows style which sets the text to "flash

so your example is good for this.