GUICtrlGetState does not return what is expected

[nitekram]

Can't understand why this does not work. It appears that if I drop the number 80 in for the value it works?

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $n, $msg

    GUICreate("My GUI (GetControlState)")
    $n = GUICtrlCreateCheckbox("checkbox", 10, 10)
    GUICtrlSetState(-1, $gui_checked)  ; checked

    GUISetState()       ; will display an empty dialog box

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd


If GUICtrlGetState($n) = $gui_checked Then MsgBox(0, "state", StringFormat("GUICtrlRead=%d\nGUICtrlGetState=%d", GUICtrlRead($n), GUICtrlGetState($n)))
If GUICtrlGetState($n) = 80 Then MsgBox(0, "state", StringFormat("GUICtrlRead=%d\nGUICtrlGetState=%d", GUICtrlRead($n), GUICtrlGetState($n)))
EndFunc   ;==>Example

Edited December 29, 2010 by nitekram

[UEZ]

Use GUICtrlRead() instead of GUICtrlGetState() to get the status of the checkbox.

If GUICtrlRead($n) = $gui_checked Then MsgBox(0, "state", StringFormat("1GUICtrlRead=%d\nGUICtrlGetState=%d", GUICtrlRead($n), GUICtrlGetState($n)))

Br,

UEZ

[nitekram]

I am not really trying see if the box is checked or not - want to check the state of the control.

for instance

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $n, $msg

    GUICreate("My GUI (GetControlState)")
    $n = GUICtrlCreateCheckbox("checkbox", 10, 10)
    ;GUICtrlSetState(-1, -1) ; checked
    GUICtrlSetState(-1, $gui_disable)  ; checked

    GUISetState()       ; will display an empty dialog box

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd


If GUICtrlGetState($n) = $gui_disable Then MsgBox(0, "state", StringFormat("GUICtrlRead=%d\nGUICtrlGetState=%d", GUICtrlRead($n), GUICtrlGetState($n)))
If GUICtrlGetState($n) = 80 Then MsgBox(0, "state", StringFormat("GUICtrlRead=%d\nGUICtrlGetState=%d", GUICtrlRead($n), GUICtrlGetState($n)))
EndFunc   ;==>Example

Edited December 29, 2010 by nitekram

[Jos]

Try:

If BitAND(GUICtrlGetState($n),$gui_disable) = $gui_disable Then ConsoleWrite(" disabled1 ..." & @CRLF)

[nitekram]

That works - could not find anything like that in the help file for GUICtrlGetState - just pulled out all my hair trying to figure it out.

[nitekram]

OK - back to pulling my hair out.

can you explain a little bit on how to make this work?

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $n, $msg

    GUICreate("My GUI (GetControlState)")
    $n = GUICtrlCreateCheckbox("checkbox", 10, 10)
    GUICtrlSetState(-1, $gui_checked) ; checked
    GUICtrlSetState(-1, $gui_disable)  ; checked

    GUISetState()       ; will display an empty dialog box

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd



If BitAND(GUICtrlGetState($n),$gui_disable, $gui_checked) = $gui_disable + $gui_checked Then ConsoleWrite(" disabled1 ..." & @CRLF)


EndFunc   ;==>Example

[Jos]

First of all you use BitAND() in the wrong way unless you would do:

BitAND(GUICtrlGetState($n),BitOR($gui_disable, $gui_checked)) = BitOR($gui_disable, $gui_checked)

but for some reason the Checked status is not retrieved with the GUICtrlGetState() at all so you need to use GuiCtrlRead for that state item.

Edited December 29, 2010 by Jos

[nitekram]

Thanks again