Inetget($varable .mp3)????

[Rogue5099]

Without going to the source of a website and finding links to each file hosted on site, is there a read the location of a file and downloading all of the contains of an index with file type .whatever.

Example:

http://causeequalstime.com/musique/

INetGet("http://causeequalstime.com/musique/" & $SongName & ".mp3")

How would I get the variable?

[DCCD]

Without going to the source of a website and finding links to each file hosted on site, is there a read the location of a file and downloading all of the contains of an index with file type .whatever.

Example:

http://causeequalstime.com/musique/

INetGet("http://causeequalstime.com/musique/" & $SongName & ".mp3")

How would I get the variable?

i guess you need to use _IELinkGetCollection () Function!

[Rogue5099]

#include <IE.au3>
$oIE = _IECreate ("http://causeequalstime.com/musique")
$oLinks = _IELinkGetCollection ($oIE)
For $oLink In $oLinks
    InetGet("http://causeequalstime.com/musique/" & $oLink, @ScriptDir & "\Downloads\")
Next

This isn't working any suggestions?

[Rogue5099]

I can't imagine it could be done any easier than this.

#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

Global $sURL = "http://causeequalstime.com/musique/"
Global $sSource = BinaryToString(InetRead($sURL))
Global $aLinks = StringRegExp($sSource, '(?s)(?i)<a href="(.*?)">', 3)

For $i = 0 To UBound($aLinks) - 1
    If StringRight($aLinks[$i], 4) = ".mp3" Then InetGet($sURL & $aLinks[$i], @ScriptDir & "\" & StringReplace($aLinks[$i], "%20", " "))
Next

Awesome!!!

[wakillon]

_IELinkGetCollection works well !

#include <IE.au3>

DirCreate ( @ScriptDir & "\Downloads" )
$oIE = _IECreate ( "http://causeequalstime.com/musique", 0, 0 )
$oLinks = _IELinkGetCollection ( $oIE )
For $oLink In $oLinks
    $_Link = $oLink.href
    If StringRight ( $_Link, 4 ) = ".mp3" Then 
        ConsoleWrite ( 'link : ' & $_Link & @CRLF )
        InetGet ( $_Link, @ScriptDir & "\Downloads\" & StringReplace ( _GetFullNameByUrl ( $_Link ), '%20', ' ' ) )
    EndIf
Next
 
_IEQuit ( $oIE ) 

Func _GetFullNameByUrl ( $_FileUrl )
    $_FileName = StringSplit ( $_FileUrl, '/' )
    If Not @error Then 
        Return $_FileName[$_FileName[0]]
    Else
        Return 0
    EndIf
EndFunc ;==> _GetFullNameByUrl ( )

Edited December 18, 2010 by wakillon