Need help with compare var

[Idc]

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 343, 99, 192, 124)
$Input1 = GUICtrlCreateInput("1", 32, 16, 73, 22)
$Input2 = GUICtrlCreateInput("10", 32, 56, 73, 22)
$Button1 = GUICtrlCreateButton("GO", 232, 32, 73, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Func compare()
If $v1 > $v2 Then
    msgbox(0,"","$v1 > $v2")
Else
    msgbox(0,"","$v1 < $v2")

EndIf
EndFunc


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            Global $v1 = GUICtrlRead($Input1)
            Global $v2 = GUICtrlRead($Input2)
            compare()
    EndSwitch
WEnd

When i fill in input 1 number "3" and click GO it is so amazing 3 > 10 ????

Could someone help me solve this problem ?

[Melba23]

Idc,

Inputs return strings - you want the numeric values so use Number to force the variables into that type:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 343, 99, 192, 124)
$Input1 = GUICtrlCreateInput("1", 32, 16, 73, 22)
$Input2 = GUICtrlCreateInput("10", 32, 56, 73, 22)
$Button1 = GUICtrlCreateButton("GO", 232, 32, 73, 25)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            $v1 = Number(GUICtrlRead($Input1))
            $v2 = Number(GUICtrlRead($Input2))
            compare($v1, $v2) ; Why make them Global - just pass as parameters
    EndSwitch
WEnd

Func compare($v1, $v2)
    If $v1 > $v2 Then
        MsgBox(0, "", "$v1 > $v2")
    Else
        MsgBox(0, "", "$v1 < $v2")

    EndIf
EndFunc   ;==>compare

If you keep them as strings you actually compare the ASCII values - and "3" really is greater than "1" in that case.

M23