Look for substring within string...if found replace it?

[newbtophpautoit]

Hey!

I have a text file (text_file.txt) containing data as so:

substring:replacement

bye:hello
no:yes

Basically a list of two words/phrases seperated by the : character. (the first is the substring to look for, the other is the replacement) - each pair is on a new line.

Now what I want to do is somehow extract the text files data and loop through it (atleast thats how I'd do so in PHP), so it looks for the substring within the $string and if found replaces it with the replacement so e.g. if bye is found within the $string, then its replaced with hello.

My current code:

;this is where its going to be applying the replacements too...
$string = '.....';

;extract the text files data...
$text_file_data = FileRead(@ScriptDir & "\text_file.txt")

Hope that makes sense, I'm fairly new to Autoit and I'm used to using PHP (as you may have noticed from the way I thought out the process )

Appreciate all your help!

Edited December 16, 2010 by newbtophpautoit

[Melba23]

newbtophpautoit,

I would read the text of the file you wish to alter into a single variable (FileRead) and the list of pairs into an array (_FileReadToArray).

I would then loop through the pairs list (For...Next) and split each pair into the target and replacement (StringSplit) - once you have those 2 words, replace all instances of the former with the latter in the file text (StringReplace).

Finally rewrite the altered file (FileWrite).

Give it a go - you know where we are if you run into problems.

M23

[PsaltyDS]

Sounded like a fun demo, and I'm waiting for some long scripts to run.

Test1.txt:

good:bad
aid:legislature
quick:lazy
jumped:crawled
over:under

Test1.au3:

#include <File.au3>

Global $aReplace
Global $sFile = @ScriptDir & "\Test1.txt"
Global $sString = "Now is the time for all good men to come to the aid of their country.  The quick brown fox jumped over the lazy dog."

ConsoleWrite("Debug: $sString = " & $sString & @LF)

_FileReadToArray($sFile, $aReplace)
For $n = 1 To $aReplace[0]
    $aSplit = StringSplit($aReplace[$n], ":")
    $sString = StringReplace($sString, $aSplit[1], $aSplit[2])
Next

ConsoleWrite("Debug: $sString = " & $sString & @LF)

Missing all kinds of boring stuff like error checking and correction for replacing capitalized words, etc.

Merry Christmas!

[newbtophpautoit]

newbtophpautoit,

I would read the text of the file you wish to alter into a single variable (FileRead) and the list of pairs into an array (_FileReadToArray).

I would then loop through the pairs list (For...Next) and split each pair into the target and replacement (StringSplit) - once you have those 2 words, replace all instances of the former with the latter in the file text (StringReplace).

Finally rewrite the altered file (FileWrite).

Give it a go - you know where we are if you run into problems.

M23

Cool! I'll give it a go, Autoit seems pretty similiar to PHP.

StringReplace => str_replace()

for => for()

StringSplit => implode()

and so on

Edited December 16, 2010 by newbtophpautoit

[newbtophpautoit]

Sounded like a fun demo, and I'm waiting for some long scripts to run.

Test1.txt:

good:bad
aid:legislature
quick:lazy
jumped:crawled
over:under

Test1.au3:

#include <File.au3>

Global $aReplace
Global $sFile = @ScriptDir & "\Test1.txt"
Global $sString = "Now is the time for all good men to come to the aid of their country.  The quick brown fox jumped over the lazy dog."

ConsoleWrite("Debug: $sString = " & $sString & @LF)

_FileReadToArray($sFile, $aReplace)
For $n = 1 To $aReplace[0]
    $aSplit = StringSplit($aReplace[$n], ":")
    $sString = StringReplace($sString, $aSplit[1], $aSplit[2])
Next

ConsoleWrite("Debug: $sString = " & $sString & @LF)

Missing all kinds of boring stuff like error checking and correction for replacing capitalized words, etc.

Merry Christmas!

Snap! thats how I also did it however I use $aRecords instead of $aReplace (just copyied from documentation )

and Merry Christmas!

[Melba23]

newbtophpautoit,

Glad we could help. But in future, when you reply please use the "Add Reply" button at the top and bottom of the page rather then the "Reply" button in the post itself. That way you do not get the contents of the previous post quoted in your reply and the whole thread becomes easier to read.

M23

[GEOSoft]

I try to avoid using useless UDF functions if possible so here is the same thing as Melba23 wanted you to do sans the file.au3 UDF

$sDoc = @ScriptDir & "\somefile.txt"
$sStr = FileRead($sDoc)
$sHold = $sStr
$aSRE = StringRegExp(FileRead(@ScriptDir & "\Text_File.txt", "(?m:^|\n)(.+):(.+)", 3)
If NOT @Error Then
    For $i = 0 To Ubound($aSRE) -2 Step 2
        $sStr = StringReplace($sStr, $aSRE[$i], $aSRE[$i+1])
    Next
EndIf
If $sStr <> $sHold Then
    $hFile = FileOpen($sDoc, 2)
    FileWrite($hFile, $sStr)
    FileClose($hFile)
EndIf

Edited December 16, 2010 by GEOSoft