State of the Listview

[JFX]

maybe I see something obvious not, but the Remark of GUICtrlGetState:

Exceptions:

For ListView controls it returns the number of the clicked column.

Leaves me with the question how to detect the State of the Listview?

For example if a listview was hidden with GUICtrlSetState, how can I detect if it is hidden or not?

[Melba23]

JFX,

Use WinGetState with the ListView handle to determine the state.

Press the button while the ListView is visible and then after 5 secs when it is hidden:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hLV = GUICtrlCreateListView("Col 1|Col2", 10, 10, 200, 200)

$hButton = GUICtrlCreateButton("State", 10, 300, 80, 30)

GUISetState()

$iBegin = TimerInit()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            $iState = WinGetState(GUICtrlGetHandle($hLV))
            If BitAnd($iState, 2) Then
                ConsoleWrite("ListView visible" & @CRLF)
            Else
                ConsoleWrite("ListView hidden" & @CRLF)
            EndIf
    EndSwitch

    If TimerDiff($iBegin) > 5000 Then
        GUICtrlSetState($hLV, $GUI_HIDE)
    EndIf
WEnd

Al clear?

M23

[JFX]

Al clear?

Yes, thanks a lot