how to get file name by window title?

[SharpShooter]

hellooo

i want to know that how can i get the name of file by it's Window name?

File name like this: Explorer.exe

Window name like this: New Folder

by this we can get Process ID, but i want to get Process or file name.

$x = WinGetProcess("test")

MsgBox(4096, "PID is", $x)

how can i do this?

[SharpShooter]

i just got the solution but now i have another problem.

#include <Process.au3>
Opt("WinTitleMatchMode", 2)
$title = WinGetTitle("Super", "")
$pid = WinGetProcess($title)
$name = _ProcessGetName($pid)
MsgBox(64, "Process Name is: ", $name)

but the problem is that if i change "Super" to "super" then it gives nothing.

i want it to work on all words even like this "SuPeR"

help me please

[bo8ster]

You could use the output of WinList with StringCompare. WinList will also have the handle.

[Varian]

Change corresponding lines to this

Opt('WinTitleMatchMode', 4)
$Title = WinGetTitle("[REGEXPTITLE:(?i)super]", "")

This is a case insensitive search for the word "super" anywhere in the Title. Just be careful for multiple matches. You can refine the regular expression to narrow down your results and also add class components to narrow down the window search returns

[SharpShooter]

i was trying to close a Window but excluding Browsers.

i did this:

#include <Process.au3>
Func _Close($win)
    Opt("WinTitleMatchMode", 4)
    $title = WinGetTitle("[REGEXPTITLE:(?i)"&$win&"]", "")
    $pid = WinGetProcess($title)
    $name = _ProcessGetName($pid)
    If Not $name = "Firefox.exe" Or "iexplorer.exe" or "chrome.exe" Then
        WinClose($win)
    EndIf   
    ;MsgBox(64, "Process Name is: ", $name)
EndFunc
_Close("super")

but i Failed to do so.

what is my mistake in this script?

what i am doing wrong?

Edited September 3, 2010 by SprinterGuru

[SharpShooter]

can anybody tell how to get that work?

i want to close a window by it's name, but i don't want that it effect browser windows.

[wakillon]

It's not iexplorer.exe, but iexplore.exe

Try this

#include <Process.au3>


_Close("super")

Func _Close($win)
    Opt("WinTitleMatchMode", 4)
    $title = WinGetTitle("[REGEXPTITLE:(?i)"&$win&"]", "")
    $pid = WinGetProcess($title)
    $name = _ProcessGetName($pid)
    If $name <> "Firefox.exe" And $name <> "iexplore.exe" And $name <> "chrome.exe" Then
        WinClose($win)
    EndIf   
    ;MsgBox(64, "Process Name is : ", $name)
EndFunc

Edited September 4, 2010 by wakillon

[maqleod]

can anybody tell how to get that work?

i want to close a window by it's name, but i don't want that it effect browser windows.

Process Manager Source

One of my projects is a process manager, it displays all the processes running on the system, windows associated with those processes and will also provide the file on disk associated with that process. It contains all you need to do what you need to do. Look at the source, if you have any questions about any portion of it, ask.

Edited September 4, 2010 by maqleod

[SharpShooter]

can anybody tell how to get that work?

i want to close a window by it's name, but i don't want that it effect browser windows.

[wakillon]

can anybody tell how to get that work?

i want to close a window by it's name, but i don't want that it effect browser windows.

Have you tried my modified script ?

[SharpShooter]

i got an error when trying to run your script.

>"D:\Program Files\AutoIt3\SciTE\..\autoit3.exe" /ErrorStdOut "D:\Documents and Settings\Oley\My Documents\Downloads\Compressed\PM_1.0_Source\Process Manager.au3"

D:\Documents and Settings\Oley\My Documents\Downloads\Compressed\PM_1.0_Source\Process Manager.au3 (17) : ==> Error opening the file.:

#include <CompInfo.au3>

>Exit code: 1 Time: 2.916

Also, i don't know which part of your script i can use to make my script work!

[SharpShooter]

@ wakillon

Yes it worked.

Thanks man

nowi need to collected other browser exe names to make it work with all.

[wakillon]

Another way

#include <Process.au3>
#include <Array.au3>

$_Title = "explorer"
GuiCreate ( $_Title )
GUISetState ( )
Sleep ( 2000 )

_CloseWindowWithString ( $_Title )

Func _CloseWindowWithString ( $_String )
    $_BrowserList = 'Firefox.exe,iexplore.exe,chrome.exe,opera.exe,safari.exe'
    $_BrowserList = StringSplit ( $_BrowserList, ',' ) ; _ArrayDisplay ( $_BrowserList )
    $_WinList = WinList ( )
    For $_I = 1 To $_WinList[0][0]
        If StringInStr ( $_WinList[$_I][0], $_String ) <> 0 And Not _
        _AlreadyInArray ( $_BrowserList, _ProcessGetName ( WinGetProcess ( $_WinList[$_I][0], "" ) ) ) Then WinClose ( $_WinList[$_I][1] )
    Next
EndFunc ;==> _CloseWindowWithString ( )

Func _AlreadyInArray ( $_SearchArray, $_Item )
    $_Index = _ArraySearch ( $_SearchArray, $_Item ) 
    If @error Then   
        Return False
    Else  
        If  $_Index <> 0 Then       
            Return True
        Else 
            Return False
        EndIf   
    EndIf
EndFunc ;==> _AlreadyInArray ( )

Edited September 4, 2010 by wakillon

[SharpShooter]

Thanks a lot wakillon, but i got a couple of questions.

Which script is faster and takes less cpu usage? in other words which one is better?

'll it work to match a word in whole sentence like in the script posted before?

what if i use it for too many Windows and Keywords? i mean easily use for more then one keyword?

like "super" , "dvd" , "volume" , etc (check and close at the same timewithout effecting browsers.

And thanks once again for the help... it's really great.

Edited September 5, 2010 by SprinterGuru

[wakillon]

I don't know which is better

The first script close only one window with the string

instead of second that close all windows containing string in their title !

Try and see

[bo8ster]

@SprinterGuru - I recommend you use wakillon's second script. It does what I was thinking of well.

It does not matter which is faster, it matters which script is simpler to use and has more functionality.

Good script wakillon!

Edited September 6, 2010 by bo8ster

[SharpShooter]

#include <Process.au3>
#include <Array.au3>
Func _CloseWindowWithString ( $_String )
    $_BrowserList = 'Firefox.exe,iexplore.exe,chrome.exe,opera.exe,safari.exe'
    $_BrowserList = StringSplit ( $_BrowserList, ',' ) ; _ArrayDisplay ( $_BrowserList )
    $_WinList = WinList ( )
    For $_I = 1 To $_WinList[0][0]
        If StringInStr ( $_WinList[$_I][0], $_String ) <> 0 And Not _
        _AlreadyInArray ( $_BrowserList, _ProcessGetName ( WinGetProcess ( $_WinList[$_I][0], "" ) ) ) Then WinClose ( $_WinList[$_I][1] )
    Next
EndFunc ;==> _CloseWindowWithString ( )

Func _AlreadyInArray ( $_SearchArray, $_Item )
    $_Index = _ArraySearch ( $_SearchArray, $_Item ) 
    If @error Then   
        Return False
    Else  
        If  $_Index <> 0 Then       
            Return True
        Else 
            Return False
        EndIf   
    EndIf
EndFunc ;==> _AlreadyInArray ( )
_CloseWindowWithString ( $_Title1 )
_CloseWindowWithString ( $_Title2 )
_CloseWindowWithString ( $_Title3 )
_CloseWindowWithString ( $_Title4 )
_CloseWindowWithString ( $_Title5 )
_CloseWindowWithString ( $_Title6 )
_CloseWindowWithString ( $_Title7 )
_CloseWindowWithString ( $_Title8 )
_CloseWindowWithString ( $_Title9 )

from the script posted above ^, can we modify this part

_CloseWindowWithString ( $_Title1 )
_CloseWindowWithString ( $_Title2 )
_CloseWindowWithString ( $_Title3 )
_CloseWindowWithString ( $_Title4 )
_CloseWindowWithString ( $_Title5 )
_CloseWindowWithString ( $_Title6 )
_CloseWindowWithString ( $_Title7 )
_CloseWindowWithString ( $_Title8 )
_CloseWindowWithString ( $_Title9 )

to be like this:

_CloseWindowWithString ($Title1, $Title2, $Title3, $Title4, $Title5, $Title6)

Edited September 6, 2010 by SprinterGuru

[wakillon]

@SprinterGuru - I recommend you use wakillon's second script. It does what I was thinking of well.

It does not matter which is faster, it matters which script is simpler to use and has more functionality.

Good script wakillon!

@Bo8ster

Thanks !

#include <Process.au3>
#include <Array.au3>
Func _CloseWindowWithString ( $_String )
    $_BrowserList = 'Firefox.exe,iexplore.exe,chrome.exe,opera.exe,safari.exe'
    $_BrowserList = StringSplit ( $_BrowserList, ',' ) ; _ArrayDisplay ( $_BrowserList )
    $_WinList = WinList ( )
    For $_I = 1 To $_WinList[0][0]
        If StringInStr ( $_WinList[$_I][0], $_String ) <> 0 And Not _
        _AlreadyInArray ( $_BrowserList, _ProcessGetName ( WinGetProcess ( $_WinList[$_I][0], "" ) ) ) Then WinClose ( $_WinList[$_I][1] )
    Next
EndFunc ;==> _CloseWindowWithString ( )

Func _AlreadyInArray ( $_SearchArray, $_Item )
    $_Index = _ArraySearch ( $_SearchArray, $_Item ) 
    If @error Then   
        Return False
    Else  
        If  $_Index <> 0 Then       
            Return True
        Else 
            Return False
        EndIf   
    EndIf
EndFunc ;==> _AlreadyInArray ( )
_CloseWindowWithString ( $_Title1 )
_CloseWindowWithString ( $_Title2 )
_CloseWindowWithString ( $_Title3 )
_CloseWindowWithString ( $_Title4 )
_CloseWindowWithString ( $_Title5 )
_CloseWindowWithString ( $_Title6 )
_CloseWindowWithString ( $_Title7 )
_CloseWindowWithString ( $_Title8 )
_CloseWindowWithString ( $_Title9 )

from the script posted above ^, can we modify this part

_CloseWindowWithString ( $_Title1 )
_CloseWindowWithString ( $_Title2 )
_CloseWindowWithString ( $_Title3 )
_CloseWindowWithString ( $_Title4 )
_CloseWindowWithString ( $_Title5 )
_CloseWindowWithString ( $_Title6 )
_CloseWindowWithString ( $_Title7 )
_CloseWindowWithString ( $_Title8 )
_CloseWindowWithString ( $_Title9 )[/size]
 
[size="2"]

to be like this:

_CloseWindowWithString ($Title1, $Title2, $Title3, $Title4, $Title5, $Title6)

@Sprinterguru

Try this...

[/size]
[size=2]
#include <Process.au3>
#include <Array.au3>

Dim $_StringArray[10] = [ 10, 'string1', 'string2', 'string3', 'string4', 'string5', 'string6', 'string7', 'string8', 'string9' ]
_ArrayDisplay ( $_StringArray )
_CloseWindowWithStringArray ( $_StringArray )
Exit

Func _CloseWindowWithStringArray ( $_StringArray )
    $_BrowserList = 'Firefox.exe,iexplore.exe,chrome.exe,opera.exe,safari.exe'
    $_BrowserList = StringSplit ( $_BrowserList, ',' ) ; _ArrayDisplay ( $_BrowserList )
    For $_H = 1 To UBound ( $_StringArray ) -1
        $_WinList = WinList ( )
        For $_I = 1 To $_WinList[0][0]
            If StringInStr ( $_WinList[$_I][0], $_StringArray[$_H] ) <> 0 And Not _
            _AlreadyInArray ( $_BrowserList, _ProcessGetName ( WinGetProcess ( $_WinList[$_I][0], "" ) ) ) Then WinClose ( $_WinList[$_I][1] )
        Next
    Next
EndFunc ;==> _CloseWindowWithStringArray ( )

Func _AlreadyInArray ( $_SearchArray, $_Item )
    $_Index = _ArraySearch ( $_SearchArray, $_Item ) 
    If @error Then   
        Return False
    Else  
        If  $_Index <> 0 Then       
            Return True
        Else 
            Return False
        EndIf   
    EndIf
EndFunc ;==> _AlreadyInArray ( )[/size]
[size=2]

Or this...

#include <Process.au3>
#include <Array.au3>

_CloseWindowWithStringList ( 'string1,string2,string3,string4,string5,string6,string7,string8,string9' )
Exit

Func _CloseWindowWithStringList ( $_StringList )
    $_BrowserList = 'Firefox.exe,iexplore.exe,chrome.exe,opera.exe,safari.exe'
    $_BrowserList = StringSplit ( $_BrowserList, ',' ) ; _ArrayDisplay ( $_BrowserList )
    $_StringArray = StringSplit ( $_StringList, ',' )
    For $_H = 1 To UBound ( $_StringArray ) -1
        $_WinList = WinList ( )
        For $_I = 1 To $_WinList[0][0]
            If StringInStr ( $_WinList[$_I][0], $_StringArray[$_H] ) <> 0 And Not _
            _AlreadyInArray ( $_BrowserList, _ProcessGetName ( WinGetProcess ( $_WinList[$_I][0], "" ) ) ) Then WinClose ( $_WinList[$_I][1] )
        Next
    Next
EndFunc ;==> _CloseWindowWithStringList ( )

Func _AlreadyInArray ( $_SearchArray, $_Item )
    $_Index = _ArraySearch ( $_SearchArray, $_Item ) 
    If @error Then   
        Return False
    Else  
        If  $_Index <> 0 Then       
            Return True
        Else 
            Return False
        EndIf   
    EndIf
EndFunc ;==> _AlreadyInArray ( )

Edited September 6, 2010 by wakillon