Need Help With the Guictrlcreate Tab

[Mohit 0]

Guys , i Have created the tabs i was just wondering is it possible that say i have 5 tabs each tab can have a different background Image Or Color.

[Melba23 3,496]

Mohit,

You can colour the tabs lke this:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiTab.au3>

$hGUI = GUICreate("_GUICtrlTab_SetBkColor() Demo", 320, 280)

$hTab = GUICtrlCreateTab(10, 20, 300, 250)

GUICtrlCreateTabItem("Tab 1")
_GUICtrlTab_SetBkColor($hGUI, $hTab, 0xFF0000)

GUICtrlCreateButton("Some Button", 20, 50)

GUICtrlCreateTabItem("Tab 2")
_GUICtrlTab_SetBkColor($hGUI, $hTab, 0x00CC00)

GUICtrlCreateCheckbox("Some Checkbox", 20, 50)

 GUICtrlCreateTabItem(""); end tabitem definition

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUICtrlTab_SetBkColor($hWnd, $hSysTab32, $sBkColor)

    Local $aTabPos = ControlGetPos($hWnd, "", $hSysTab32)
    Local $aTab_Rect = _GUICtrlTab_GetItemRect($hSysTab32, -1)
    GUICtrlCreateLabel("", $aTabPos[0] + 2, $aTabPos[1] + $aTab_Rect[3] + 4, $aTabPos[2] - 6, $aTabPos[3] - $aTab_Rect[3] - 7)
    GUICtrlSetBkColor(-1, $sBkColor)
    GUICtrlSetState(-1, $GUI_DISABLE)

EndFunc   ;==>_GUICtrlTab_SetBkColor

I have never tried images. Give it a go using the same principle and see if it works - please let me know how you get on.

M23

Edit: I got bored (Ryder Cup rained off) - it does work for images as well:

Func _GUICtrlTab_SetBkPic($hWnd, $hSysTab32, $sPic)

    Local $aTabPos = ControlGetPos($hWnd, "", $hSysTab32)
    Local $aTab_Rect = _GUICtrlTab_GetItemRect($hSysTab32, -1)
    GUICtrlCreatePic($sPic, $aTabPos[0] + 2, $aTabPos[1] + $aTab_Rect[3] + 4, $aTabPos[2] - 6, $aTabPos[3] - $aTab_Rect[3] - 7)
    GUICtrlSetState(-1, $GUI_DISABLE)

EndFunc   ;==>_GUICtrlTab_SetBkPic

Edited October 1, 2010 by Melba23

[Mohit 0]

thanks i will try that.