Window On Top of a specific Window

[inm101]

Is there a way to assign a specific window ("Window A") to always stay above another specific window ("Window B")? At the same time, I don't want Window A to be on top of all windows, just above Window B when it is maximized.

Edited December 3, 2010 by inm101

[Melba23]

inm101,

Look at _WinAPI_SetWindowPos in the Helpfile - the $hAfter parameter allows you to position the window just above another in the z-order.

M23

[inm101]

inm101,

Look at _WinAPI_SetWindowPos in the Helpfile - the $hAfter parameter allows you to position the window just above another in the z-order.

M23

Thank you for the suggestion. I understand what you are saying, but I don't understand how to use it because the helpfile doesn't give an example of its usage like in the other help file topics.

[Melba23]

inm101,

Try something like this:

; You will need this at the top of your script
#include <WinAPI.au3>

; Window B is already created and has handle $hGUI_B

; Create Window A
$hGUI_A = GUICreate("GUI A", $iWidth, $iHeight, $iX, $iY)
; Now set it in z-order just above Window B
_WinAPI_SetWindowPos($hGUI_A, $hGUI_B, $iX, $iY, $iWidth, $iHeight, $SWP_NOACTIVATE)
; And then show it
GUISetState(@SW_SHOW, $hGUI_A)

And that should do the trick.

M23

[inm101]

inm101,

Try something like this:

; You will need this at the top of your script
#include <WinAPI.au3>

; Window B is already created and has handle $hGUI_B

; Create Window A
$hGUI_A = GUICreate("GUI A", $iWidth, $iHeight, $iX, $iY)
; Now set it in z-order just above Window B
_WinAPI_SetWindowPos($hGUI_A, $hGUI_B, $iX, $iY, $iWidth, $iHeight, $SWP_NOACTIVATE)
; And then show it
GUISetState(@SW_SHOW, $hGUI_A)

And that should do the trick.

M23

I think this is the magic line I'm after:

_WinAPI_SetWindowPos($hGUI_A, $hGUI_B, $iX, $iY, $iWidth, $iHeight, $SWP_NOACTIVATE)

It's blowing up on the last part "$SWP_NOACTIVATE". I don't know why it's blowing up there.

AutoIt3 Syntax Checker v1.54.8 Copyright © Tylo 2007

C:\Scripting\EMR_Sign\EMR_Sign.au3(56,87) : WARNING: $SWP_NOACTIVATE: possibly used before declaration.

_WinAPI_SetWindowPos($handle1,$handle2, $iX, $iY, $iWidth, $iHeight, $SWP_NOACTIVATE)

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^

C:\Scripting\EMR_Sign\EMR_Sign.au3(56,87) : ERROR: $SWP_NOACTIVATE: undeclared global variable.

_WinAPI_SetWindowPos($handle1,$handle2, $iX, $iY, $iWidth, $iHeight, $SWP_NOACTIVATE)

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^

C:\Scripting\EMR_Sign\EMR_Sign.au3 - 1 error(s), 1 warning(s)

[Melba23]

inm101,

Looks like you need to add another #include file:

#include <Constants.au3>

M23

P.S. When you reply please use the "Add Reply" button at the top and bottom of the page rather then the "Reply" button in the post itself. That way you do not get the contents of the previous post quoted in your reply and the whole thread becomes easier to read.

[inm101]

Thanks for the tip about readability. It's still not behaving as I'd like it to. Again, I want Window A ("$GuiTitle") to always (and only) be above Window B ("$WinTitle"), but I still can't make it happen.

BTW...$WinTitle is not an Auto IT GUI.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <Constants.au3>

$Wintitle = "MIS Sign Documents"
$GuiTitle = "My GUI"

while 1
sleep(1000)
$handle =""
$handle = ControlGetHandle($wintitle,"","[CLASS:RATeditwindow; INSTANCE:1]")
    if StringLen($handle)>0 Then
        Example1()
    Else
        WinClose($GuiTitle)
    EndIf
wend

Func Example1()
    Local $msg,$Button_1

    $iX = 40
    $iY = 40
    $iWidth = 200
    $iHeight = 675
    $hGUI_A = GUICreate($GuiTitle, $iX, $iY, $iWidth, $iHeight,$WS_POPUP)
    $Button_1 = GUICtrlCreateButton("Sign", 0, 0, 40, 40)
    
    $handle2 = WinGetHandle($wintitle)
    Consolewrite ($handle2)
    _WinAPI_SetWindowPos($hGUI_A,$handle2, $iWidth, $iHeight, $iX, $iY, $SWP_NOACTIVATE)
    GUISetState(@SW_SHOW)
    
    
    While WinExists($wintitle)
        ;_WinAPI_SetWindowPos($hGUI_A,$handle2, $iWidth, $iHeight, $iX, $iY, $SWP_NOACTIVATE)
        $msg = GUIGetMsg()
            WinMove($Wintitle,"",0,0)
            ;WinSetOnTop($Guititle, "", 1)
            WinSetState("My GUI","",@SW_SHOW)
            
            Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $Button_1
                WinMove($Wintitle,"",0,0)
                $pos = MouseGetPos()
                ClipPut ("")
                MouseClick("left",105,143,1,1)
                MouseClick("left",79,143,1,1)
                MouseClick("left",105,143,1,1)
                $clip = ClipGet()
                Consolewrite($clip & @CRLF)
                $result1 = StringInStr($clip, "[*]")
                $result2 = StringInStr($clip, "[]")
                If $result1 > 0 or $result2 > 0 Then
                    ConsoleWrite("Found [*] or []" & @CRLF)
                    MouseMove($pos[0], $pos[1], 0)
                    MsgBox(16, "Warning", "Please finish editing this report before attempting to sign it.")
                Else
                    GUISetState(@SW_HIDE)
                    MouseClick("left",221,698,1,1)
                    GUISetState(@SW_SHOW)
                EndIf
                MouseMove($pos[0], $pos[1], 0)
            EndSelect
        
    WEnd
    GUIDelete()
EndFunc

Edited December 3, 2010 by inm101

[GEOSoft]

From the help file WinSetOnTop()

Third-party programs which add an "Always On Top" context menu entry might not update their menu entry to reflect the AutoIt-induced change in TOPMOST status.

[inm101]

The non AutoIT window does not have an "Always On Top" option in the context menu of the app.

[Melba23]

inm101,

Checking a script in which I have used _WinAPI_SetWindowPos I see that I created the "on-top" GUI using the "beneath" GUI as the parent and created the controls after the API call. So try this:

$handle2 = WinGetHandle($wintitle)
Consolewrite ($handle2)

$hGUI_A = GUICreate($GuiTitle, $iX, $iY, $iWidth, $iHeight,$WS_POPUP, -1, $handle2)
_WinAPI_SetWindowPos($hGUI_A,$handle2, $iWidth, $iHeight, $iX, $iY, $SWP_NOACTIVATE)

$Button_1 = GUICtrlCreateButton("Sign", 0, 0, 40, 40)

GUISetState(@SW_SHOW)

Fingers crossed!

M23

Edit: Just seen the posts above - my "beneath" GUI is also a non-AutoIt app and my script works.

Edited December 3, 2010 by Melba23

[GEOSoft]

From the help file WinSetOnTop()

Third-party programs which add an "Always On Top" context menu entry might not update their menu entry to reflect the AutoIt-induced change in TOPMOST status.

The exstyle $WS_EX_TOPMOST and most Window UDF functions suffer from the same limitation. That's a Windows limitation, not one that is AutoIt specific.

[inm101]

MELBA, IT WORKS!!!!!!!!!!!!! WOOT, WOOT! You rule.

I think the part that put me over the top was your suggestion to use this:

$handle2 = WinGetHandle($wintitle)
    
$iX = 40
$iY = 40
$iWidth = 200
$iHeight = 675
        
$hGUI_A = GUICreate($GuiTitle, $iX, $iY, $iWidth, $iHeight,$WS_POPUP, -1, $handle2)
_WinAPI_SetWindowPos($hGUI_A,$handle2, $iWidth, $iHeight, $iX, $iY, $SWP_NOACTIVATE)

Here's the final code. Thank you so much for your help.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <Constants.au3>

$Wintitle = "MIS Sign Documents"
$GuiTitle = "My GUI"

while 1
sleep(1000)
$handle =""
$handle = ControlGetHandle($wintitle,"","[CLASS:RATeditwindow; INSTANCE:1]")
    if StringLen($handle)>0 Then
        Example1()
    Else
        WinClose($GuiTitle)
    EndIf
wend

Func Example1()
    Local $msg,$Button_1
    
    $handle2 = WinGetHandle($wintitle)
    
    $iX = 40
    $iY = 40
    $iWidth = 200
    $iHeight = 675
        
    $hGUI_A = GUICreate($GuiTitle, $iX, $iY, $iWidth, $iHeight,$WS_POPUP, -1, $handle2)
    _WinAPI_SetWindowPos($hGUI_A,$handle2, $iWidth, $iHeight, $iX, $iY, $SWP_NOACTIVATE)

    $Button_1 = GUICtrlCreateButton("Sign", 0, 0, 40, 40)   

    GUISetState(@SW_SHOW)
    
    While WinExists($wintitle)

        $msg = GUIGetMsg()
            WinMove($Wintitle,"",0,0)
            Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $Button_1
                WinMove($Wintitle,"",0,0)
                $pos = MouseGetPos()
                ClipPut ("")
                MouseClick("left",105,143,1,1)
                MouseClick("left",79,143,1,1)
                MouseClick("left",105,143,1,1)
                $clip = ClipGet()
                Consolewrite($clip & @CRLF)
                $result1 = StringInStr($clip, "[*]")
                $result2 = StringInStr($clip, "[]")
                If $result1 > 0 or $result2 > 0 Then
                    ConsoleWrite("Found [*] or []" & @CRLF)
                    MouseMove($pos[0], $pos[1], 0)
                    MsgBox(16, "Warning", "Please finish editing this report before attempting to sign it.")
                Else
                    GUISetState(@SW_HIDE)
                    MouseClick("left",221,698,1,1)
                    GUISetState(@SW_SHOW)
                EndIf
                MouseMove($pos[0], $pos[1], 0)
            EndSelect
    WEnd
    GUIDelete()
EndFunc

[Melba23]

inm101,

My pleasure.

Sorry it took a few tries to get it to work - I will check on the working code first next time rather than relying on the little grey cells!

M23