~ a number

[maestro]

Hi, I am wondering if its possible to have a number "around" the value, for example

$Pz=60
$z=100
While $Pz <> $z

I want to know if there's any way to give a variable a "threshold" like making $z = 50 to 150

[PsaltyDS]

Hard to tell what you mean. Maybe something like this?

$Pz=60
$z=50
While $Pz <> $z
    ConsoleWrite("Loop:  " & $Pz & " <> " & $z & @LF)
    $z += 1
WEnd
ConsoleWrite("Exited loop:  " & $Pz & " = " & $z & @LF)

If that's it, then more sensible would be:

For $z = 50 To 59
    ConsoleWrite("Loop:  $z = " & $z & @LF)
Next
ConsoleWrite("Exited loop:  $z = " & $z & @LF)

[MvGulik]

Sound like he is thinking something fussy. (AutoIt for neural networks ... Maybe in the far, far, future.)

@OP

Currently the number variable type only has one distinct value, and thats it. (ignoring float exceptional behaviors.)

If you care to explain why you think you need something like that. Others might post some ideas on how to go about it in AutoIt.

Edited July 23, 2010 by MvGulik

[PsaltyDS]

Yeah, that kind of thing would be easy to implement with some UDFs, but would not be supported by the native functions and operators.

$Pz=60
$z = _RangeCreate(50, 150)
While _RangeIsInRange($Pz, $z)
    ConsoleWrite("Loop:  $Pz = " & $Pz & "; is in range" & @LF)
    $Pz += 1
WEnd
ConsoleWrite("Exited loop:  $Pz = " & $Pz & "; is out of range" & @LF)


Func _RangeCreate($Min, $Max)
    Local $Range[2] = [$Min, $Max]
    Return $Range
EndFunc

Func _RangeIsInRange($val, $Range)
    If ($val >= $Range[0]) And ($val <= $Range[1]) Then
        Return True
    Else
        Return False
    EndIf
EndFunc

[GEOSoft]

Switch $number
    Case 50 To 150
        ;; Do something
    Case Else
        ;; Do something else
EndSwitch

[ClayB]

I am new to AutoIt but how I would try it in java would be to have a starting number then set an upper and lower boundary by doing addition and subtraction on that value and setting those to two new values. You could then use the high and low boundaries in comparisons. Not sure if that helps at all.

Edited July 23, 2010 by ClayB

[Pottery]

#include <Array.au3>
Dim $Array[101]
For $i = 0 to 100
    $Array[$i] = $i + 50
Next
_ArrayDisplay($Array)

$Array now has values 50 through 150 in there.

$Variable = Floor(Random(50, 150))
MsgBox(64, 'Example', $Variable)

If you want a random number between 50 and 150, use this second one.

Edited July 23, 2010 by Epdmk

[GEOSoft]

If you want it as a function then here is the simplest IMHO

Func _InRange($iVal, $iMin, $iMax)
   Switch $iVal
       Case $iMin To $iMax
           Return True
       Case Else
           Return False
   EndSwitch
EndFunc

[PsaltyDS]

That's a good one, George, but it still makes the point that these kinds of operations will require a roll-your-own approach. AutoIt does not support fuzzy logic natively.

[GEOSoft]

Very true but when having to "roll your own" I try to keep it as simple as possible.

[Spiff59]

Or...

RangeTest(13)
RangeTest(135)
RangeTest(211)
RangeTest(72)

Func RangeTest($num)
    Local $base = 100, $threshhold = 50 ; range  50 to 150
    If Abs($base - $num) <= $threshhold Then MsgBox(1,"", "Number " & $num  & " is within range")
EndFunc

Edit: Or , UDF'ed:

Func RangeTest($num, $base, $threshhold)
    If Abs($base - $num) <= $threshhold Then Return 1
EndFunc

Edited July 23, 2010 by Spiff59