do iterate all controls in form

[Ontosy]

Do it is possibile to iterate all controls in form?

f.e.

for control in form ...

[Melba23]

Ontosy,

When you create control with the native Autoit commands (GUICtrlCreate*) AutoIt allocates each control a ControlID which is returned by the command. This ControlID is actually an index to an internal AutoIt array where AutoIt tracks the controls. So if you create controls in IMMEDIATE SUCCESSION than they will have consecutive ControlIDs and you can use a loop to action each of them.

But do note that Autoit allocates the first available index in this array, so if you have deleted any controls there will be vacant spaces early in the array and you are unlikely to get consecutive ControlIDs.

Here is a short example to show this in action:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

; This dummy control gets the ControlID of the first checkbox to start our loop
$iCheckStart = GUICtrlCreateDummy() + 1
; Now create the checkboxes - note we do not store the ControlIDs
For $i = 0 To 10
    GUICtrlCreateCheckbox($i, 25, 10 + ($i * 20), 200, 15)
Next

$hButton_Check = GUICtrlCreateButton("Check All", 10, 300, 80, 30)
$hButton_Clear = GUICtrlCreateButton("Uncheck All", 100, 300, 80, 30)

GUISetState(@SW_SHOW)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton_Check
            ; Loop through the ControlIDs
            For $i = $iCheckStart To $iCheckStart + 10
                GUICtrlSetState($i, $GUI_CHECKED)
            Next
        Case $hButton_Clear
            For $i = $iCheckStart To $iCheckStart + 10
                GUICtrlSetState($i, $GUI_UNCHECKED)
            Next
    EndSwitch

WEnd

All clear?

M23

[Ontosy]

I would to iterate the control become not after creation.

[guinness]

I would have given a similar example to what Melba23 gave, so I am a little confused to what you are looking for.

If you want to know what the ControlID is e.g. Button, Static then have a look at _WinAPI_GetClassName() in the Help File.

[Ontosy]

Ok ty.