Create GUI controls using FOR loop?

[jorgev]

Is it possible to create GUI controls using FOR loop?

Im getting "ERROR (23) : ==> Subscript used with non-Array variable.:" when trying to GUICtrlSetData($dropid[$dro],"hello"), i'm trying to populate

all 10 combo's with the same value, and would like a controlID for each combo. Any hints are appriciated.

ex:

#include <GUIConstantsEx.au3>
GUICreate("test",800,600)
$dropstotal = 10
$dropposleft = 10
$droppostop = 50
$dropwidth = 150
$dropheight = 20
for $dro = 1 to $dropstotal
    $dropid = GUICtrlCreateCombo("", $dropposleft, $droppostop, $dropwidth, $dropheight)
    $droppostop = $droppostop + 30
Next
GUISetState()
GUICtrlSetData($dropid[$dro],"hello")
While 1
  $msg = GUIGetMsg()
  Select
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop
  EndSelect
WEnd

[Tec]

Example with Buttons. Hope this help you.

#include <GUIConstantsEx.au3>

$x = 0
Dim $Button[6]

$Gui = GUICreate("Test", 125, 34 )

$Btn_Start = GUICtrlCreateDummy()
For $i = 1 To 5
    $x = ($i - 1) * 25
    $Button[$i] = GUICtrlCreateButton($i, $x, 5, 24, 24)
Next
$Btn_End = GUICtrlCreateDummy()

GUISetState(@SW_SHOW)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Btn_Start To $Btn_End
            For $i = 1 To UBound($Button) - 1
                If $Msg == $Button[$i] Then
                    MsgBox(0, "test", "Button: " & $Button[$i])
                EndIf
            Next
    EndSwitch
    Sleep( 10)
WEnd

Edited August 27, 2010 by Tec

[BrewManNH]

In your first example $DropID is a variable, while in the second example, $Button[x] is an array. That's your error, because the second example actually worked for me, although the MsgBox numbers don't match the button id's as set by the $i variable. When pushing 1 I got 6, 2 was 7, 3 was 8 etc. I didn't investigate it very far but it does work as an array when it's actually using an array.

[jorgev]

Correct

I used the example from Tec and it's working as intended

thankyou very much