Get a constant name by its Value

[Juvigy]

I have a large list of AUtoIT constants with different values. For example:

Const $test1 = 1
Const $test2 = 2
Const $test3 = 3

Is there a way to get a constant name by its value? I mean:

Global $check = 2

I want a way to receive "$test2" if the value of $check is 2 or "$test1" if the value of $check is 1 and etc.

Hope i explained it well. 10x in advance.

[Melba23]

Juvigy,

An associated array would be helpful here - nutster has an excellent one here.

Once you have downloaded it, this script shows how to use it to do what you want:

#include <AssocArrays.au3>

; Create an exit mode!
HotKeySet("{ESC}", "On_Exit")
Func On_Exit()
    Exit
EndFunc

; Create associative array
Local $aConst_List
AssocArrayCreate($aConst_List, 7)

; Fill array with valuesd and associated names
For $i = 0 To 5
    AssocArrayAssign($aConst_List, $i, "$test" & $i)
Next

While 1
    ; Generate a value
    $iRand = Random(0, 5, 1)
    ; Retrieve the name
    $sConst = AssocArrayGet($aConst_List,$iRand)
    ; Display it
    MsgBox(0, "Result", "Value " & $iRand & " associated with " & $sConst)

WEnd

Please ask if you need any more pointers.

M23

[trancexx]

But Melba23 that would be terrible use of associative array. Misuse I daresay.

[Melba23]

trancexx,

It would have been most unlike you not to "dare" to say it!

Could I enquire what you might suggest to solve the problem?

M23

[trancexx]

Could I enquire what you might suggest to solve the problem?

You could. I suggest not solving it. It's senseless in its bare existence, don't you agree?

[Melba23]

trancexx,

Like you I have some difficulty in understanding why the OP wants to do what has been asked. But when faced with questions such as this with no real information as to why the problem actually exists, I tend to treat them as existing outside any present reality and to solve them purely as an intellectual exercise.

In this case an associative array seemed a reasonable tool. I suppose I could have created an array and used _ArraySearch or any number of other tricks, but that solution took my fancy at that instant - no doubt the result would have been different in another time/space moment.

M23

[iamtheky]

provided the constants nicely have the matching numbers as in your example

#include <array.au3>

Dim $Con[4]

$Con [0] = "test 0"
$Con [1] = "test 1"
$Con [2] = "test 2"
$Con [3] = "test 3"



while 1
$r = _check()
msgbox (0, '' , $Con[$r])
Wend


func _check ()
    $check = random (0 , 3 , 1)
    return $check
    endfunc

Edited December 14, 2010 by iamtheky

[martin]

I have a large list of AUtoIT constants with different values. For example:

Const $test1 = 1
Const $test2 = 2
Const $test3 = 3

Is there a way to get a constant name by its value? I mean:

Global $check = 2

I want a way to receive "$test2" if the value of $check is 2 or "$test1" if the value of $check is 1 and etc.

Hope i explained it well. 10x in advance.

Maybe you need somethng like this.

Dim $names[5] = ["test1","test2","apple5","dog17","tree12"]
 $check = 3
 ConsoleWrite($names[$check] & @CRLF)

or like this

Func getname($val)
    Switch $val
        Case $test1
            Return "test1"
        Case $test2
            Return "test2"
    EndSwitch
EndFunc   ;==>getname

or maybe

Const $test1 = 1, $test2 = 2, $apple5 = 3, $dog17 = 17, $tree12 = 12
Dim $names[5]= ["test1", "test2", "apple5", "dog17", "tree12"]

$check = 3

ConsoleWrite(NameOf($check) & @CRLF)

Func NameOf($val)
    ConsoleWrite("val = " & $val & @CRLF)
    For $n = 0 To UBound($names) - 1
        If Eval($names[$n]) = $val Then Return "$" & $names[$n]
    Next
    Return ''
EndFunc   ;==>NameOf

Edited December 14, 2010 by martin