Encrypt/Decrypt

[R0bzt3R]

How do I Decrypt the message, instead of Encrypt the message.

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <Crypt.au3>
#include <WinAPI.au3>

$hWnd=GUICreate("Realtime Encrypting",400,300,-1)
$hInputEdit=GUICtrlCreateEdit("",0,0,400,150,$ES_WANTRETURN)
$hOutputEdit=GUICtrlCreateEdit("",0,150,400,150,$ES_READONLY)
GUIRegisterMsg($WM_COMMAND,"WM_COMMAND")
GUISetState(@SW_SHOW)

_Crypt_Startup()
$hKey=_Crypt_DeriveKey("SomePassword",$CALG_RC4)

Do
    $msg=GUIGetMsg()
Until $msg=$GUI_EVENT_close

_Crypt_DestroyKey($hKey)
_Crypt_Shutdown()

Func WM_COMMAND($hWinHandle,$iMsg,$wParam,$lParam)
    If _WinAPI_HiWord($wParam)=$EN_CHANGE And _WINAPI_LoWord($wParam)=$hInputEdit Then
        $bEncrypted=_Crypt_EncryptData(GUICtrlRead($hInputEdit),$hKey,$CALG_USERKEY)
        GUICtrlSetData($hOutputEdit,$bEncrypted)
    EndIf
EndFunc

[Melba23]

R0bzt3R,

By using _Crypt_DecryptData, or is that too obvious a solution and I have misunderstood your question?

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <Crypt.au3>
#include <WinAPI.au3>

$hWnd = GUICreate("Realtime Encrypting", 400, 450)
$hInputEdit = GUICtrlCreateEdit("", 0, 0, 400, 150, $ES_WANTRETURN)
$hOutputEdit = GUICtrlCreateEdit("", 0, 150, 400, 150, $ES_READONLY)
$hClearEdit = GUICtrlCreateEdit("", 0, 300, 400, 150, $ES_READONLY)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

_Crypt_Startup()
$hKey = _Crypt_DeriveKey("SomePassword", $CALG_RC4)

Do
    $msg = GUIGetMsg()
Until $msg = $GUI_EVENT_close

_Crypt_DestroyKey($hKey)
_Crypt_Shutdown()

Func WM_COMMAND($hWinHandle, $iMsg, $wParam, $lParam)
    If _WinAPI_HiWord($wParam) = $EN_CHANGE And _WinAPI_LoWord($wParam) = $hInputEdit Then
        $bEncrypted = _Crypt_EncryptData(GUICtrlRead($hInputEdit), $hKey, $CALG_USERKEY)
        GUICtrlSetData($hOutputEdit, BinaryToString($bEncrypted))
        $bCleartext = _Crypt_DecryptData($bEncrypted, $hKey, $CALG_USERKEY)
        GUICtrlSetData($hClearEdit, BinaryToString($bCleartext))
    EndIf
EndFunc   ;==>WM_COMMAND

M23

[Zedna]

@Melba

There is some problem in your script or maybe in Crypt UDF.

When I delete previously typed string there is still text "Ž=)'" in decrypted panel at bottom.

EDIT: It corresponds to empty string converted to binary --> 0x00000000

EDIT2:

here is correction

Func WM_COMMAND($hWinHandle, $iMsg, $wParam, $lParam)
    If _WinAPI_HiWord($wParam) = $EN_CHANGE And _WinAPI_LoWord($wParam) = $hInputEdit Then
        $bEncrypted = _Crypt_EncryptData(GUICtrlRead($hInputEdit), $hKey, $CALG_USERKEY)
        GUICtrlSetData($hOutputEdit, BinaryToString($bEncrypted))
    If $bEncrypted = 0x0 Then
        GUICtrlSetData($hClearEdit, '')
    Else
        $bCleartext = _Crypt_DecryptData($bEncrypted, $hKey, $CALG_USERKEY)
        GUICtrlSetData($hClearEdit, BinaryToString($bCleartext))
    EndIf
    EndIf
EndFunc   ;==>WM_COMMAND

Edited December 15, 2010 by Zedna

[Melba23]

Zedna,

Thanks for that.

M23

[R0bzt3R]

Thank you very much!

[R0bzt3R]

I fidgure it out for a while, but now it won't work.

Needed that 3 windowed crypter.

Who i can write in "Cryptish"

And "My message"

And it will translate it either way.