how to make the string bigger?

[Merchants]

how to make the string bigger?

from this

to this

and how do i get to only in sec and mins i don't need the hours so like this 00:02 Mins, Secs

expandcollapse popup

; *** Demo to show a timer window
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Date.au3>

Opt("TrayIconDebug", 1)

Opt("MustDeclareVars", 1)

Global $timer, $Secs, $Mins, $Hour, $Time

_Main()

Func _Main()
    ;Create GUI
    GUICreate("Timer", 90, 30)
    GUICtrlCreateLabel("00:00:00", 10, 10)
    GUISetStyle($WS_POPUP)
    GUISetState()
    ;Start timer
    $timer = TimerInit()
    AdlibEnable("Timer", 50)
    ;
    While 1
        ;FileWriteLine("debug.log",@min & ":" & @sec & " ==> before")
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
        ;FileWriteLine("debug.log",@min & ":" & @sec & " ==> after")
    WEnd
EndFunc   ;==>_Main
;
Func Timer()
    _TicksToTime(Int(TimerDiff($timer)), $Hour, $Mins, $Secs)
    Local $sTime = $Time  ; save current time to be able to test and avoid flicker..
    $Time = StringFormat("%02i:%02i:%02i", $Hour, $Mins, $Secs)
    If $sTime <> $Time Then ControlSetText("Timer", "", "Static1", $Time)
EndFunc   ;==>Timer

Edited October 1, 2010 by Merchants

[Melba23]

Merchants,

After this line:

GUICtrlCreateLabel("00:00:00", 10, 10)

you need one beginning with

GUICtrlSetFont(-1, .........)

But do make sure your label is big enough to hold the bigger string.

You might also make life much easier for yourself by doing this:

expandcollapse popup

; *** Demo to show a timer window
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Date.au3>

Global $hLabel ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<

Opt("TrayIconDebug", 1)

Opt("MustDeclareVars", 1)

Global $timer, $Secs, $Mins, $Hour, $Time

_Main()

Func _Main()
    ;Create GUI
    GUICreate("Timer", 90, 30)
    $hLabel = GUICtrlCreateLabel("00:00:00", 10, 10, 100, 20) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    GUICtrlSetFont(-1, 12) ; This sets 12 point text <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    GUISetStyle($WS_POPUP)
    GUISetState()
    ;Start timer
    $timer = TimerInit()
    AdlibRegister("Timer", 50)
    ;
    While 1
        ;FileWriteLine("debug.log",@min & ":" & @sec & " ==> before")
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
        ;FileWriteLine("debug.log",@min & ":" & @sec & " ==> after")
    WEnd
EndFunc   ;==>_Main
;
Func Timer()
    _TicksToTime(Int(TimerDiff($timer)), $Hour, $Mins, $Secs)
    Local $sTime = $Time  ; save current time to be able to test and avoid flicker..
    $Time = StringFormat("%02i:%02i:%02i", $Hour, $Mins, $Secs)
    If $sTime <> $Time Then GUICtrlSetData($hLabel, $Time) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<
EndFunc   ;==>Timer

It is a lot easier when you have created the controls. The Control* commands are for controls in other GUIs.

M23

[ajag]

Merchants,

GUICreate("Timer", 120, 50)                       ; <<<<< enlarge the GUI
  GUICtrlCreateLabel("00:00:00", 10, 10, 120, 50)   ; <<<<< enlarge the label
  GUICtrlSetFont(-1,20,200)                         ; <<<<< Set a big font for the label

[Merchants]

wel this is usefull ty

and how do i remove the hours i have try that but getting errors

[dwerf]

Line 41 (37 in first post)

$Time = StringFormat("%02i:%02i", $Mins, $Secs)

Edited October 1, 2010 by dwerf