AnyFileExists = FileExists and *.*

[monter]

I noticed that

FileExists("path\filename.ext") and FileExists("path\*.ext") works properly if I want to check if given files exist, but if any file exist:

FileExists("path\*.*") it fails, because it works like FileExists("path") - checks existence of directory.

So I made a small func AnyFileExists:

expandcollapse popup

$path = 'C:\Newly_created_123\directory_456'

DirCreate($path)
If @error Then
    MsgBox(16, Default, 'Error creating directory', 12)
    Exit
EndIf
OnAutoItExitRegister('OnExit')
MsgBox(64, Default, $path & @CRLF & "shouldn't contain any files.", 4)

Test_FileExists()
Test_FFFF()

Func Test_FileExists()
    If FileExists($path) Then MsgBox(64, 'Test_FileExists', $path & @CRLF & 'EXISTS.', 6) ; TRUE
    If FileExists($path & '\*.mp3') Then
        MsgBox(64, 'Test_FileExists', $path & '\*.mp3' & @CRLF & 'exists.', 6)
    Else
        MsgBox(64, 'Test_FileExists', $path & '\*.mp3' & @CRLF & "DOESN'T EXIST.", 6) ; TRUE
    EndIf
    If FileExists($path & '\*.*') Then MsgBox(48, 'Test_FileExists', $path & '\*.*' & @CRLF & 'exists (but directory is empty!).', 9) ; FALSE - IMO it should be TRUE!
EndFunc ;==>Test_FileExists


Func Test_FFFF()
    $checkFiles = AnyFileExists($path, '*.*')
    If $checkFiles = 0 Then
        MsgBox(64, 'Test_FFFF', $path & '\*.*' & @CRLF & "DOESN'T EXIST.", 9) ; TRUE
    Else
        MsgBox(64, 'Test_FFFF', $path & '\*.*' & @CRLF & 'exists.', 6)
    EndIf
EndFunc ;==>Test_FFFF

Func AnyFileExists($sPath, $sFilter)
    FileChangeDir($sPath)
    Local $ff1f = FileFindFirstFile($sFilter)
    FileChangeDir(@ScriptDir)
    FileClose($ff1f)
    If $ff1f = -1 Then
        Return 0
    Else
        Return 1
    EndIf
EndFunc ;==>AnyFileExists

Func OnExit()
    FileChangeDir('C:\')
    If FileExists(StringLeft($path, StringInStr($path, '\', 0, -1) -1)) Then DirRemove(StringLeft($path, StringInStr($path, '\', 0, -1) -1), 1)
EndFunc ;==>OnExit

AnyFileExists.au3

Edited October 23, 2010 by monter

[SmOke_N]

Func _FileExistsEx($s_path)
    Local $hFF = FileFindFirstFile($s_path)
    If $hFF = -1 Then Return SetError(1, 0, 0)
    FileClose($hFF)
    Return 1
EndFunc

Edit:

I just wanted to show you, in case you don't notice, you're missing a key element in your call ( FileClose() ).

Edited October 23, 2010 by SmOke_N

[monter]

you're missing a key element in your call ( FileClose() ).

Of course, I forgot it

[TheSaint]

And another way of course, is to use DirGetSize("$path", 1) on the parent folder, which will return an array with the files & folders count.

Perhaps you could do a version of your function using that ... to cater for when a filepath (not folderpath is used)?

It should take less code and have the added benefit of reporting both file numbers and (especially) folder numbers of the passed path.

Which means you get to see if files &/or folders exist in the given path.