Input Mysql output to a combobox

[JamesDover]

Hello, I'm trying to put the results of a mysql query into a combo box. The problem is that it is all coming out together. For example: JimJohnFredJohnsonSamWheat

Cheers

Func Myquery()
    $NameList1 = ""
        $NametoFind = GUICtrlRead($Input1) & "%"
    $RemoteFormatString = "SELECT * FROM hardware WHERE userid LIKE '%s'"
    $SQLCode = StringFormat($RemoteFormatString, $NametoFind)
    $TableContents = _Query($SQLInstance, $SQLCode)
    With $TableContents
        While Not .EOF
            $NameList1 &= .Fields("name" ).value & @CRLF
            .MoveNext
        WEnd
    EndWith
    GUICtrlSetData($Input1, $NameList1);setting to combobox
    _MySQLEnd($SQLInstance)
    MsgBox(0, "TestOutput", $NameList1)
EndFunc   ;==>DisplayTable

[GEOSoft]

$NameList1 &= "|" & .Fields("name" ).value ;; No @CRLF for a list or Combo

Edited October 20, 2010 by GEOSoft

[JamesDover]

Thank you for your quick response. It works perfectly.

Cheers

$NameList1 &= "|" & .Fields("name" ).value ;; No @CRLF for a list or Combo

[GEOSoft]

Glad to be of assistance.

[JamesDover]

One more question. When it populates the combo box it looks blank until I click on the drop down box. Is there a way to have the first result showing in the combo box so the user can see that the search is done?

Cheers

[GEOSoft]

$sDefault = StringRegExpReplace($NameList1, "^\|(.+?)\|.+", "$1")
GUICtrlSetData($MyList, $nameList1, $sDefault)

[JamesDover]

I think I maybe doing this wrong. So should it run after the query? Thanks for your help.

Func Mac()
    $SQLInstance3 = _MySQLConnect($UserName, $Password, $Database, $MySQLServerName) 
    $Mac1 = ""
    $NametoFind2 = GUICtrlRead($Userid)
    $RemoteFormatString2 = 'SELECT * FROM networks WHERE (hardware_id = "%s")'
    $SQLCode3 = StringFormat($RemoteFormatString2, $NametoFind2)
    $TableContents3 = _Query($SQLInstance3, $SQLCode3)
    With $TableContents3
        While Not .EOF
            $Mac1 &= "|" & .Fields("macaddr" ).value 
            .MoveNext
        WEnd
    EndWith
    GUICtrlSetData($MACAddressCombo, $Mac1)
    sleep(1000)
    ;;
    $sDefault = StringRegExpReplace($MACAddressCombo, "^\|(.+?)\|.+", "$1")
    GUICtrlSetData($Mac1, $MACAddressCombo, $sDefault)
    ;;
    _MySQLEnd($SQLInstance3)
    ;MsgBox(0, "DEBUG", $Mac1);Debug
EndFunc   ;==>Mac

$sDefault = StringRegExpReplace($NameList1, "^\|(.+?)\|.+", "$1")
GUICtrlSetData($MyList, $nameList1, $sDefault)

[GEOSoft]

Func Mac()
    Local $SQLInstance3 = _MySQLConnect($UserName, $Password, $Database, $MySQLServerName) 
    Local $Mac1 = ""
    Local $NametoFind2 = GUICtrlRead($Userid)
    Local $RemoteFormatString2 = 'SELECT * FROM networks WHERE (hardware_id = "%s")'
    Local $SQLCode3 = StringFormat($RemoteFormatString2, $NametoFind2)
    Local $TableContents3 = _Query($SQLInstance3, $SQLCode3)
    With $TableContents3
        While Not .EOF
            $Mac1 &= "|" & .Fields("macaddr" ).value 
            .MoveNext
        WEnd
    EndWith
    Local $sDefault = StringRegExpReplace($Mac1, "^\|(.+?)\|.+", "$1")
    GUICtrlSetData($MACAddressCombo, $Mac1, $sDefault)
    ;;
    _MySQLEnd($SQLInstance3)
    ;MsgBox(0, "DEBUG", $Mac1);Debug
EndFunc   ;==>Mac

Edited October 27, 2010 by GEOSoft

[JamesDover]

Excellent it works great. Thanks again

Func Mac()
    Local $SQLInstance3 = _MySQLConnect($UserName, $Password, $Database, $MySQLServerName) 
    Local $Mac1 = ""
    Local $NametoFind2 = GUICtrlRead($Userid)
    Local $RemoteFormatString2 = 'SELECT * FROM networks WHERE (hardware_id = "%s")'
    Local $SQLCode3 = StringFormat($RemoteFormatString2, $NametoFind2)
    Local $TableContents3 = _Query($SQLInstance3, $SQLCode3)
    With $TableContents3
        While Not .EOF
            $Mac1 &= "|" & .Fields("macaddr" ).value 
            .MoveNext
        WEnd
    EndWith
    Local $sDefault = StringRegExpReplace($Mac1, "^\|(.+?)\|.+", "$1")
    GUICtrlSetData($MACAddressCombo, $Mac1, $sDefault)
    ;;
    _MySQLEnd($SQLInstance3)
    ;MsgBox(0, "DEBUG", $Mac1);Debug
EndFunc   ;==>Mac

[GEOSoft]

Glad to help and happy it works for you.

[russell]

Can you post the whole script please. So i can study it for my projects.