Multiline GUI Label using $SS_CENTERIMAGE

[DarkBoost]

Please help me make this multiline.

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>

Dim $w = 450
Dim $h = 450

GUICreate("", $w, $h)
GUICtrlCreateLabel("Line 1..." &@CRLF& "Line 2..." &@CRLF& "Line 3...", 10, 10, $w-20, $h-20, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUISetState()

While 1
    Dim $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

[Melba23]

DarkBoost,

Unfortunately $SS_CENTERIMAGE overrides all the @CRLFs.

However, if you use my StringSize UDF (link in my sig) you can get around this with a bit of maths:

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>

#include <StringSize.au3>

Dim $w = 450
Dim $h = 450

; Get size of label required for the text
$aLabelInfo = _StringSize("Line 1..." &@CRLF& "Line 2..." &@CRLF& "Line 3...")

GUICreate("", $w, $h)

; Calculate the required position of the label
$iLabel_X = Int(($w - $aLabelInfo[2]) / 2)
$iLabel_Y = Int(($h - $aLabelInfo[3]) / 2)
GUICtrlCreateLabel("Line 1..." &@CRLF& "Line 2..." &@CRLF& "Line 3...", $iLabel_X, $iLabel_Y, $aLabelInfo[2], $aLabelInfo[3], $SS_CENTER)

GUISetState()

While 1
    Dim $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

I hope that is what you need to progress.

M23

[DarkBoost]

Melba23

Cheers buddy that worked a treat... nice scripting there

[Melba23]

DarkBoost,

Thanks. Glad I could help.

M23