Way to get physical memory

[JohnOne]

MemGetStats() returns incorrect amount for me.

Is there another more accurate method about?

I have looked, and might have missed a post amid all the game threads associated with memory.

MsgBox(0,"",_Mem())

Func _Mem()
    $a = MemGetStats()
    $a = Round($a[1] / 1024)
    Return $a & " MB"
EndFunc

EDIT:

returns 992 for me or 1015 when / 1000, with 1GB ram.

Edited February 7, 2011 by JohnOne

[AdmiralAlkex]

Why do you think it's wrong? What does task manager say you have?

Is it the actual hardware you want? Try the

[UEZ]

Try this:

#AutoIt3Wrapper_UseX64=n

MsgBox(0, "Physical Memory", "Physical Memory installed: " & Round(GetMemWMI() / 1024 ^2, 0) & " MB")

Func GetMemWMI($srv = "localhost")
    Local $mem, $colItems, $colItem, $ping, $x
    $ping = Ping($srv)
    If $ping Then
        $objWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!\\" & $srv & "\root\cimv2")
        $colItems = $objWMIService.ExecQuery("Select Capacity from Win32_PhysicalMemory", "WQL", 0x30)
        If IsObj($colItems) Then
            For $objItem In $colItems
                $mem += $objItem.Capacity
            Next
            Return SetError(0, 0, $mem)
        Else
            Return SetError(2, 0, 0)
        EndIf
    Else
        Return SetError(1, 0, 0)
    EndIf
EndFunc

I'm sure that there is a kernel32.dll version flying around...

Br,

UEZ

Edited February 7, 2011 by UEZ

[JohnOne]

ask manager reports 991 MB

Cheers UEZ, that seems to get it, speed is not really an issue against accuracy for me.

Just had to change

Round(GetMemWMI() / 1024 ^2, 0) & " GB")

To

Round(GetMemWMI() / 1024 ^3, 0) & " GB")

Unless I have 1024 GB

Anyway it reports 1 GB which is what I was after, just wondering if it will be ok on 64 bit OS.

[jvanegmond]

If task manager reports 991 MB, and your code in the OP reports 992 MB, you don't suspect a rounding error of some kind? Seems like a trivial thing to try before making a thread.

MsgBox(0,"",_Mem())

Func _Mem()
    $a = MemGetStats()
    $a = Floor($a[1] / 1024)
    Return $a & " MB"
EndFunc

[JohnOne]

Yes, I did that and Ceiling, except I dont want what task manager reports, I want the amount of physical memory slotted into my memory banks, that is 1GB.

[Tripredacus]

Yes, I did that and Ceiling, except I dont want what task manager reports, I want the amount of physical memory slotted into my memory banks, that is 1GB.

You are best off reading out of the WMI then, as posted earlier.

[UEZ]

ask manager reports 991 MB

Cheers UEZ, that seems to get it, speed is not really an issue against accuracy for me.

Just had to change

Round(GetMemWMI() / 1024 ^2, 0) & " GB")

To

Round(GetMemWMI() / 1024 ^3, 0) & " GB")

Unless I have 1024 GB

Anyway it reports 1 GB which is what I was after, just wondering if it will be ok on 64 bit OS.

GetMemWMI() / 1024 ^2 is MB and not GB

It is also working properly when compiling it as x64 application.

Br,

UEZ

[JohnOne]

Great, thanks once again buddy.

[AdmiralAlkex]

Windows Vista SP1 and later also has the function GetPhysicallyInstalledSystemMemory (<-- link) in Kernel32.dll

MsgBox(0, "Title", "GetPhysicallyInstalledSystemMemory = " & _GetPhysicallyInstalledSystemMemory())

Func _GetPhysicallyInstalledSystemMemory()
    $aRet = DllCall("Kernel32.dll", "int", "GetPhysicallyInstalledSystemMemory", "int*", "")
    If @error Then Return SetError(1, 0, 0)
    Return $aRet[1]
EndFunc

[JohnOne]

Thanks AdmiralAlkex, another good one, reports 1048576.