How to add dimension to an existing array?

[zwierzak]

Hello. I have a problem. I've described it in the code's comments

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $item[30]
GUICreate("listview items", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
GUISetBkColor(0x00E0FFFF) ; will change background color
$listview = GUICtrlCreateListView("X|Y", 10, 10, 165, 200)
$button = GUICtrlCreateButton("Refresh", 5, 220, 70, 20)
$button2 = GUICtrlCreateButton("test", 75, 220, 70, 20)
GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            $var = WinList("notepad") 
            For $i = 1 To $var[0][0]
                
                If $var[$i][0] <> "" And IsVisible($var[$i][1]) Then 
                    $string = StringSplit($var[$i][0], "-")
                    $item[$i] = GUICtrlCreateListViewItem($string[3], $listview)
                    
                    ;HOW TO MAKE IT LIKE THIS?
                    ;$string[$i] = StringSplit($var[$i][0], "-")
                    ;$item[$i] = GUICtrlCreateListViewItem($string[$i][3], $listview)
                    ;I want to make X number of strings, but it already has got 1 array. How to make another one - add new dimension to the existing array?
                EndIf
            Next
        Case $button2
            MsgBox(0,GUICtrlRead($listview), "text")
    EndSwitch
WEnd

Func IsVisible($handle)
    If BitAND(WinGetState($handle), 1) Then
        Return 1
    Else
        Return 0
    EndIf

EndFunc   ;==>IsVisible

I'd like to make it like this but dunno how

;HOW TO MAKE IT LIKE THIS?

;$string[$i] = StringSplit($var[$i][0], "-")

;$item[$i] = GUICtrlCreateListViewItem($string[$i][3], $listview)

;I want to make X number of strings, but it already has got 1 array. How to make another one - add new dimension to the existing array?

Edited September 18, 2010 by zwierzak

[MvGulik]

"How to add new dimension to the existing array?"

Assuming: while maintaining the data inside the array.

By copying the data from one array(old) to the other array(new)

Redim allows you to change the size of the exiting dimensions while maintaining the data inside the array.

(Redim also allows the number of dimensions of a existing array to be changed, but in such a case the array data will be lost/cleared.)

Edited September 18, 2010 by MvGulik

[Melba23]

zwierzak,

Just use ReDim like this:

#include <Array.au3>

Global $aArray[2][2] = [["A", "B"], ["C", "D"]]

_ArrayDisplay($aArray)

ReDim $aArray[UBound($aArray)][3]

_ArrayDisplay($aArray)

M23

[ProgAndy]

@Melba23: As far as I remember this wasn't possible in older versions of AutoIt, but it seems the behaviour has changed. This means, MvGulik's statment is now incorrect. Edited September 18, 2010 by ProgAndy

[zwierzak]

Thats weird for me, cos Redim didn't work for me. So I've tried to make another array which will keep the previous array's data. And u know what? It works xD

Global $newstring[30]
$string = StringSplit($var[$i][0], "-")                     
_ArrayDisplay($string)                  
$newstring[$i] = $string[3]                     
$item[$i] = GUICtrlCreateListViewItem($newstring[$i], $listview)

[Melba23]

Guys,

Do not get confused between the number of dimensions (the number of [ ] after the array name) and the size of existing dimensions (changing the number within an existing [ ]).

If you want to retain the existing data in an array, there is no way to increase the number of dimensions, you have to copy the data from the existing array to another array with the required number of dimensions. Using any form of declaration (Global/Local/Dim/Redim) and changing the number of dimensions will erase all existing elements from the array.

However, by using ReDim you can alter the size of existing dimensions without deleting existing elements as I showed above.

M23

Edit: Amended as explained in the posts below.

Edited September 19, 2010 by Melba23

[ProgAndy]

Oh right. I really should read more carefully.

[RagsRevenge]

Guys,

ReDim will not increase the number of dimensions - it will not turn $aArray[x][y] into $aArray[x][y][z]. But it will alter the size of existing dimensions as I showed above.

Do not get confused between the number of dimensions (the number of [ ] after the array name) and the size of existing dimensions (changing the number within an existing [ ]).

M23

Oh dear, I've written a function specially to deal with my misreading of that.

D

[MvGulik]

ReDim will not increase the number of dimensions - it will not turn $aArray[x][y] into $aArray[x][y][z]. But it will alter the size of existing dimensions as I showed above.

Brrr. Why do I have a problem with this. O yea, being a nitpick.

[Melba23]

MvGulik,

What is bugging you about the statement? I am happy to change it if you feel it is less than clear.

My definition of the number of dimensions matches that used in geometry:

1D array = a line of elements, with a single coordinate

2D array = a plane with x,y coordinates

3D array = a volume with x, y, z coordinates

......

The size of the dimensions just sets the length, area and volume respectively of the space needed to hold the elements.

M23

[Ascend4nt]

Just taking a shot in the dark here Melba, but I'm guessing the nitpicking is about the fact that you can increase the number of dimensions with ReDim. The problem is doing that will destroy the data and has a net effect of being just another new 'Dim'.

MvGulik was correct in his first post regarding copying the data to a new multi-dimensional array, as that is the only way to 'add' dimensions.

[MvGulik]

Nothing wrong with your definitions. You know them better than I do.

But...

Local $array[1]=[1]
    DebugOut('$array', $array) ;### Debug DebugOut.
    ReDim $array[1][2]
    DebugOut('$array', $array) ;### Debug DebugOut.

!> MAIN()
--- --- 0 (array dump), $array:[1].
.   000 |I3| 1 (0x00.00.00.00.00.00.00.01)
--- --- 0 [0,0]
--- --- 0 (array dump), , $array:[1][2].
--- |--| 0| 1|
[0] |St|  |  | 
--- --- 0 [0,0]
!< MAIN()

Redim just changed the number of dimensions. from array[x] to array[x][y]

(its the fact that you can't do it while preserving the data inside a array.)

---

Depending on the point of view. Your also correct of course. As it could be argued that when Redim is used to change the number of dimensions on a existing array. Redim will internally toss the existing array/data and create a new(empty) array for the used variable/$name.

Edited September 19, 2010 by MvGulik

[Melba23]

MvGulik & Ascend4nt,

Understood.

I must admit that I had not realised that ReDim could actually redeclare an array with a different number of dimensions - albeit loosing the data in the process. I have only ever used it to resize existing dimensions - as the OP needed.

You live and learn each day - I have amended the earlier post. Thanks for pointing it out.

M23