_DirRename() can anyone make the function with different code? *Challenge*

[guinness]

_DirRename() is able to rename folders randomly. You specify the parent directory (the initial folder) and then specify a sub-folder(s) that are included within the parent folder. It will then rename all the sub-folder(s) til it reaches the parent directory.

The function is working as intended, but I wanted to throw the question out of if anyone can create a similar function with different code? I simply want to learn!

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
_DirRename("C:\Test Folder\", "C:\Test Folder\Test\Test1\Test2\Test3\")
; Result: "C:\Test Folder\RANDOM_0\RANDOM_1\RANDOM_2\RANDOM_3\")

Func _DirRename($iInPath, $iOutPath)
    Local $TEMPiFrom, $TEMPiTo
    If StringRight($iInPath, 1) <> "\" Then $iInPath &= "\"
    If StringRight($iOutPath, 1) = "\" Then $iOutPath = StringTrimRight($iOutPath, 1)
    Local $iStringSplit = StringSplit(StringReplace($iOutPath, $iInPath, ""), "\")

    Local $TEMPiStringSplit = $iStringSplit[0]

    For $A = 1 To $iStringSplit[0]
        For $B = 1 To $TEMPiStringSplit
            $TEMPiFrom &= $iStringSplit[$B] & "\"
            If $B > 1 Then $TEMPiTo &= $iStringSplit[$B - 1] & "\"
        Next
        Local $iRandom = Chr(Random(Asc("a"), Asc("z"), 1)) & Random(1, 500, 1)

        If FileExists($iInPath & $TEMPiFrom) Then
            DirMove($iInPath & $TEMPiFrom, $iInPath & $TEMPiTo & $iRandom & "\")
            DirRemove($iInPath & $TEMPiTo & $iRandom)
        EndIf
        $TEMPiFrom = ""
        $TEMPiTo = ""
        $TEMPiStringSplit -= 1
    Next
EndFunc   ;==>_DirRename

Edited September 10, 2010 by guinness

[zorphnog]

Here's my crack at it:

_DirRandomize("C:\Test Folder\", "Test\Test1\Test2\Test3\")

Func _DirRandomize($sParent, $sChildren)
    Local $aChildren, $sCurDir, $i, $sNewDir
    If StringRight($sParent, 1) <> "\" Then $sParent &= "\"
    If StringRight($sChildren, 1) <> "\" Then $sChildren &= "\"
    $aChildren = StringRegExp($sChildren, "(?U:.+)\\", 3)
    If @error Then Return SetError(1, 0, 0)

    $sCurDir = $sParent
    For $i=0 To UBound($aChildren) - 1
        Do
            $sNewDir = $sCurDir & Chr(Random(97, 122, 1)) & Random(1, 500, 1) & "\"
        Until Not FileExists($sNewDir)
        DirMove($sCurDir & $aChildren[$i], $sNewDir)
        $sCurDir = $sNewDir
    Next
EndFunc

[XKahn]

Instead of DirMove () - Moving the contents of the sub directory and deleting the old folder you could use;

RunWait (@ComSpec & " /c rename " & $old_name & " " & $new_name, "", @SW_HIDE)

This drops to the cmd prompt level and uses rename to simply rename the folder, the contents remain unchanged. That should help cut down a lot of the bulk in your script.

[zorphnog]

Instead of DirMove () - Moving the contents of the sub directory and deleting the old folder you could use;

RunWait (@ComSpec & " /c rename " & $old_name & " " & $new_name, "", @SW_HIDE)

This drops to the cmd prompt level and uses rename to simply rename the folder, the contents remain unchanged. That should help cut down a lot of the bulk in your script.

Using DirMove with the source and destination in the same folder will simply rename the folder. Much in the way that the cmd prompt move works.

[guinness]

Excellent zorphnog! Different to how I did it and I especially like the use of StringRegExp instead of StringSplit.

I wanted to post a message like this because it's always great to see different styles of coding. Most of the 'stuff' I have learnt from the Help File (which is detailed) and Searching, hence why my number of posts are so low.

I may do these challenge posts from time to time, just to learn different styles.

[Spiff59]

There is one HUGE advantage to the DOS "rename" command, versus using the built-in DirMove() function to rename a folder.

DirMove() starts copying files, and only fails once it encounters a read-only or open file.

You're left with some of your files/folders moved, some not moved, and no record of which is which.

The DOS "rename" command functions much better as it will fail with an error code if any file is open, but leave your initial files and directory structure intact. No mess to clean up

Edited September 21, 2010 by Spiff59