[SOLVED] Mouse move event

[ALTIN]

Hello AutoIters,

recently I'm writing a program, basically it is a simple color detector to copy color code.

I finished it quickly, just some small details left...

For now I'm using $GUI_EVENT_MOUSEMOVE to detect whether mouse has moved and to update the new color values, however this only works if my program's window has the focus. If I minimize my program or if another program has the focus, then I can't detect mouse move event.

this is a basic "skeleton" of what I have now

#include <GUIConstantsEx.au3>   

$GUI = GUICreate("Color", 400, 200) 
GUISetState()

While 1
    $msg = GUIGetMsg($GUI)
    Select
        Case $msg = $GUI_EVENT_CLOSE
                Exit
        Case $msg = $GUI_EVENT_MOUSEMOVE
            $pos = MouseGetPos()
            ToolTip ("x: " & $pos[0] & "x: " & $pos[1], 10, 10)
    EndSelect
WEnd

I would like to detect mouse movement Globally, I mean even if my program's window doesn't have the focus.

Anyone know how to do that?

Thanks bro/s

Edited September 20, 2010 by ALTIN

[PsaltyDS]

Just repeat MouseGetPos() unconditionally and watch for the X or Y value to change.

[ALTIN]

Just repeat MouseGetPos() unconditionally and watch for the X or Y value to change.

PsaltyDS, yes you are right in what you intend to say, I had this way before, however (you know) the frequency of refreshing new values is so high, as you can freely see the values "vibrating".

This is more visible (for example) if I use a label to preview the current color value.

Don't know if you got what I mean?

[Melba23]

ALTIN,

Whenever you update a control in a tight loop using GUICtrlSetData or GUICtrlSetState, you need a method to prevent this "vibrating", or "flickering" (which is the more common term). One way is to check the current value of the control and only update when it needs changing:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hLabel_1 = GUICtrlCreateLabel("", 10, 10, 50, 50)
GUICtrlSetFont(-1, 16)

$hLabel_2 = GUICtrlCreateLabel("", 10, 100, 50, 50)
GUICtrlSetFont(-1, 16)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; The top label will flicker
    GUICtrlSetData($hLabel_1, @SEC)

    ; The bottom one will not
    If GUICtrlRead($hLabel_2) <> @SEC Then
        GUICtrlSetData($hLabel_2, @SEC)
    EndIf

WEnd

Move the mouse around to see the flicker to best effect.

I hope this helps.

M23