listview checkboxes

[GodForsakenSoul]

well, i learned how to do checkboxes in listview, but i can't seem to read their state.

i tried GuiCtrlGetState(), but i got the integer 80 from it. whether it is checked or not, i got 80.

i trie GuiCtrlRead(), but got whatever it was in the listview, in the helpfile example case, "item3|col32|col33".

I don't seem to get this to work properly.

so... i need one of two things, either to figure out how to use the listview checkbox, or, aletrnatively, something else that works.

[BugFix]

Example from help file (_GUICtrlListView_GetItemChecked):

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $hListView
    
    GUICreate("ListView Get Item Checked State", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
    GUISetState()
    
    ; Add columns
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; Add items
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)

    ; Check item 2
    _GUICtrlListView_SetItemChecked($hListView, 1)
    MsgBox(4160, "Information", "Item 2 Checked: " & _GUICtrlListView_GetItemChecked($hListView, 1))

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

[GodForsakenSoul]

uh... huh... your example doesn't work. Error opening memory.au3

also, it doesn't let me play with the example. it automatically does #2, AND i don't like this particular line.

MsgBox(4160, "Information", "Item 2 Checked: " & _GUICtrlListView_GetItemChecked($hListView, 1))

your example has only been designed for item 2, despite whether or not you're willing to pick it.

[BugFix]

Now i've modified it. So you can set checked and read check-state by yourself:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $hListView, $btn, $state

    GUICreate("ListView Get Item Checked State", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
    $btn = GUICtrlCreateButton('Check State', 160, 275, 80, 20)
    GUISetState()

    ; Add columns
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; Add items
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)

    ; Loop until user exits
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                GUIDelete()
                ExitLoop
            Case $btn
                $state = ''
                For $i = 0 To _GUICtrlListView_GetItemCount($hListView) -1
                    If _GUICtrlListView_GetItemChecked($hListView, $i) Then $state &= $i & ', '
                Next
                If $state <> '' Then MsgBox(0, '', 'Index checked Item: ' & StringTrimRight($state, 2))
        EndSwitch
    WEnd
EndFunc   ;==>_Main

Edited October 31, 2010 by BugFix

[GodForsakenSoul]

one last question: i want to analize (sp?) the UDF's myself.

i follow the "if you want something done right, you oughtta do it yourslef" thing.

i have never went so deep into autoit actually... where do i find these UDF's?

meanwhile, i shall play with your example.

[BugFix]

where do i find these UDF's?

Open the iclude file ( #include <GuiListView.au3> ).

To do this in SciTE: place cursor between the chars of this include-line. Than hit "Alt+i" - now the file will opened.

[guinness]

Than hit "Alt+i"

Wow, I learnt something today

[GEOSoft]

In addition to what BugFix posted, you can find all the standard UDFs in your AutoIt3\Include\ folder.