GUICtrlSetTip in Treeview

[Jayson]

Hello guys ! I would like to know if it's possible to make a GUICtrlSetTip on some specific item from Treeview filled by a 2d Array.

I made some research and can't find any good example for my project.

Edited October 19, 2010 by Jayson

[Melba23]

Jayson,

I am not sure you can have ToolTips in a Treeview.

If you look at these 2 treeviews (the top one created with the UDF; the lower with the native commands) you can see that there is a "tooltip-like" box which shows the text of an item which is too long to fit in the control.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiTreeView.au3>

Global $aData[3][2] = [[1, 11], [1, 12], [2, 21]]

$hGUI = GUICreate("Test", 500, 500)

$hTV1 = _GUICtrlTreeView_Create($hGUI, 10, 10, 100, 100)

_GUICtrlTreeView_BeginUpdate($hTV1)

$iCurrent_Parent = 0
For $i = 0 To UBound($aData) - 1
    If $aData[$i][0] <> $iCurrent_Parent Then
        $iCurrent_Parent = $aData[$i][0]
        $hParent = _GUICtrlTreeView_Add($hTV1, 0, "Parent " & $aData[$i][0])
    EndIf
    $hChild = _GUICtrlTreeView_AddChild($hTV1, $hParent, "Child " & $aData[$i][1] & " with a very long name")
Next

_GUICtrlTreeView_EndUpdate($hTV1)

$hTV2 = GUICtrlCreateTreeView(10, 200, 100, 100)

$iCurrent_Parent = 0
For $i = 0 To UBound($aData) - 1
    If $aData[$i][0] <> $iCurrent_Parent Then
        $iCurrent_Parent = $aData[$i][0]
        $hParent = GUICtrlCreateTreeViewItem("Parent " & $aData[$i][0], $hTV2)
    EndIf
    $hChild = GUICtrlCreateTreeViewItem("Child " & $aData[$i][1] & " with a very long name", $hParent)
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

As you can only have one tooltip per control (as far as I know) that means that there is no room for a user-defined tooltip - certainly none of my tooltip code can produce one and, like you, I can find nothing on the forum.

Looks like this one might be impossible (that should get someone running to prove me wrong!).

M23

[Jayson]

I'll keep trying until I give up. First, i'm thinking of creating 2 identical TV. One too small that show the ToolTip of the text too long and one normal. So we could grab the tooltip and match it with any array.

OR

Addind spaces to the ends of every array so it will looks like it doesn't fit and display the tooltip so we can change it after.

Do you think that work around would work ?

Edited October 19, 2010 by Jayson

[BrewManNH]

You might be able to do it with a ToolTip and use the $TVS_TRACKSELECT parameter. Not sure as I haven't tried it.

[Melba23]

Jayson,

Do not thank me (other than for my searching abilities! ), thank a very good coder called Siao:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>

Global $aData[3][2] = [["Parent 1", "Child 11 with a very long name"],["Parent 1", "Child 12 with a very long name"],["Parent 2", "Child 21 with a very long name"]]

$hGUI = GUICreate("Test", 500, 500)
GUISetBkColor(0xC4C4C4)

$hTV1 = _GUICtrlTreeView_Create($hGUI, 10, 10, 150, 150)

_GUICtrlTreeView_BeginUpdate($hTV1)

$sParent = ""
For $i = 0 To UBound($aData) - 1

    ConsoleWrite($aData[$i][0] & @CRLF)

    If $aData[$i][0] <> $sParent Then
        $sParent = $aData[$i][0]
        $hParent = _GUICtrlTreeView_Add($hTV1, 0, $aData[$i][0])
    EndIf
    $hChild = _GUICtrlTreeView_AddChild($hTV1, $hParent, $aData[$i][1])
Next

_GUICtrlTreeView_EndUpdate($hTV1)

$hTV2 = GUICtrlCreateTreeView(10, 200, 150, 150)
$hTV2_Handle = GUICtrlGetHandle($hTV2)

$sParent = ""
For $i = 0 To UBound($aData) - 1
    If $aData[$i][0] <> $sParent Then
        $sParent = $aData[$i][0]
        $hParent = GUICtrlCreateTreeViewItem($aData[$i][0], $hTV2)
    EndIf
    $hChild = GUICtrlCreateTreeViewItem($aData[$i][1], $hParent)
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_MOUSEMOVE
            SetTip()
    EndSwitch
WEnd

Func SetTip()

    $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "uint", MouseGetPos(0), "uint", MouseGetPos(1))
    Switch $aHwnd[0]
        Case $hTV1, $hTV2_Handle

            $tMPos = _WinAPI_GetMousePos(True, $aHwnd[0])
            $hItem = _GUICtrlTreeView_HitTestItem($aHwnd[0], DllStructGetData($tMPos, 1), DllStructGetData($tMPos, 2))

            If $hItem = 0 Then
                ToolTip("")
            Else
                ToolTip(_GUICtrlTreeView_GetText($aHwnd[0], $hItem))
            EndIf
    EndSwitch

EndFunc

Enjoy!

M23

[Jayson]

Melba,

I might not get what that code does because it still doing the same thing as your other code

[Melba23]

Jayson,

Do you not get a ToolTip with the name of the item you are hovering over - as well as the normal "full length" tooltip if the item is too long?

M23

[Jayson]

Melba,

Not at all it just show the tooltip because the text if too long not the other one

[Melba23]

Jayson,

What OS and AutoIt version do you use?

M23

[Jayson]

Melba,

I'm using W7 x64 with AutoIT version 3.3.6.1

[Melba23]

Jayson,

Try increasing the width of the 2 treeviews to 250 so the "full length" tooltip is not used - do you get the mouse based ToolTip then?

M23

[Jayson]

Melba,

I increased the width but i still don't see the mouse tooltip. That's pretty strange.

[Melba23]

Jayson,

Please run the ToolTip example from the Help file - do you see it then?

M23

[Jayson]

Melba,

It works with these example. ToolTip and GUICtrlSetTip is showing correctly but not with the code you showed me.

Edited October 19, 2010 by Jayson

[Bert]

I have a 64bit Windows 7 rig. I'm getting the same result as Jayson.

[BrewManNH]

I am running Win7 x86 and it's working ok for me. The only problem I found with the code is that the tooltip is very persistent and takes some work to get rid of it from every screen. As soon as you leave the treeview window, the tooltip tends to get stuck, but it IS working on x86 Windows.

[Jayson]

So this might being a bug then ?

[GEOSoft]

It's not an AutoIt bug because the native control doesn't support tooltips like you want to use. It's an issue with Siao's function when it's used on x64 systems and since that is not even a standard UDF function then it does not belong in Bug Reports either so don't report it. Someone will figure out the solution and post it, I'm sure but it will have to be someone who can test it on x64 and that's not going to be me. I don't load x64 versions of any operating system.

[Jayson]

GEOSoft,

Thank you for your explanation !

[Melba23]

jayson,

I see GEOSoft just beat me to it!

It is an x64 problem - the data structures are not aligning properly when we pass the mouse position to the DLL.

I am at the ragged edge of my knowledge here, but I think I might have a solution. Please replace the SetTip function with this version and see if it works:

Func SetTip()
    
    If @AutoItX64 Then
        ; If running on x64 - convert position data to x64 structure
        Local $tPoint = DllStructCreate("int X;int Y")
        DllStructSetData ( $tPoint, "X", MouseGetPos(0))
        DllStructSetData ( $tPoint, "Y", MouseGetPos(1))        
        Local $tPoint64 = DllStructCreate("int64", DllStructGetPtr($tPoint))
        Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "int64", DllStructGetData($tPoint64, 1))
    Else
        ; If running on x86 - use the original structure
        Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "uint", MouseGetPos(0), "uint", MouseGetPos(1))
    EndIf

    Switch $aHwnd[0]
        Case $hTV1, $hTV2_Handle

            $tMPos = _WinAPI_GetMousePos(True, $aHwnd[0])
            $hItem = _GUICtrlTreeView_HitTestItem($aHwnd[0], DllStructGetData($tMPos, 1), DllStructGetData($tMPos, 2))

            If $hItem = 0 Then
                ToolTip("")
            Else
                ToolTip(_GUICtrlTreeView_GetText($aHwnd[0], $hItem))
            EndIf
    EndSwitch

EndFunc

How did I do?

M23

Edit: Screwed up the DllStructCreate - told you I was on the edge. Try it now!

Edited October 20, 2010 by Melba23