Jump to content

Volume Control

AZJIO

By AZJIO,
in AutoIt Example Scripts

 Share

Recommended Posts

AZJIO Universalist

AZJIO

Posted
Posted (edited)

Volume Control (En, Ru)

HotKey = Shift+MouseWheel (or Ctrl, Alt)

VolCon.7z- v0.5, 266kb, exe+sources+hook.dll+sndico.dll

SoundGetSetQuery.au3 - Author:  Austin Beer

7xc.gif

 

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_OutFile=VolCon.exe
#AutoIt3Wrapper_icon=VolCon.ico
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_UseAnsi=y
#AutoIt3Wrapper_Res_Comment=-
#AutoIt3Wrapper_Res_Description=VolCon.exe
#AutoIt3Wrapper_Res_Fileversion=0.5.0.0
#AutoIt3Wrapper_Res_Fileversion_AutoIncrement=n
#AutoIt3Wrapper_Res_LegalCopyright=AZJIO
#AutoIt3Wrapper_Res_Language=1049
#AutoIt3Wrapper_Run_AU3Check=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

;  @AZJIO 23.09.2010 (AutoIt3_v3.2.12.1+)

#include <GUIConstantsEx.au3>
#include "SoundGetSetQuery.au3"
FileInstall("C:\sndico.dll", "*")
FileInstall("C:\hook.dll", "*")
Opt("TrayMenuMode", 7)
Opt("TrayOnEventMode", 1)

; En
$LngTitle='Volume Control'
$LngAbout='About'
$LngVer='Version'
$LngSite='Site'
$LngQuit='Exit'
$LngSet='Setting'
$LngTrn='Transparent (0-255)'
$LngSV='Set the volume at startup (0-100)'
$LngAS='Auto start when Windows starts'
$LngAp='Apply'
$LngTh='Themes'
$LngGHK='HotKey'
$LngHK='Regulation'
$LngHK1='+MouseWheel'
$LngHKM='Mute Ctrl+'
$LngMxr='Standard Mixer'


; Ru
Global $langdef = '0000'&@OSLang ; читаем язык по умолчанию
If $langdef = 00000419 Then
    $LngAbout='О программе'
    $LngVer='Версия'
    $LngSite='Сайт'
    $LngQuit='Выход'
    $LngSet='Настройки'
    $LngTrn='Прозрачность (0-255)'
    $LngSV='Установить громкость при старте (0-100)'
    $LngAS='Автостарт при загрузке Windows'
    $LngAp='Применить'
    $LngTh='Цветовая тема'
    $LngGHK='Горячие клавиши'
    $LngHK='Регулировка'
    $LngHK1='+Колёсико мыши'
    $LngHKM='Вкл/выкл Ctrl+'
    $LngMxr='Микшер Windows'
EndIf

Const $WH_MOUSE = 7
Const $WM_AUTOITMOUSEWHEELUP = 0x1400 + 0x0D30
Const $WM_AUTOITMOUSEWHEELDOWN = 0x1400 + 0x0D31

Global $tr = 0, $setico='', $TrGui=0, $iniTrn, $iniX, $iniY, $iniAtSt, $iniDV, $iniColBk, $iniColVol, $a, $iniHK='', $iniHKM=''
; Dim $a[101]

Global Const $WS_EX_TRANSPARENT = 0x00000020 ; прозрачность поддерживается
Global Const $WS_EX_TOPMOST = 0x00000008 ; поверх всех окон
Global Const $WS_POPUP = 0x80000000 ; без заголовка
Global Const $WS_EX_TOOLWINDOW = 0x00000080 ; не отображать в панели задач
; константы для перемещения индикатора
Global Const $HTCLIENT = 1
Global Const $HTCAPTION = 2

; Global Const $SS_LEFTNOWORDWRAP = 0xC
Global Const $SS_CENTERIMAGE = 0x0200
Global Const $SS_CENTER = 0x1
Global Const $SS_ETCHEDFRAME = 0x12

Global Const $TRAY_EVENT_PRIMARYDOUBLE = -13

Global $Ini = @ScriptDir&'\VolCon.ini'
If Not FileExists($Ini) Then 
$file = FileOpen($Ini,2)
FileWrite($file, _
'[setting]' & @CRLF & _
'transparent=190' & @CRLF & _
'xpos='&@DesktopWidth-60 & @CRLF & _
'ypos='&@DesktopHeight-165 & @CRLF & _
'DefVol=0' & @CRLF & _
'HotKey=A0' & @CRLF & _
'HotKeyM=' & @CRLF & _
'ColorBk=d0ff96' & @CRLF & _
'ColorVol=00d20a')
FileClose($file)
EndIf

$DWX= @DesktopWidth
$DWY= @DesktopHeight

$iniTrn= IniRead ($Ini, 'setting', 'transparent', '190')
$iniX= IniRead ($Ini, 'setting', 'xpos', $DWX-60)
$iniY= IniRead ($Ini, 'setting', 'ypos', $DWY-165)
$iniDV= IniRead ($Ini, 'setting', 'DefVol', '0')
$iniColBk= Dec(IniRead ($Ini, 'setting', 'ColorBk','d0ff96'))
$iniColVol= Dec(IniRead ($Ini, 'setting', 'ColorVol','00d20a'))
$iniHK= IniRead ($Ini, 'setting', 'HotKey', 'A0')
$iniHKM= IniRead ($Ini, 'setting', 'HotKeyM', '')
If $iniHK='' Then $iniHK='A0'
If $iniX > $DWX-30 Then $iniX=$DWX-60
If $iniY > $DWY-135 Then $iniY=$DWY-165
If $iniHKM<>'' Then HotKeySet('^{'&$iniHKM&'}', "_MUTE")


If StringLeft($iniDV, 1)<>0 Then _SoundSetMasterVolume(StringTrimLeft($iniDV, 1))

$gui = GUICreate($LngTitle, 30, 135, $iniX, $iniY, $WS_POPUP+$WS_EX_TRANSPARENT,$WS_EX_TOPMOST+$WS_EX_TOOLWINDOW)
TraySetIcon('stobject.dll', -3)
; If @compiled=0 Then TraySetIcon('stobject.dll', -3)
 ; скрипт назначения колёсику мыши горячей клавиши - http://www.autoitscript.com/forum/index.php?showtopic=27994&st=0&p=198681&#entry198681
; hook.dll - http://www.autoitscript.com/forum/index.php?showtopic=83645&st=0&p=598457&#entry598457
Global $DLLinst = DllCall("kernel32.dll", "hwnd", "LoadLibrary", "str", ".\hook.dll")
Global $mouseHOOKproc = DllCall("kernel32.dll", "hwnd", "GetProcAddress", "hwnd", $DLLinst[0], "str", "MouseProc")

Global $hhMouse = DllCall("user32.dll", "hwnd", "SetWindowsHookEx", "int", $WH_MOUSE, "hwnd", $mouseHOOKproc[0], "hwnd", $DLLinst[0], "int", 0)

DllCall(".\hook.dll", "int", "SetValuesMouse", "hwnd", $gui, "hwnd", $hhMouse[0])

GUIRegisterMsg($WM_AUTOITMOUSEWHEELUP, "myfunc")
GUIRegisterMsg($WM_AUTOITMOUSEWHEELDOWN, "myfunc")
TraySetOnEvent($TRAY_EVENT_PRIMARYDOUBLE,"_MUTE")
GUIRegisterMsg(0x0003 , "WM_MOVE")
$volcur=Int(_SoundGetMasterVolume())

; округление к кратным величинам
If $volcur > 20 Then
    $volcur-=Mod($volcur,5)
    _SoundSetMasterVolume($volcur)
EndIf
If $volcur < 20 And $volcur>5 Then
    $volcur-=Mod($volcur-2,3)
    _SoundSetMasterVolume($volcur)
EndIf

$vol=GUICtrlCreateLabel ($volcur,  0, 0, 30, 27, BitOR($SS_CENTER, $SS_CENTERIMAGE), $GUI_WS_EX_PARENTDRAG)
GUICtrlSetFont (-1,12,400)
GUICtrlSetCursor(-1, 0)
GUICtrlCreateLabel ('-',  2, 28, 27, 105, $SS_ETCHEDFRAME, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetCursor(-1, 0)
$b= GUICtrlCreateGraphic(4, 30, 22, 101)
GUICtrlSetBkColor(-1, $iniColBk)
WinSetTrans($gui,"", $iniTrn)
_indic($volcur)
_ico($volcur)
$delta=5
$GuiPos=''
If _SoundGetMasterMute()=1 Then TraySetIcon('sndico.dll', 12)

$nSet= TrayCreateItem($LngSet)
TrayItemSetOnEvent(-1, "_set")

$nMixer= TrayCreateItem($LngMxr)
TrayItemSetOnEvent(-1, "_Mixer")

$nAbout= TrayCreateItem($LngAbout)
TrayItemSetOnEvent(-1, "_about")

$nExit = TrayCreateItem($LngQuit) 
TrayItemSetOnEvent(-1, "_Quit")

TraySetToolTip($LngTitle)

While 1
    Sleep(500)
    If $tr = 1 Then
        $tr = 0
        Sleep(1500)
        If $tr = 0 Then
            If $DWX=@DesktopWidth And $DWY=@DesktopHeight Then
                $GuiPos = WinGetPos($Gui)
                $iniX=$GuiPos[0]
                $iniY=$GuiPos[1]
            EndIf
            GuiSetState(@SW_HIDE)
        EndIf
    EndIf
    Sleep(500)
    $tr1 = 0
WEnd

Func MyFunc($hWndGUI, $MsgID, $WParam, $LParam)
If Not _IsPressed($iniHK) Or $TrGui=1 Or _SoundGetMasterMute()=1 Then Return
$V=Int(_SoundGetMasterVolume())
GuiSetState(@SW_SHOWNA)
$tr = 1
    Select 
        case $msgid=$WM_AUTOITMOUSEWHEELUP
            If $delta=0 Then Return
            If $V>=20 Then $delta=5
            If $V<20 Then $delta=3
            If $V<5 Then $delta=1
            If $V+$delta > 100 Then $delta=100-$V
           _SoundSetMasterVolume($V+$delta)
            _indic($V+$delta)
            GUICtrlSetData($vol,$V+$delta)
            _ico($V+$delta)
        case $msgid=$WM_AUTOITMOUSEWHEELDOWN
            If $V=0 Then Return
            If $V>20 Then $delta=5
            If $V<=20 Then $delta=3
            If $V<=5 Then $delta=1
            ; If $V-$delta < 0 Then $delta=$V+1
            _SoundSetMasterVolume($V-$delta)
            _indic($V-$delta)
            GUICtrlSetData($vol,$V-$delta)
            _ico($V-$delta)
    EndSelect
    If $DWX=@DesktopWidth And $DWY=@DesktopHeight Then
        If $GuiPos<>'' Then
            $iniX=$GuiPos[0]
            $iniY=$GuiPos[1]
        EndIf
        WinMove($gui, "", $iniX, $iniY)
    Else
        WinMove($gui, "", @DesktopWidth-60, @DesktopHeight-165)
    EndIf
EndFunc

Func _IsPressed($sHexKey, $vDLL = 'user32.dll')
    Local $a_R = DllCall($vDLL, "short", "GetAsyncKeyState", "int", '0x' & $sHexKey)
    If @error Then Return SetError(@error, @extended, False)
    Return BitAND($a_R[0], 0x8000) <> 0
EndFunc

Func _indic($V)
    GUICtrlDelete($a)
    $a = GUICtrlCreateGraphic(4, 130-$V, 22, $V)
    GUICtrlSetBkColor(-1, $iniColVol)
    GUICtrlSetGraphic($a, $GUI_GR_REFRESH)
EndFunc

Func _Quit()
    TraySetState(2)
    DllCall("user32.dll", "int", "UnhookWindowsHookEx", "hwnd", $hhMouse[0])
    DllCall("kernel32.dll", "int", "FreeLibrary", "hwnd", $DLLinst[0])
    If $GuiPos<>'' Then
        IniWrite($Ini, "setting", "xpos", $GuiPos[0])
        IniWrite($Ini, "setting", "ypos", $GuiPos[1])
    EndIf
    Exit
EndFunc

Func _ico($V, $m=0)
$tmp=$setico
Switch $V
    Case 0 To 5
       $setico=1
    Case 6 To 15
       $setico=2
    Case 16 To 25
       $setico=3
    Case 26 To 35
       $setico=4
    Case 36 To 45
       $setico=5
    Case 46 To 55
       $setico=6
    Case 56 To 65
       $setico=7
    Case 66 To 75
       $setico=8
    Case 76 To 85
       $setico=9
    Case 86 To 95
       $setico=10
    Case 96 To 100
       $setico=11
    Case Else
       $setico=12
EndSwitch
If $setico <> $tmp Or $m=1 Then _TrayIcon($setico)
EndFunc

Func _TrayIcon($setico)
    TraySetIcon('sndico.dll', $setico)
    ; If @compiled=0 Then TraySetIcon('stobject.dll', -3)
EndFunc

Func WM_MOVE()
    If $DWX=@DesktopWidth And $DWY=@DesktopHeight Then
        $GuiPos = WinGetPos($Gui)
        $iniX=$GuiPos[0]
        $iniY=$GuiPos[1]
    EndIf
    $tr = 1
EndFunc

Func _set()
    $TrGui=1
    TrayItemSetState($nSet,128)
    TrayItemSetState($nAbout,128)
    TrayItemSetState($nExit,128)

    GUISetState(@SW_DISABLE, $Gui)
    $Gui1 = GUICreate($LngTitle, 300, 230, @DesktopWidth-370, @DesktopHeight-295, -1, 0x00000080,$Gui)

    $TrnInp= GUICtrlCreateInput($iniTrn, 5, 10, 35, 21)
    GUICtrlCreateLabel($LngTrn, 45, 12, 160, 17, 0xC)

    $DefVolInp= GUICtrlCreateInput(_SoundGetMasterVolume(), 5, 35, 35, 21)
    $ChDV=GUICtrlCreateCheckbox ($LngSV, 45, 37, 250, 17)
    If StringLeft($iniDV, 1)<>0 Then GuiCtrlSetState($ChDV, 1)

    $ChAS=GUICtrlCreateCheckbox ($LngAS, 5, 62, 200, 17)
    RegRead("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "Volume_Control")
    If Not @Error Then GuiCtrlSetState($ChAS, 1)

    $ChTh=GUICtrlCreateCheckbox ($LngTh, 5, 87, 105, 17)
    $ThInp= GUICtrlCreateCombo('', 110, 85, 90, 21)
    GUICtrlSetData(-1, 'Green|Red|Blue|Yellow', 'Green')
    Switch HEX($iniColVol,6)
        Case '00d20a'
            GUICtrlSetData($ThInp,'Green')
        Case 'd4451d'
            GUICtrlSetData($ThInp,'Red')
        Case '01adcf'
            GUICtrlSetData($ThInp,'Blue')
        Case 'e8db00'
            GUICtrlSetData($ThInp,'Yellow')
    EndSwitch
    $gr1 = GUICtrlCreateGraphic(205, 85, 22, 11)
    GUICtrlSetBkColor(-1, $iniColBk)
    $gr2 = GUICtrlCreateGraphic(205, 96, 22, 11)
    GUICtrlSetBkColor(-1, $iniColVol)
    $gr3 = GUICtrlCreateGraphic(230, 85, 22, 11)
    GUICtrlSetBkColor(-1, $iniColBk)
    $gr4 = GUICtrlCreateGraphic(230, 96, 22, 11)
    GUICtrlSetBkColor(-1, $iniColVol)
    
    GUICtrlCreateGroup($LngGHK, 1, 112, 297, 73)

    $ChHK=GUICtrlCreateCheckbox ($LngHK, 5, 132, 105, 17)
    $HKInp= GUICtrlCreateCombo('', 110, 130, 90, 21)
    GUICtrlSetData(-1, 'Left SHIFT|Right SHIFT|SHIFT|Left Ctrl|Right Ctrl|Ctrl|Alt', 'Left SHIFT')
    GUICtrlCreateLabel($LngHK1, 203, 132, 93, 17, 0xC)
    Switch $iniHK
        Case 'A0'
            GUICtrlSetData($HKInp,'Left SHIFT')
        Case 'A1'
            GUICtrlSetData($HKInp,'Right SHIFT')
        Case '10'
            GUICtrlSetData($HKInp,'SHIFT')
        Case 'A2'
            GUICtrlSetData($HKInp,'Left Ctrl')
        Case 'A3'
            GUICtrlSetData($HKInp,'Right Ctrl')
        Case '11'
            GUICtrlSetData($HKInp,'Ctrl')
        Case '12'
            GUICtrlSetData($HKInp,'Alt')
    EndSwitch

    $ChHKM=GUICtrlCreateCheckbox ($LngHKM, 5, 157, 105, 17)
    $HKMInp= GUICtrlCreateCombo('', 110, 155, 90, 21)
    GUICtrlSetData(-1, '|PAUSE|F12|9|0', $iniHKM)
    If Not StringInStr('|PAUSE|F12|9|0|', '|'&$iniHKM&'|') And $iniHKM<>'' Then
        GUICtrlSetData($HKMInp,$iniHKM,$iniHKM)
    EndIf
    If $iniHKM<>'' Then GuiCtrlSetState($ChHKM, 1)

    $apply=GUICtrlCreateButton ($LngAp,  210, 195, 85, 30)
    GUISetState(@SW_SHOW, $Gui1)
    $msg = $Gui1
    
    While 1
      $msg = GUIGetMsg()
      Select
        Case $msg = $HKMInp
            GuiCtrlSetState($ChHKM, 1)
        Case $msg = $ThInp
            GuiCtrlSetState($ChTh, 1)
            Switch GUICtrlRead($ThInp)
                Case 'Green'
                    GUICtrlSetBkColor($gr3, Dec('d0ff96'))
                    GUICtrlSetBkColor($gr4, Dec('00d20a'))
                Case 'Red'
                    GUICtrlSetBkColor($gr3, Dec('fbb194'))
                    GUICtrlSetBkColor($gr4, Dec('d4451d'))
                Case 'Blue'
                    GUICtrlSetBkColor($gr3, Dec('a7f2fc'))
                    GUICtrlSetBkColor($gr4, Dec('01adcf'))
                Case 'Yellow'
                    GUICtrlSetBkColor($gr3, Dec('fbffab'))
                    GUICtrlSetBkColor($gr4, Dec('e8db00'))
            EndSwitch
            GUICtrlSetGraphic($a, $GUI_GR_REFRESH)
        Case $msg = $HKInp
            GuiCtrlSetState($ChHK, 1)
        Case $msg = $apply
            $iniTrn = GUICtrlRead($TrnInp)
            IniWrite($Ini, "setting", "transparent", $iniTrn)
            WinSetTrans($gui,"", $iniTrn)
            If GUICtrlRead($ChDV) = 1 Then
                $DefVolInp0 = GUICtrlRead($DefVolInp)
                $iniDV='1'&$DefVolInp0
                IniWrite($Ini, "setting", "DefVol", $iniDV)
            Else
                IniWrite($Ini, "setting", "DefVol", '0')
                $iniDV=0
            EndIf
            If GUICtrlRead($ChAS)=1 Then
                RegWrite("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "Volume_Control", "REG_SZ", '"'&@AutoItExe&'"')
            Else
                RegDelete("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "Volume_Control")
            EndIf
            If GUICtrlRead($ChTh) = 1 Then
                Switch GUICtrlRead($ThInp)
                    Case 'Green'
                        _Color('d0ff96', '00d20a')
                    Case 'Red'
                        _Color('fbb194', 'd4451d')
                    Case 'Blue'
                        _Color('a7f2fc', '01adcf')
                    Case 'Yellow'
                        _Color('fbffab', 'e8db00')
                EndSwitch
            EndIf
            If GUICtrlRead($ChHK) = 1 Then
                Switch GUICtrlRead($HKInp)
                    Case 'Left SHIFT'
                        $iniHK='A0'
                    Case 'Right SHIFT'
                        $iniHK='A1'
                    Case 'SHIFT'
                        $iniHK='10'
                    Case 'Left Ctrl'
                        $iniHK='A2'
                    Case 'Right Ctrl'
                        $iniHK='A3'
                    Case 'Ctrl'
                        $iniHK='11'
                    Case 'Alt'
                        $iniHK='12'
                    Case Else
                        $iniHK='A0'
                EndSwitch
                IniWrite($Ini, "setting", "HotKey", $iniHK)
            EndIf
    
            If GUICtrlRead($ChHKM) = 1 And GUICtrlRead($HKMInp)<>'' Then
                If $iniHKM<>'' Then HotKeySet('^{'&$iniHKM&'}')
                $iniHKM=GUICtrlRead($HKMInp)
                If $iniHKM<>'' Then
                    HotKeySet('^{'&$iniHKM&'}', "_MUTE")
                    IniWrite($Ini, "setting", "HotKeyM", $iniHKM)
                EndIf
            Else
                If $iniHKM<>'' Then HotKeySet('^{'&$iniHKM&'}')
                $iniHKM=''
                IniWrite($Ini, "setting", "HotKeyM", '')
            EndIf
            
            ContinueCase 
        Case $msg = -3
            $msg = $Gui
            GUIDelete($Gui1)
            TrayItemSetState($nSet,64)
            TrayItemSetState($nAbout,64)
            TrayItemSetState($nExit,64)
            GUISetState(@SW_ENABLE, $Gui)
            $TrGui=0
            ExitLoop
        EndSelect
    WEnd
EndFunc

Func _Color($1, $2)
    IniWrite($Ini, "setting", "ColorBk", $1)
    IniWrite($Ini, "setting", "ColorVol", $2)
    $iniColBk=Dec($1)
    $iniColVol=Dec($2)
    GUICtrlSetBkColor($b, $iniColBk)
    GUICtrlSetBkColor($a, $iniColVol)
EndFunc

Func _MUTE()
    $Mute=_SoundGetMasterMute()
    If $Mute = 0 Then
        _SoundSetMasterMute(1)
        TraySetIcon('sndico.dll', 12)
    EndIf
    If $Mute = 1 Then
        _SoundSetMasterMute(0)
        _ico(_SoundGetMasterVolume(), 1)
    EndIf
EndFunc

Func _Mixer()
    Run(@ComSpec & " /c rundll32.exe shell32.dll,Control_RunDLL mmsys.cpl,,0", '', @SW_HIDE)
    If $langdef = 00000419 Then
        $title='Свойства: Звуки и аудиоустройства'
        WinWaitActive($title)
        ControlClick($title, "", "[CLASS:Button; INSTANCE:4]")
        WinClose($title)
    EndIf
EndFunc

Func _About()
$TrGui=1
TrayItemSetState($nSet,128)
TrayItemSetState($nAbout,128)
TrayItemSetState($nExit,128)

GUISetState(@SW_DISABLE, $Gui)
$font="Arial"
    $Gui1 = GUICreate($LngAbout, 270, 180, -1, -1, -1, 0x00000080,$Gui)
    GUISetBkColor (0xf8c848)
    GUICtrlCreateLabel($LngTitle, 0, 20, 270, 23, 0x01)
    GUICtrlSetFont (-1,15, 600, -1, $font)
    GUICtrlSetColor(-1,0xa21a10)
    GUISetFont (9, 600, -1, $font)
    GUICtrlCreateLabel($LngVer&' 0.5  23.09.2010', 55, 100, 210, 17)
    GUICtrlCreateLabel($LngSite&':', 55, 115, 40, 17)
    $url=GUICtrlCreateLabel('http://azjio.ucoz.ru', 92, 115, 170, 17)
    GUICtrlSetCursor(-1, 0)
    GUICtrlSetColor(-1, 0x0000ff)
    GUICtrlCreateLabel('WebMoney: R939163939152', 55, 130, 210, 17)
    GUICtrlCreateLabel('Copyright AZJIO © 2010', 55, 145, 210, 17)
    GUISetState(@SW_SHOW, $Gui1)
$msg = $Gui1
    While 1
      $msg = GUIGetMsg()
      Select
        Case $msg = $url
            ShellExecute ('http://azjio.ucoz.ru')
        Case $msg = -3
            $msg = $Gui
            GUIDelete($Gui1)
            TrayItemSetState($nSet,64)
            TrayItemSetState($nAbout,64)
            TrayItemSetState($nExit,64)
            GUISetState(@SW_ENABLE, $Gui)
            $TrGui=0
            ExitLoop
        EndSelect
    WEnd
EndFunc
           

  Updated, v0.5

Mute - HotKey

rounding

ico

Updated, v0.4

The program does not turn off the game when you call the hot key

Choice of hot keys

When you change the screen resolution during the start of the game, the "Volume Control" displays in the visible region

  

Updated, v0.3

Mute - Double click on the icon

Themes - Green, Red, Blue, Yellow (Setting)

Fix - Func _indic($V)

Edited by AZJIO

My other projects or all

Link to comment
Share on other sites
Yashied Universalist

Yashied

Posted
Posted

Unfortunately, VolCon will not work in Windows Vista/7.

My UDFs:

iKey | FTP Uploader | Battery Checker | Boot Manager | Font Viewer | UDF Keyword Manager | Run Dialog Replacement | USBProtect | 3D Axis | Calculator | Sleep | iSwitcher | TM | NetHelper | File Types Manager | Control Viewer | SynFolders | DLL Helper

Animated Tray Icons UDF Library | Hotkeys UDF Library | Hotkeys Input Control UDF Library | Caret Shape UDF Library | Context Help UDF Library | Most Recently Used List UDF Library | Icons UDF Library | FTP UDF Library | Script Communications UDF Library | Color Chooser UDF Library | Color Picker Control UDF Library | IPHelper (Vista/7) UDF Library | WinAPI Extended UDF Library | WinAPIVhd UDF Library | Icon Chooser UDF Library | Copy UDF Library | Restart UDF Library | Event Log UDF Library | NotifyBox UDF Library | Pop-up Windows UDF Library | TVExplorer UDF Library | GuiHotKey UDF Library | GuiSysLink UDF Library | Package UDF Library | Skin UDF Library | AITray UDF Library | RDC UDF Library

Appropriate path | Button text color | Gaussian random numbers | Header's styles (Vista/7) | ICON resource enumeration | Menu & INI | Tabbed string size | Tab's skin | Pop-up circular menu | Progress Bar without animation (Vista/7) | Registry export | Registry path jumping | Unique hardware ID | Windows alignment

More...

qrcode.png

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share
Go to topic listing

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...