Find and replace some numbers after calculation.

[giannis121]

Hello friends!

This is my first post here (so please be patient - i am not a professional).

What i want to do is the following:

I want to open a txt format file,

find and replace some numbers.

The syntax is not allways the same inside the text file.

The numbers are allways after a specific latter.

For example:

T00 A100.2 B11.0

T01 A119.3 B211.8 C21.4 D21.0

So i would like to add certain values. For example after "A" i want to add +100.6 and after "B" +150.0.

Finaly the file will look like:

T00 A200.8 B161.0

T01 A219.9 B361.8 C21.4 D21.0

I have found in the forums some useful code for FileRead and FileReplace,

but still not enough for me.

Can anyone help?

[Melba23]

giannis121,

Welcome to the AutoIt forum.

Here is a way to do what you want:

expandcollapse popup

#include <Array.au3>

$sInput = "T00 A100.2 B11.0" & @CRLF & "T01 A119.3 B211.8 C21.4 D21.0"

; Split into lines
$aInput_Lines = StringSplit($sInput, @CRLF, 1)
; Take each line in turn
For $i = 1 To $aInput_Lines[0]
    ; Split the line into elements
    $aInput_Items = StringSplit($aInput_Lines[$i], " ")
    ; This will hold the recreated line
    $sTempLine = ""
    ; For each element in the line
    For $j = 1 To $aInput_Items[0]
        Switch StringLeft($aInput_Items[$j], 1)
            ; if it begins with A
            Case "A"
                ; Remove the A
                $sTempItem = StringTrimLeft($aInput_Items[$j], 1)
                ; Convert the number into an actual number and add as required
                $iTempNumber = Number($sTempItem) + 100.6
                ; Add to the new line with a trailing space
                $sTempLine &= "A" & $iTempNumber & " "
            Case "B"
                $sTempItem = StringTrimleft($aInput_Items[$j], 1)
                $iTempNumber = Number($sTempItem) + 150
                $sTempLine &= "B" & $iTempNumber & " "
            Case Else
                $sTempLine &= $aInput_Items[$j] & " "
        EndSwitch
    Next
    ; Replace the exisitng line with the new one after removing the final space
    $aInput_Lines[$i] = StringTrimRight($sTempLine, 1)

Next
; Convert the array of lines back into a string
$sOutput = _ArrayToString($aInput_Lines, @CRLF, 1)
; Display it
ConsoleWrite($sOutput & @CRLF)

Please ask if you have any questions on what is going on in the script.

You could also use an SRE - but that might be rushing things a bit!

M23

[giannis121]

Thank you for the reply!

Can you make it more specific for me, please?

The input data is a file "test.txt" (see attached file)

The values for adding to the existing ones are inside the "value.txt"

The original text inside the "test.txt" will not be touched.

Under it there will be the new calculated text.

If you find it difficult to create it for me,

please just give me the commands & functions that i may need to use.

Thank you in advance.

Giannis

test.txt

values.txt

[Melba23]

giannis121,

- Use FileRead to get the text from the original file.

- Use the code I gave you to amend the text.

- Use FileWrite to append the new text to the file.

You will now have a file which contains both sets of text.

Try it yourself and come back if you have problems.

M23

[giannis121]

Thank you very much!

Works fine!

[Melba23]

giannis121,

My pleasure!

Always nice to help those who help themselves too!

M23