Multiple choice input box

[paul1149]

Hi,

Sorry for what I suspect is a simple question. I have a script (see below) by which I switch Power Plans in Win7. It opens an InputBox, I type in the number of the plan that I want and click OK. It works fine.

But I'd like to expand the box and add more options, and I'd like to 1) clean up the options presentation, one option per line, and 2) possibly assign each option to a Control Button.

Is something like this possible?

Thanks,

p.

The existing script:

$PowerPlan = InputBox( "Choose Power Plan", "1: Energy Star, 2: myNoSleep" )

If $PowerPlan = 1 Then

Run("Powercfg -setactive c0ea6ad3-6145-4447-a15e-5fb97be69b98")

Exit

Else

Run("powercfg -setactive c78a5555-aa90-40c0-a554-20788489c55b")

Exit

EndIf

[Melba23]

paul1149,

Sounds like you need a combo:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
GUICtrlSetData(-1, "Energy Star|myNoSleep")

GUISetState()

$sCurrCombo = ""

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hCombo
            If GUICtrlRead($hCombo) <> $sCurrCombo Then
                $sCurrCombo = GUICtrlRead($hCombo)
                MsgBox(0, "Choice", $sCurrCombo)
            EndIf
    EndSwitch

WEnd

M23

[paul1149]

paul1149,

Sounds like you need a combo:

Thanks. That's pretty good, and good to know. Is it possible to list the options openly, one per line, with a control button for each one?

Thanks again,

p.

[Melba23]

paul1149,

Is it possible to list the options openly, one per line, with a control button for each one?

If that is all you want, just create a GUI with buttons and associated labels.

M23

[GEOSoft]

M23 appears to be asleep at the wheel today. I think he probably meant use RADIO buttons and read the value of those when a Control button is clicked.

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hRadio_1 = GUICtrlCreateRadio("Energy Star", 10, 10, 100, 20)
$hRadio_2 = GUICtrlCreateRadio("My No Sleep", 10, 30, 100, 20)
$hRadio_3 = GUICtrlCreateRadio("My Other Scheme", 10, 60, 100, 20)
$hBtn_Go = GUICtrlCreateButton("Set", 220, 420, 60, 25)
GUISetState()

$sText = ""

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hBtn_Go
            For $i = $hRadio_1 To $hRadio_3
                If GUICtrlRead($i) = 1 Then
                    $sText = GUICtrlRead($i, 1)
                    MsgBox(0, "Choice", $sText)
                    ExitLoop
                EndIf
            Next
    EndSwitch
WEnd

[paul1149]

GEOSoft,

Thanks much for taking the time to write that. I'm not getting anything from it though. Could there be something missing, or am I doing something wrong?

Thanks again,

p.

[Melba23]

George,

Less of the cheek - I do have other things to do in my life you know!

Actually I forgot to log off!

paul1149,

George was not able to read my mind this time - what I actually had in mind was something like this:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Energy Star", 100, 15, 100, 20)
GUICtrlCreateLabel("My No Sleep", 100, 55, 100, 20)
GUICtrlCreateLabel("My Other Scheme", 100, 95, 100, 20)

$hButton_1 = GUICtrlCreateButton("Go", 10, 10, 80, 30)
$hButton_2 = GUICtrlCreateButton("Go", 10, 50, 80, 30)
$hButton_3 = GUICtrlCreateButton("Go", 10, 90, 80, 30)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton_1
            MsgBox(0, "Choice", "Energy Star")
        Case $hButton_2
            MsgBox(0, "Choice", "My No Sleep")
        Case $hButton_3
            MsgBox(0, "Choice", "My Other Scheme")
    EndSwitch
WEnd

As you can see, there are many ways to skin this particular feline.

M23

[paul1149]

M23 and GEO,

Wow - sorry. I had a file mix-up. Somehow the file I was working on in the editor was not the file I was executing from Desktop. Once I got that straightened out these scripts work perfectly. This button one is exactly what I was looking for. Thanks much to both of you for your time on this!

Thanks,

p.

[GEOSoft]

Darn!!!! M23 wins again. I'll settle that issue on the next one.

[paul1149]

You guys have a great camaraderie. And it helps us who need to learn! The script is working great now, thanks again.

p.

[SpecialS]

Melba23

Lets say i would like to make a loop that only gets activated once you pressed Case $hButton_1

How would you do it?

[Melba23]

SpecialS,

Put the loop inside a function which you call when the button is actioned? Without more details I cannot really offer anything more sensible.

M2£