get active control

[IchBistTod]

How do I find what the active control is?

aka the field the user currently has selected.

[Tvern]

ControlGetFocus() works. I don't think there is a build in function that returns the CtrlID, but you could loop through all your controls for one with a matching CLASSNN, or loop through your controls with GUICtrlGetState()

[PsaltyDS]

Use _WinAPI_GetDlgCtrlID() to retrieve a ControlID:

#include <WinAPI.au3>

Run("notepad.exe")
Sleep(2000)
$idFocus = _FocusCtrlID("Untitled - Notepad", "")
MsgBox(64, "Result", "Focus ID = " & $idFocus & "; @error = " & @error)
WinClose("Untitled - Notepad", "")

Func _FocusCtrlID($hWnd, $sTxt = "")
    Local $hFocus = ControlGetHandle($hWnd, $sTxt, ControlGetFocus($hWnd, $sTxt))
    If IsHWnd($hFocus) Then
        Return _WinAPI_GetDlgCtrlID($hFocus)
    Else
        Return SetError(1, 0, 0)
    EndIf
EndFunc   ;==>_FocusCtrlID

[IchBistTod]

The reason I ask this is because I have a series of input boxes next to one another and when one has been filled out I want to switch to the next.

I know its gonna take some coding magic to make users be able to go back in the sequence and start from the point they selected(eg: they typed a wrong letter).

Its a product key input GUI.

I already have it verifying the product key algorithm and telling the user if input is invalid before allowing them to continue.

[PsaltyDS]

Registering WM_NOTIFY WM_COMMAND and watching the appropriate EN_CHANGE or other messages would be more direct if it's your own GUI.

Edit: Oops, there I go trusting the swiss-cheese brain again.

Edited November 29, 2010 by PsaltyDS

[Melba23]

IchBistTod,

Registering WM_NOTIFY and watching the appropriate EN_CHANGE

I have use WM_COMMAND and $EN_UPDATE with success:

#include <GUIConstantsEx.au3>

Global $input_limit = 2

$gui = GUICreate("InputBox autofocus demo", 200, 100)
$in1 = GUICtrlCreateInput("", 20, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$in2 = GUICtrlCreateInput("", 80, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$in3 = GUICtrlCreateInput("", 140, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$btn = GUICtrlCreateButton("OK", 75, 60, 40, 25)

GUIRegisterMsg(0x0111, "On_WM_COMMAND")
GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $btn
            $str = GUICtrlRead($in1) & "-" & GUICtrlRead($in2) & "-" & GUICtrlRead($in3)
            MsgBox(0, "You have entered", $str)
    EndSwitch
WEnd

Func On_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAnd($wParam, 0x0000FFFF)
    Switch $nNotifyCode
        Case 0x400 ;$EN_UPDATE
            If StringLen(GUICtrlRead($nID)) = $input_limit Then GUICtrlSetState($nID+1, $GUI_FOCUS)
    EndSwitch
EndFunc

M23

[IchBistTod]

IchBistTod,

I have use WM_COMMAND and $EN_UPDATE with success:

#include <GUIConstantsEx.au3>

Global $input_limit = 2

$gui = GUICreate("InputBox autofocus demo", 200, 100)
$in1 = GUICtrlCreateInput("", 20, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$in2 = GUICtrlCreateInput("", 80, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$in3 = GUICtrlCreateInput("", 140, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$btn = GUICtrlCreateButton("OK", 75, 60, 40, 25)

GUIRegisterMsg(0x0111, "On_WM_COMMAND")
GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $btn
            $str = GUICtrlRead($in1) & "-" & GUICtrlRead($in2) & "-" & GUICtrlRead($in3)
            MsgBox(0, "You have entered", $str)
    EndSwitch
WEnd

Func On_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAnd($wParam, 0x0000FFFF)
    Switch $nNotifyCode
        Case 0x400 ;$EN_UPDATE
            If StringLen(GUICtrlRead($nID)) = $input_limit Then GUICtrlSetState($nID+1, $GUI_FOCUS)
    EndSwitch
EndFunc

M23

wow that is amazing!

I had no idea that the process could be simplified to such a small amount of code.

I suppose i should really start to learn these GUIRegisterMsg(0x0111, "On_WM_COMMAND") and other "registermessage"'s any advice on where to look to learn more about them?

[PsaltyDS]

I suppose i should really start to learn these GUIRegisterMsg(0x0111, "On_WM_COMMAND") and other "registermessage"'s any advice on where to look to learn more about them?

Go through the help file examples under most of the _GuiCtrl* UDF functions. Most of the handlers for non-AutoIt controls, for example _GuiCtrlButton_Create() instead of GuiCtrlCreateButton(), use this kind of message handling.

[JAFN]

IchBistTod,

I have use WM_COMMAND and $EN_UPDATE with success:

#include <GUIConstantsEx.au3>

Global $input_limit = 2

$gui = GUICreate("InputBox autofocus demo", 200, 100)
$in1 = GUICtrlCreateInput("", 20, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$in2 = GUICtrlCreateInput("", 80, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$in3 = GUICtrlCreateInput("", 140, 20, 30, 20)
GUICtrlSetLimit(-1, $input_limit)
$btn = GUICtrlCreateButton("OK", 75, 60, 40, 25)

GUIRegisterMsg(0x0111, "On_WM_COMMAND")
GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $btn
            $str = GUICtrlRead($in1) & "-" & GUICtrlRead($in2) & "-" & GUICtrlRead($in3)
            MsgBox(0, "You have entered", $str)
    EndSwitch
WEnd

Func On_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAnd($wParam, 0x0000FFFF)
    Switch $nNotifyCode
        Case 0x400 ;$EN_UPDATE
            If StringLen(GUICtrlRead($nID)) = $input_limit Then GUICtrlSetState($nID+1, $GUI_FOCUS)
    EndSwitch
EndFunc

M23

I've had some results modifying this to my needs but I don't understand why it works.

Specifically how the parameters got passed to the function.

[AdmiralAlkex]

I've had some results modifying this to my needs but I don't understand why it works.

Specifically how the parameters got passed to the function.

Here's some reading for you:

About Messages and Message Queues

[Melba23]

JAFN,

I know you have read the GUIRegisterMsg tutorial in the Wiki - you said then you did not understand it. ;(

Now you have seen a message handler in action, please read the tutorial again and ask about anything in it you do not understand. I wrote it to explain about Windows messages and message handlers at a pretty basic level, so if it does not explain well enough then I need to change it.

M23