Check line ends in txt file

[Sercankd]

i have a txt file that contains some image links and normal page links like

http://www.google.com/

http://www.google.com/logo.jpg

http://www.yahoo.com/yahooo.png

http://www.yahoo.com/

http://www.yahoo.com/mail

i want to remove all lines that doesnt end with common image extensions like .jpg .png .gif

i suck at regexp i cant do it please help me

[iamtheky]

This will pull those lines, i too lack skills with regexp

#include <array.au3>
#Include <File.au3>


Dim $Asites
_FileReadToArray("c:\sites.txt", $Asites)

Dim $Apics[1]
$Apng = _ArrayFindAll ($Asites, ".png", 0 ,0 , 0 , 1)
$Ajpg = _ArrayFindAll ($Asites, ".jpg", 0 ,0 , 0 , 1)
$Agif = _ArrayFindAll ($Asites, ".gif", 0 ,0 , 0 , 1)
_ArrayConcatenate ($Apics , $Ajpg)
_ArrayConcatenate ($Apics , $Apng)
_ArrayConcatenate ($Apics , $Agif)
_ArrayDelete ($Apics , 0)

for $i = 0 to ubound ($Apics) - 1
filewrite ("c:\sites_pics_only.txt" , $Asites[$Apics[$i]] & @CRLF)
next

[Bowmore]

Here is one way of doing this sort of thing

#include <file.au3>

; Create a test file
Local $sFileName = "C:\Documents and Settings\" & @UserName & "\My Documents\Mylinklist.txt"
Local $sMyLinksData = "http://www.google.com/" & @CRLF & "http://www.google.com/logo.jpg" & @CRLF & "http://www.yahoo.com/yahooo.png" & @CRLF & "http://www.yahoo.com/" & @CRLF & "http://www.yahoo.com/mail" & @CRLF
FileWrite($sFileName,$sMyLinksData)

Local $aListData = 0
Local $hFile = 0

_FileReadToArray($sFileName,$aListData)
FileMove($sFileName,$sFileName & ".bak") ; make a backup copy
$hFile = FileOpen($sFileName,2) ; Create a new empty verion of the file
For $i = 1 To UBound($aListData) - 1
    If StringRegExp($aListData[$i],"(?i:.jpg|.png|.gif)$") Then ;add extra flie types by inserting |.ext
        ; Keep this line, write it to the new file
        FileWriteLine($hFile,$aListData[$i])
    EndIf
Next
FileClose($hFile)

[Jos]

$text = "http://www.google.com/" & @crlf & _
"http://www.google.com/logo.jpg" & @crlf & _
"http://www.google.com/logo3.jpg" & @crlf & _
"http://www.yahoo.com/" & @crlf & _
"http://www.yahoo.com/yahooo.png" & @crlf & _
"http://www.yahoo.com/" & @crlf & _
"http://www.yahoo.com/mail" & @crlf
$array = StringRegExp($text, '(?i)(.*?\.jpg|.*?\.gif|.*?\.png)', 3)
for $i = 0 to UBound($array) - 1
    msgbox(0, "RegExp Test with Option 1 - " & $i, $array[$i])
Next

[UEZ]

Is there any way to invert the result? I mean finding *.jpg, *.gif, *.png and invert the results!

Br,

UEZ

[iamtheky]

couldnt you use bowmores solution with an If NOT....filewriteline statement instead?

unless you mean reverse the order -- or turn them upside down?

Edited October 31, 2010 by iamtheky

[Sercankd]

This will pull those lines, i too lack skills with regexp

#include <array.au3>
#Include <File.au3>


Dim $Asites
_FileReadToArray("c:\sites.txt", $Asites)

Dim $Apics[1]
$Apng = _ArrayFindAll ($Asites, ".png", 0 ,0 , 0 , 1)
$Ajpg = _ArrayFindAll ($Asites, ".jpg", 0 ,0 , 0 , 1)
$Agif = _ArrayFindAll ($Asites, ".gif", 0 ,0 , 0 , 1)
_ArrayConcatenate ($Apics , $Ajpg)
_ArrayConcatenate ($Apics , $Apng)
_ArrayConcatenate ($Apics , $Agif)
_ArrayDelete ($Apics , 0)

for $i = 0 to ubound ($Apics) - 1
filewrite ("c:\sites_pics_only.txt" , $Asites[$Apics[$i]] & @CRLF)
next

thank you that solved my problem

[UEZ]

couldnt you use bowmores solution with an If NOT....filewriteline statement instead?

unless you mean reverse the order -- or turn them upside down?

I meant it with StringRegExp. With RegEx it is simple to get all the extension but it would save a lot of work if regexp can invert the results.

Then you can easily delete all non extension and overwrite the text file for example.

Br,

UEZ

[GEOSoft]

@UEZ

Do you mean reverse the array returned from the SRE?

@Sercankd

Just a minor rework of Jos' code to get the result you seem to want.

$text = "http://www.google.com/" & @crlf & _
"http://www.google.com/logo.jpg" & @crlf & _
"http://www.google.com/logo3.jpg" & @crlf & _
"http://www.yahoo.com/" & @crlf & _
"http://www.yahoo.com/yahooo.png" & @crlf & _
"http://www.yahoo.com/" & @crlf & _
"http://www.yahoo.com/mail" & @crlf
$array = StringRegExp($text, '(?i)(.*?\.jpg|.*?\.gif|.*?\.png)', 3)
If NOT @Error Then
    $text = ""
    For $i = 0 to UBound($array) - 1
        ;msgbox(0, "RegExp Test with Option 1 - " & $i, $array[$i]) ;; Attn: JOS -- You said "RegExp Test with Option 1 and yet you used Option 3
        $text &= $array[$i] & @CRLF
    Next
EndIf
MsgBox(0, "Result", $text)

If you #Include<array.au3> at the top of your script, there are many things you can do with the returned array.

Change the last part of the code to.

$array = StringRegExp($text, '(?i)(.*?\.jpg|.*?\.gif|.*?\.png)', 3)
If NOT @Error Then
    $array = _ArrayUnique($array)
    ;_ArrayReverse($array);; For UEZ
    $text = _ArrayToString($array, @CRLF)
EndIf
MsgBox(0, "Result", $text)

EDIT:

Missed a set of code tags

Edited October 31, 2010 by GEOSoft

[Jos]

; Attn: JOS -- You said "RegExp Test with Option 1 and yet you used Option 3

One of those Cut&Paste starters that didn't get changed

[GEOSoft]

I meant it with StringRegExp. With RegEx it is simple to get all the extension but it would save a lot of work if regexp can invert the results.

Then you can easily delete all non extension and overwrite the text file for example.

Br,

UEZ

Better to manipulate the array to what you want and then over-write the file I think. Of course you could also do at least part of it by changing the order of the conditionals but that isn't guaranteed to be accurate either.

[UEZ]

@UEZ

Do you mean reverse the array returned from the SRE?

No, let me try to explain it again:

1:http://www.google.com/
2:http://www.google.com/logo.jpg
3:http://www.yahoo.com/yahooo.png
4:http://www.yahoo.com/
5:http://www.yahoo.com/mail

The RegExp code will find line 2 and line 3 but can I inverse it so that I will get the line 1, 4 and 5?

Something like ^.*\.(jpg|png|gif) which is of course not working!

Br,

UEZ

Edited October 31, 2010 by UEZ

[GEOSoft]

In that case it's faster to use StringRegExpReplace()

$sTxt = [url="http://www.google.com/"]1:http://www.google.com/[/url] & @CRLF
$sTxt &= [url="http://www.google.com/logo.jpg"]2:http://www.google.com/logo.jpg[/url] & @CRLF
$sTxt &= [url="http://www.yahoo.com/yahooo.png"]3:http://www.yahoo.com/yahooo.png[/url] & @CRLF
$sTxt &= [url="http://www.yahoo.com/"]4:http://www.yahoo.com/[/url] & @CRLF
$sTxt &= [url="http://www.yahoo.com/mail"]5:http://www.yahoo.com/mail[/url]

$sTxt = StringRegExpReplace($sTxt, "(?m:^|\n)(.*\.jpg|.*\.png|.*\.gif).*", "")
MsBox(0, "Result", $sTxt)

EDIT: had one too many ".*" in there

Edited October 31, 2010 by GEOSoft