Set Color

[SkellySoul]

Hello I am making a small little game and ran into a funny problem that I can't think of solving

As the progress bar drains it changes color but the problem is it always sets it to green because once the Progress < 75 it will always be lower and set it to green.

If GUICtrlRead($Progress) = 0 Then
    _Game_Over()
ElseIf GUICtrlRead($Progress) < 75 Then
    GUICtrlSetColor($Progress, 0x00FF00)
ElseIf GUICtrlRead($Progress) < 60 Then
    GUICtrlSetColor($Progress, 0xFFFF00)
ElseIf GUICtrlRead($Male_Progress) < 30 Then
    GUICtrlSetColor($Progress, 0xFF0000)
EndIf

[BrewManNH]

You need to reverse your comparisons, put the lowest number first and work your way up to 75. That way if it matches one the lower comparisons, the higher ones won't be checked.

[kaotkbliss]

Or you could use ranges instead, like:

ElseIf GUICtrlRead($Progress) < 75 And GUICtrlRead($Progress) > 59 Then

GUICtrlSetColor($Progress, 0x00FF00)

[Melba23]

SkellySoul,

As you have discovered, GUICtrlSetColor does not work if the Progress has a theme from the OS. So you have 2 choices:

- 1. Use the the 3 available $PBST colours (green, yellow, red).

- 2. Remove the theme from the progress bar and use GUICtrlSetColor - but this also changes the appearance of the progress.

Anyway, you choose:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

Const $PBST_NORMAL = 0x0001
Const $PBST_ERROR = 0x0002
Const $PBST_PAUSED = 0x0003

$hGUI = GUICreate("Progress Test", 500, 130)

$hProg_Theme = GUICtrlCreateProgress(10, 10, 480, 30)
GUICtrlSetData(-1, 100)

$hProg_NoTheme = GUICtrlCreateProgress(10, 50, 480, 30)
GUICtrlSetData(-1, 100)
; Remove the theme
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($hProg_NoTheme), "wstr", 0, "wstr", 0)
GUICtrlSetColor(-1, 0x00FF00)

$hProgressButton = GUICtrlCreateButton("Progress", 10, 90, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hProgressButton
            ; GUICtrlSendMsg($hProg_Theme, $PBM_SETSTATE, $PBST_NORMAL, 0) ; Just to show the green message
            For $i = 100 To 1 Step -1
                GUICtrlSetData($hProg_Theme, $i)
                GUICtrlSetData($hProg_NoTheme, $i)
                Sleep(50)
                Switch $i
                    Case 60
                        GUICtrlSendMsg($hProg_Theme, $PBM_SETSTATE, $PBST_PAUSED, 0)
                        GUICtrlSetColor($hProg_NoTheme, 0xFFFF00)
                    Case 30
                        GUICtrlSendMsg($hProg_Theme, $PBM_SETSTATE, $PBST_ERROR, 0)
                        GUICtrlSetColor($hProg_NoTheme, 0xFF0000)
                EndSwitch
            Next
            ; For some reason Vista requries a double whammy to set it to zero!
            GUICtrlSetData($hProg_Theme, 0)
            GUICtrlSetData($hProg_Theme, 0)
            GUICtrlSetData($hProg_NoTheme, 0)
            GUICtrlSetData($hProg_NoTheme, 0)
            Sleep(50)
    EndSwitch

WEnd

Happy?

M23

[guinness]

Nice example Melba23! Have been using for a while, so this is a nice addition to my collection.

[SkellySoul]

Thanks very much I should of have caught that but still to early to think properly