How to use "setLocaleInfo" to change date format in XP

[dkwokgs]

Hi There,

I have tried using the registry method but it does not refresh the system immediately.

I need to change the date format for about 2000 computers.

Found this "setLocaleInfo" on Microsoft website but do not know how to use it in Autoit. Please advise.

http://msdn.microsoft.com/en-us/library/aa913806.aspx

Thanks in advanced.

[PsaltyDS]

Your link is to the wrong version (WinCE). The correct one is on MSDN: SetLocaleInfo Function.

Yashied's WinAPIEx UDF has a _WinAPI_GetLocaleInfo(), but not the coresponding _WinAPI_SetLocaleInfo().

You'll have to roll your own.

[Yashied]

expandcollapse popup

#Include <WinAPIEx.au3>

Global Const $LOCALE_INVARIANT = 0x007F
Global Const $LOCALE_SYSTEM_DEFAULT = 0x0800
Global Const $LOCALE_USER_DEFAULT = 0x0400

Global Const $LOCALE_CUSTOM_DEFAULT = 0x0C00
Global Const $LOCALE_CUSTOM_UI_DEFAULT = 0x1400
Global Const $LOCALE_CUSTOM_UNSPECIFIED = 0x1000

_WinAPI_SetLocaleInfo($LOCALE_USER_DEFAULT, $LOCALE_SSHORTDATE, 'dd-MMM-yy')

; #FUNCTION# ====================================================================================================================
; Name...........: _WinAPI_SetLocaleInfo
; Description....: Sets an item of information in the user override portion of the current locale.
; Syntax.........: _WinAPI_SetLocaleInfo ( $LCID, $iType, $sData )
; Parameters.....: $LCID   - Locale identifier for which to set information.
;                  $iType  - Type of locale information to set. This parameter can be one of the $LOCALE_... constants.
;                  $sData  - The string containing the locale information to set. The information must be in the format specific to
;                            the specified constant.
; Return values..: Success - 1.
;                  Failure - 0 and sets the @error flag to non-zero.
; Author.........: Yashied
; Modified.......:
; Remarks........: None
; Related........:
; Link...........: @@MsdnLink@@ SetLocaleInfo
; Example........: Yes
; ===============================================================================================================================

Func _WinAPI_SetLocaleInfo($LCID, $iType, $sData)

    Local $Ret = DllCall('kernel32.dll', 'int', 'SetLocaleInfoW', 'long', $LCID, 'int', $iType, 'wstr', $sData)

    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    Return 1
EndFunc   ;==>_WinAPI_SetLocaleInfo

[PsaltyDS]

I was going to send Yashied a PM, but as they say "Speak of the devil..."