Combo and format issue - aligning text

[nitekram]

I am trying to align text in a combo box - the problem is is that it does not align no matter what I have tried - this example is my last attemp and it correctly displays in the console window but not in the combo box - can someone show me what I am doing wrong?

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Local $data[20][2], $data2[20]
Local $strintest = 0

$gui = GUICreate('', 260,410)
$test = GUICtrlCreateCombo('', 0, 0, 250, 400, $WS_VSCROLL)
GUISetState()

For $i = 0 To UBound($data) - 1
    For $j = 0 To Random(3, 10)
        $data[$i][0] &= Random('1', '7', 1)
        $data[$i][1] &= Random('1', '7', 1)
    Next
Next

For $g = 0 To UBound($data) - 1
    If $strintest <= StringLen($data[$g][0]) Then $strintest = StringLen($data[$g][0])
Next

$strintest += 5

For $l = 0 To UBound($data) - 1
    If StringLen($data[$l][0]) <> $strintest Then
        Do
            $data[$l][0] &= ' '
        Until StringLen($data[$l][0]) >= $strintest
    EndIf
Next

For $i = 0 To UBound($data) - 1

    ConsoleWrite('!>' & $data[$i][0] & $data[$i][1] & @CRLF)
    GUICtrlSetData($test, $data[$i][0] & $data[$i][1])
Next

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

[Melba23]

nitekram,

Just use a monospaced font for the combo like this:

$test = GUICtrlCreateCombo('', 0, 0, 250, 400, $WS_VSCROLL)
GUICtrlSetFont(-1, 10, Default, Default, "Courier New") ; <<<<<<<<<<<<<<<<<<<<<<<<

Or you could use the new Consolas font which was designed to look less "clunky".

M23

[nitekram]

Sooooooo, I spent over 4 hours trying to figure this out and it was just the FONT - I feel stupid.

Thanks for your help, once again.