How to use a var in a For statement from a label?

[Damein]

Not 100% sure how to ask this, so let me show you an example.

#include <GUIConstantsEx.au3>

GuiCreate("Test GUI")
$1 = GuiCtrlCreateLabel("This is a test label 1", 5,30)
$2 = GuiCtrlCreateLabel("This is a test label 2", 5,60)
$3 = GuiCtrlCreateLabel("This is a test label 3", 5,90)
GuiSetState()

While 1
    For $Count = 0 To 4 Step +1
        GuiCtrlSetData($Count, "Change to me!")
        Sleep(600)
        GuiCtrlSetData($Count, "Then back to original!")
        Sleep(600)
        GuiCtrlSetData($Count, "This is a test label " & $Count)
        Sleep(600)
    Next
    $Count = 0
    Sleep(10)
    WEnd

So in this script I would assume that on each go it would change one label, starting at 1, since Count would be the numeral 1 and the label has the numeral one as well. I may be assuming too much and the Count var does not actually call upon the $1 as I thought it would, if this is the case then is there a way to do this?

Thanks.

As a side note, running the script as is will change the first and second label, but will also display it as the count being 3 for 1 and 4 for 2 on the labels. So I'm not 100% what is going on.

Edited February 23, 2011 by Damein

[Melba23]

Damein,

I may be assuming too much

Correct!

The variable names are $1, $2 and $3, while $Count is set to 1, 2 and 3. You need to use Execute like this:

#include <GUIConstantsEx.au3>

HotKeySet("{ESC}", "On_Exit")

GuiCreate("Test GUI")
$1 = GuiCtrlCreateLabel("This is a test label 1", 5, 30, 200)
$2 = GuiCtrlCreateLabel("This is a test label 2", 5, 60, 200)
$3 = GuiCtrlCreateLabel("This is a test label 3", 5, 90, 200)
GuiSetState()

While 1
    For $Count = 1 To 3
        GuiCtrlSetData(Execute("$" & $Count), "Change to me!")
        Sleep(600)
        GuiCtrlSetData(Execute("$" & $Count), "Then back to original!")
        Sleep(600)
        GuiCtrlSetData(Execute("$" & $Count), "This is a test label " & $Count)
        Sleep(600)
    Next
    $Count = 0
    Sleep(10)

WEnd

Func On_Exit()
    Exit
EndFunc

The Execute function returns the content of the variable defined by "$" & $count - which is the ControlID of the label.

However, the more elegant way to do this is using an array like this:

#include <GUIConstantsEx.au3>

HotKeySet("{ESC}", "On_Exit")

Global $aLabels[4]

GuiCreate("Test GUI")
$aLabels[1] = GuiCtrlCreateLabel("This is a test label 1", 5, 30, 200)
$aLabels[2] = GuiCtrlCreateLabel("This is a test label 2", 5, 60, 200)
$aLabels[3] = GuiCtrlCreateLabel("This is a test label 3", 5, 90, 200)
GuiSetState()

While 1
    For $Count = 1 To 3 Step +1
        GuiCtrlSetData($aLabels[$Count], "Change to me!")
        Sleep(600)
        GuiCtrlSetData($aLabels[$Count], "Then back to original!")
        Sleep(600)
        GuiCtrlSetData($aLabels[$Count], "This is a test label " & $Count)
        Sleep(600)
    Next

    $Count = 0
    Sleep(10)

WEnd

Func On_Exit()
    Exit
EndFunc

Now you do not need the clumsy Execute statements.

All clear? Ask if not.

M23