Simple, OOP-like syntax in AutoIt

[WorknMan]

I'm wondering if it's possible to set up data types in AutoIt that are a little more complex than arrays, but not really as complex as full-blown objects either. I know there's an OOP UDF floating around, but I'm not exactly sure how it works.

Basically, if I've got a $person array that's set up like this:

$person[0] = 'Jane' ;first name
$person[1] = 'Doe' ;last name
$person[2] = 23 ;age
$person[3] = 'F' ;gender
; and so on ...

return $person

I'd like to be able to set this up as something like:

$person.firstname

$person.lastname

$person.age

....

The reason I ask is because I've got a script using an array with 15+ elements, and it gets a bit difficult to try and remember what is $array[11] when I see it in code. Plus, if I ever need to change the order of the elements, that is a huge pain in the arse when it's being passed around from function to function.

[Melba23]

WorknMan,

I recognse the problem!

An Associative Array might be the thing you are looking for - my favourite implementation is this one by Nutster.

Take a look and see if it is what you want - please come back and ask again if you have any questions on how to use it or it does not fit your requirements.

M23

[iamtheky]

If the elements are going to be static you could always set them to common names.

#include <array.au3>

Global $person[4]

$first = 0
$last = 1
$age = 2
$sex = 3

$person[$first] = 'Jane' ;first name
$person[$last] = 'Doe' ;last name
$person[$age] = 23 ;age
$person[$sex] = 'F' ;gender
; and so on ...

_arraydisplay ($person)

[trancexx]

I'm wondering if it's possible to set up data types in AutoIt that are a little more complex than arrays, but not really as complex as full-blown objects either. I know there's an OOP UDF floating around, but I'm not exactly sure how it works.

For example this how:

expandcollapse popup

#include "oLinkedList.au3"

; Error monitoring
Global $oError = ObjEvent("AutoIt.Error", "_ErrFunc")
Func _ErrFunc()
    ConsoleWrite("COM Error, ScriptLine(" & $oError.scriptline & ") : Number 0x" & Hex($oError.number, 8) & " - " & $oError.windescription & @CRLF)
EndFunc   ;==>_ErrFunc

_AutoItObject_Startup()



Global $oMyList = LinkedList()
$oMyList.add(_CreateItem("Jane", "Doe", 23, "F"))
$oMyList.add(_CreateItem("Jack", "TheRipper", 38, "M"))
$oMyList.add(_CreateItem("Jill", "Scott", 40))
$oMyList.add(_CreateItem("Joey", "Tribiani", 30, "M"))

Global $sFemales, $sMales

For $oMember In $oMyList
    If $oMember.gender = "F" Then $sFemales &= @TAB & $oMember.Name & "    " & $oMember.LastName & "    age " & $oMember.Age & @CRLF
    If $oMember.gender = "M" Then $sMales &= @TAB & $oMember.Name & "    " & $oMember.LastName & "    age " & $oMember.Age & @CRLF
Next


ConsoleWrite(">Females:" & @CRLF & $sFemales)
ConsoleWrite(">Males:" & @CRLF & $sMales)



Func _CreateItem($sName, $sLastName, $iAge, $sGender = "F")
    Local $oClass = _AutoItObject_Class()

    $oClass.AddProperty("Name", $ELSCOPE_PUBLIC, $sName)
    $oClass.AddProperty("LastName", $ELSCOPE_PUBLIC, $sLastName)
    $oClass.AddProperty("Age", $ELSCOPE_PUBLIC, $iAge)
    $oClass.AddProperty("Gender", $ELSCOPE_PUBLIC, $sGender)

    Return $oClass.Object
EndFunc

When you look closer you will see it's a real life saver.

Btw, there can be number of variations on the subject.

[WorknMan]

Ok, I got a lot of info to sift through here, but I have a question for trancexx, or anyone who knows

I see this line in your code:

Global $oMyList = LinkedList()

What is that LinkedList() function?

Edited April 14, 2011 by WorknMan

[ProgAndy]

LinkedList is a UDF wich is defined in oLinkedList.au3. It creates an object which represents a linked list.

[RCMorey11]

I like to use enumerations. So I would have something like:

Global Enum $eFNAME, $eLNAME, $eAGE, $eSEX, $eNUM_TRAITS

Global $Person[$eNUM_TRAITS]

$Person[$eFNAME] = "John"

$Person[$eLNAME] = "Doe"

$Person[$eAGE] = 21

$Person[$eSEX] = "M"

[WorknMan]

LinkedList is a UDF wich is defined in oLinkedList.au3. It creates an object which represents a linked list.

Well, I kind of figured as such, but was wondering where to get the UDF I thought it might be a part of the AutoItObject UDF, but don't see any reference to it in the documentation or the code.

[trancexx]

Well, I kind of figured as such, but was wondering where to get the UDF I thought it might be a part of the AutoItObject UDF, but don't see any reference to it in the documentation or the code.

Sorry for not saying... you can find oLinkedList.au3 inside AutoItObject package in \Examples folder.

AutoItObject package.

Just place it together with AutoItObject.au3 into the script's folder.

Edited April 14, 2011 by trancexx