Color uneven/even ListView indices?

[gobsor]

Hey there,

I'm loading *.mp3 files from a folder into a ListView, each row gets 1 filename, filesize and an incrementing number.

To get a better overview (and yeah, I don't want to use gridlines), I thought about coloring every uneven row, that's

what I tried at least:

Func _fillSourceView($path)
    _clearListView($hSourceView)
    $files = _FileListToArray($path, "*.mp3")
    For $i = 1 To UBound($files)-1
        If Mod($i, 2) == 0 Then
            _GUICtrlListView_SetTextBkColor($hSourceView, $CLR_WHITE)
        Else
            _GUICtrlListView_SetTextBkColor($hSourceView, $CLR_MONEYGREEN)
        EndIf
        $size = FileGetSize($path&$files[$i])
        _GUICtrlListView_AddItem($hSourceView, _properNum($i))
        _GUICtrlListView_AddSubItem($hSourceView, $i-1, $files[$i], 1)
        _GUICtrlListView_AddSubItem($hSourceView, $i-1, _properSize($size), 2)
    Next
    _GUICtrlButton_Enable($idReload, True)
EndFunc ;==> _fillSourceView($path)

So what I'm basically doing is changing the text's background color of uneven rows to "moneygreen", using

If Mod($i, 2) == 0 Then
            _GUICtrlListView_SetTextBkColor($hSourceView, $CLR_WHITE)
        Else
            _GUICtrlListView_SetTextBkColor($hSourceView, $CLR_MONEYGREEN)
        EndIf

Somehow it works (sometimes) for a folder with just like 6 *.mp3 files in it, but when I add one

with ~65 *.mp3 files it sets either all rows green or all rows white. Is there some function that

can directly change the color of a ListView's row?

ie: _GUICtrlListView_SetRowBkColor($hWnd, $iIndex, $iColor) to enforce $iIndex row to have $iColor

as background color?

greetings

[water]

I fill the ListView in a loop and change the color on the fly:

For $iRec = 1 to 100
 GUICtrlCreateListViewItem(value1[$irec] & "|" & value2[$irec], $hGUIUserList)
 If Mod($iRec, 2) = 0 Then GUICtrlSetBkColor(-1, 0xD0DEC7)
Next

[gobsor]

Thanks, exactly what I was looking for

[Melba23]

gobsor,

If you use the built-in ListView, you can also use the built-in alternate line colour style - look for the <<<<<<<<<< lines:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("Test", 500, 500)

$hList = GUICtrlCreateListView("Col 1|Col 2|Col 3", 10, 10, 480, 480)
GUICtrlSetBkColor(-1, 0xFF0000)
; Set up alt line colouring
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_LV_ALTERNATE) ; <<<<<<<<<<<<<<<<<<<<<<<<

For $i = 0 To 2
    _GUICtrlListView_SetColumnWidth(-1, $i, 151)
Next

For $i = 0 To 29
    GUICtrlCreateListViewItem($i & "|" & $i & "|" & $i, $hList)
    GUICtrlSetBkColor(-1, 0x00FF00) ; <<<<<<<<<<<<<<<<<<<<<<<<
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

M23

[ReFran]

Mmmh,

The example is very good,

.... but the color ...

;-) Reinhard

[Melba23]

ReFran,

.... but the color ...

But it illustrates the alternate line colour difference so nicely!

Personally I tend to use the default backcolour and 0xCCFFCC, probably because I was brought up on the old concertina printout paper from the mainframe - very much easier on the eye.

M23

[guinness]

Is there a clever hack you know of to use _GUICtrlListView_AddItem()? I had a look at CSV-Editor by Funkey to see how they accomplished it, seems a new Function was created using the native GUICtrlCreateListViewItem.

[gobsor]

Nice example M23, thank you!

And yea, I'm using 0xF2F8FA now! Smooth color I think! ;-)

Edited August 25, 2010 by gobsor