Creating a ninimalist GUI

[Sunblood]

*Minimalist. Whoops.

I have a little monitor script that runs alongside the Till program that our cash registers use. There's very limited space to display quite a bit of information and so far this bit:

SplashTextOn("Notes", $text, 138, 285, 875, 330, 5, "Helvetica", 8)

works just fine but I would like a little more control with individual labels and colors. The option "5" makes a thin borderless titleless window with left justified text and that's just about perfect.

I've looked around at the various styles for GUIs and haven't really found anything similar. Does anyone know a good option to use or even a customized version?

Edited August 30, 2010 by Sunblood

[kaotkbliss]

This link provided by Taitel provides a nice small gui that sounds like much what you are looking for. It's pretty easy to customize as I have done with the program in my sig.

[Sunblood]

This link provided by Taitel provides a nice small gui that sounds like much what you are looking for. It's pretty easy to customize as I have done with the program in my sig.

Oh wow, that looks really nice and incredibly complex. I guess I have some work to do!

Thanks.

[UEZ]

And what about this version:

#include <GuiEdit.au3>
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Splash("Blah blahhhblahhh blaha blahhahahah" & @CRLF & "Blaha blahahah", 138, 285)
Sleep(500)
Splash_RE("Blah blahhhblahhh blaha blahhahahah" & @CRLF & "Blaha blahahah", 138, 285, 0x0000FF)
Exit


Func Splash($text, $width, $height, $left = 875, $top = 330, $sleep = 5000, $fname = "Helvetica", $fsize = 8, $fweight = 400, $fattribute = 0); coded by UEZ
    Local $hGUI = GUICreate("Splash", $width, $height, $left, $top, $WS_POPUP + $DS_MODALFRAME, $WS_EX_WINDOWEDGE)
    Local $iMemo = GUICtrlCreateEdit("", 0, 0, $width, $height, $ES_AUTOVSCROLL + $ES_READONLY)
    GUICtrlSetLimit(-1, 0x7FFFFFFF)
    GUICtrlSetFont($iMemo, $fsize, $fweight, $fattribute, $fname)
    GUISetState()
    GUICtrlSetData($iMemo, $text)
    Sleep($sleep)
    GUIDelete($hGUI)
EndFunc

Func Splash_RE($text, $width, $height, $fcolor = 0x000000, $left = 875, $top = 330, $sleep = 5000, $fname = "Helvetica", $fsize = 18); coded by UEZ
    Local $hGUI = GUICreate("Splash", $width, $height, $left, $top, $WS_POPUP + $DS_MODALFRAME, $WS_EX_WINDOWEDGE)
    Local $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 0, 0, $width, $height, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    GUISetState()
     _GUICtrlRichEdit_SetFont($hRichEdit, $fsize, $fname)
    _GuiCtrlRichEdit_SetCharColor($hRichEdit, $fcolor) ;color bgr
    _GuiCtrlRichEdit_SetText($hRichEdit, $text)
    Sleep($sleep)
    GUIDelete($hGUI)
EndFunc

For color usage you have to use the RichEdit controls!

Br,

UEZ

Edited September 12, 2010 by UEZ